Move meta-fsl-arm content to layer root

The meta-fsl-arm is going to be used as the base for this layer. It
contains a clean history and allowing a more granullar set of changes.

This commit is just a rename of all contents of meta-fsl-arm
subdirectory to this layer's root, subsequent changes are based on top
of that.

Signed-off-by: Otavio Salvador <otavio@ossystems.com.br>

26 files changed, 647 insertions, 0 deletions

diff --git a/conf/layer.conf b/conf/layer.conf
new file mode 100644
index 000000000..81d29f598
--- /dev/null
+++ b/conf/layer.conf
@@ -0,0 +1,26 @@
+# We have a conf and classes directory, add to BBPATH
+BBPATH .= ":${LAYERDIR}"
+
+# We have a packages directory, add to BBFILES
+BBFILES += "${LAYERDIR}/recipes-*/*/*.bb \
+            ${LAYERDIR}/recipes-*/*/*.bbappend"
+
+BBFILE_COLLECTIONS += "fsl-arm"
+BBFILE_PATTERN_fsl-arm := "^${LAYERDIR}/"
+BBFILE_PRIORITY_fsl-arm = "5"
+
+FSL_EULA_FILE = "${LAYERDIR}/EULA"
+
+FSL_MIRROR ?= "http://www.freescale.com/lgfiles/NMG/MAD/YOCTO/"
+
+MIRRORS += " \
+${FSL_MIRROR}   http://download.ossystems.com.br/bsp/freescale/source/ \n \
+"
+
+# Let us add layer-specific bbappends which are only applied when that
+# layer is included in our configuration
+BBFILES += "${@' '.join('${LAYERDIR}/%s/recipes*/*/*.bbappend' % layer \
+               for layer in BBFILE_COLLECTIONS.split())}"
+# Add layer-specific bb files too
+BBFILES += "${@' '.join('${LAYERDIR}/%s/recipes*/*/*.bb' % layer \
+               for layer in BBFILE_COLLECTIONS.split())}"
diff --git a/conf/machine/imx23evk.conf b/conf/machine/imx23evk.conf
new file mode 100644
index 000000000..ecaef9a6f
--- /dev/null
+++ b/conf/machine/imx23evk.conf
@@ -0,0 +1,19 @@
+#@TYPE: Machine
+#@NAME: Freescale i.MX23 Evaluation Kit
+#@SOC: i.MX23
+#@DESCRIPTION: Machine configuration for Freescale i.MX23 Evaluation Kit
+#@MAINTAINER: Otavio Salvador <otavio@ossystems.com.br>
+
+include conf/machine/include/mxs-base.inc
+
+SOC_FAMILY = "mxs:mx23"
+
+IMXBOOTLETS_MACHINE = "stmp378x_dev"
+UBOOT_MACHINE = "mx23evk_config"
+
+KERNEL_DEVICETREE = "imx23-evk.dtb"
+
+SDCARD_ROOTFS ?= "${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext3"
+IMAGE_FSTYPES ?= "tar.bz2 ext3 uboot.mxsboot-sdcard sdcard"
+
+MACHINE_FEATURES = "apm usbgadget usbhost vfat touchscreen"
diff --git a/conf/machine/imx28evk.conf b/conf/machine/imx28evk.conf
new file mode 100644
index 000000000..672e4587b
--- /dev/null
+++ b/conf/machine/imx28evk.conf
@@ -0,0 +1,57 @@
+#@TYPE: Machine
+#@NAME: Freescale i.MX28 Evaluation Kit
+#@SOC: i.MX28
+#@DESCRIPTION: Machine configuration for Freescale i.MX28 Evaluation Kit
+#@MAINTAINER: Otavio Salvador <otavio@ossystems.com.br>
+
+include conf/machine/include/mxs-base.inc
+
+SOC_FAMILY = "mxs:mx28"
+
+# Disable perf features as 2.6.35.3 fails to build otherwise
+PERF_FEATURES_ENABLE = ""
+
+IMXBOOTLETS_MACHINE = "iMX28_EVK"
+
+UBOOT_CONFIG ??= "sd"
+UBOOT_CONFIG[sd] = "mx28evk_config,sdcard"
+UBOOT_CONFIG[nand] = "mx28evk_nand_config,ubifs"
+UBOOT_CONFIG[sd-auart-console] = "mx28evk_auart_console_config,sdcard"
+
+KERNEL_DEVICETREE = "imx28-evk.dtb"
+
+SDCARD_ROOTFS ?= "${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext3"
+IMAGE_FSTYPES ?= "tar.bz2 ext3 uboot.mxsboot-sdcard sdcard"
+
+SERIAL_CONSOLE = "115200 ttyAMA0"
+
+MACHINE_FEATURES = "apm usbgadget usbhost vfat alsa touchscreen"
+
+## Parameters for NAND IC part-# K9LBG08U0D-PCB0
+
+MKUBIFS_ARGS = "--min-io-size 4096 --leb-size 516096 --max-leb-cnt 8139"
+UBINIZE_ARGS = "--min-io-size 4096 --peb-size 524288 --sub-page-size 4096"
+MXSBOOT_NAND_ARGS = "-w 4096 -o 218 -e 524288"
+
+## To determine parameters' values, run "ubiattach -m 6 /dev/ubi_ctrl"
+## (assuming the rootfs device is /dev/mtd6).  Here's an example:
+
+# # ubiattach -m 6 /dev/ubi_ctrl
+# [   28.640396] UBI: attaching mtd6 to ubi0
+# [   53.000817] UBI: scanning is finished
+# [   53.126052] UBI: attached mtd6 (name "filesystem", size 4079 MiB) to ubi0
+# [   53.133109] UBI: PEB size: 524288 bytes (512 KiB), LEB size: 516096 bytes
+# [   53.140149] UBI: min./max. I/O unit sizes: 4096/4096, sub-page size 4096
+# [   53.146895] UBI: VID header offset: 4096 (aligned 4096), data offset: 8192
+# [   53.153931] UBI: good PEBs: 8139, bad PEBs: 20, corrupted PEBs: 0
+# [   53.160263] UBI: user volume: 1, internal volumes: 1, max. volumes count: 128
+# [   53.167444] UBI: max/mean erase counter: 2/1, WL threshold: 4096, image sequence number: 0
+# [   53.175872] UBI: available PEBs: 4113, total reserved PEBs: 4026, PEBs reserved for bad PEB handling: 140
+# [   53.189399] UBI: background thread "ubi_bgt0d" started, PID 217
+# UBI device number 0, total 8139 LEBs (4200505344 bytes, f GiB), available 4113 LEBs (2122702848 bytes, f GiB), LEB size 516096 bytes (f KiB)
+
+# --min-io-size: see "min./max. I/O unit sizes: " in the ubiattach output
+# --leb-size: see "LEB size:" in the ubiattach output
+# --max-leb-cnt: see "total <n> LEBs" in the ubiattach output, where <n> is the number you want
+# --peb-size: see "PEB size:" in the ubiattach output (pick the value in bytes)
+# --sub-page-size: see "sub-page size" in the ubiattach output
diff --git a/conf/machine/imx31pdk.conf b/conf/machine/imx31pdk.conf
new file mode 100644
index 000000000..cf368eb88
--- /dev/null
+++ b/conf/machine/imx31pdk.conf
@@ -0,0 +1,24 @@
+#@TYPE: Machine
+#@NAME: Freescale i.MX31 Platform Development Kit
+#@SOC: i.MX31
+#@DESCRIPTION: Machine configuration for Freescale i.MX31 Platform Development Kit
+
+include conf/machine/include/imx-base.inc
+require conf/machine/include/tune-arm1136jf-s.inc
+
+SOC_FAMILY = "mx3:mx31"
+
+GUI_MACHINE_CLASS = "smallscreen"
+
+UBOOT_MAKE_TARGET = "u-boot-with-spl.bin"
+UBOOT_SUFFIX = "bin"
+UBOOT_MACHINE = "mx31pdk_config"
+UBOOT_BINARY = "u-boot-with-spl.bin"
+KERNEL_IMAGETYPE = "uImage"
+
+IMAGE_FSTYPES = "ubi jffs2 tar.bz2"
+MKUBIFS_ARGS = "-m 2048 -e 129024 -c 2030"
+UBINIZE_ARGS = "-m 2048 -p 128KiB -s 512"
+
+MACHINE_FEATURES += "ext3 bluetooth ext2 screen"
+
diff --git a/conf/machine/imx35pdk.conf b/conf/machine/imx35pdk.conf
new file mode 100644
index 000000000..a3fc60cb8
--- /dev/null
+++ b/conf/machine/imx35pdk.conf
@@ -0,0 +1,25 @@
+#@TYPE: Machine
+#@NAME: Freescale i.MX35 Platform Development Kit
+#@SOC: i.MX35
+#@DESCRIPTION: Machine configuration for Freescale i.MX35 Platform Development Kit
+
+include conf/machine/include/imx-base.inc
+require conf/machine/include/tune-arm1136jf-s.inc
+
+SOC_FAMILY = "mx3:mx35"
+
+UBOOT_MACHINE = "mx35pdk_config"
+UBOOT_SUFFIX = "bin"
+UBOOT_BINARY = "u-boot.bin"
+UBOOT_MAKE_TARGET = "u-boot.bin"
+KERNEL_IMAGETYPE = "uImage"
+
+GUI_MACHINE_CLASS = "bigscreen"
+
+ROOT_FLASH_SIZE = "256"
+
+JFFS2_ERASEBLOCK = "0x20000"
+
+IMAGE_FSTYPES += "jffs2 tar.bz2"
+
+MACHINE_FEATURES += "ext2 ext3 screen"
diff --git a/conf/machine/imx51evk.conf b/conf/machine/imx51evk.conf
new file mode 100644
index 000000000..9d7d06ca4
--- /dev/null
+++ b/conf/machine/imx51evk.conf
@@ -0,0 +1,17 @@
+#@TYPE: Machine
+#@NAME: Freescale i.MX51 Evaluation Kit
+#@SOC: i.MX51
+#@DESCRIPTION: Machine configuration for Freescale i.MX51 Evaluation Kit
+#@MAINTAINER: Daiane Angolini <daiane.angolini@freescale.com>
+
+include conf/machine/include/imx-base.inc
+include conf/machine/include/tune-cortexa8.inc
+
+SOC_FAMILY = "mx5:mx51"
+
+# Disable perf features as 2.6.35.3 fails to build otherwise
+PERF_FEATURES_ENABLE = ""
+
+KERNEL_DEVICETREE = "imx51-babbage.dtb"
+
+UBOOT_MACHINE = "mx51evk_config"
diff --git a/conf/machine/imx53ard.conf b/conf/machine/imx53ard.conf
new file mode 100644
index 000000000..c338d6b51
--- /dev/null
+++ b/conf/machine/imx53ard.conf
@@ -0,0 +1,22 @@
+#@TYPE: Machine
+#@NAME: Freescale i.MX53 SABRE Automotive Board
+#@SOC: i.MX53
+#@DESCRIPTION: Machine configuration for Freescale i.MX53 SABRE Automotive Board
+#@MAINTAINER: Daiane Angolini <daiane.angolini@freescale.com>
+
+include conf/machine/include/imx-base.inc
+include conf/machine/include/tune-cortexa8.inc
+
+SOC_FAMILY = "mx5:mx53"
+
+# Disable perf features as 2.6.35.3 fails to build otherwise
+PERF_FEATURES_ENABLE = ""
+
+KERNEL_DEVICETREE = "imx53-ard.dtb"
+
+UBOOT_MACHINE = "mx53ard_config"
+KERNEL_IMAGETYPE = "uImage"
+
+MACHINE_FIRMWARE += "linux-firmware-ar3k \
+                     linux-firmware-ath6k"
+MACHINE_FEATURES += "wifi bluetooth"
diff --git a/conf/machine/imx53qsb.conf b/conf/machine/imx53qsb.conf
new file mode 100644
index 000000000..0e7349e82
--- /dev/null
+++ b/conf/machine/imx53qsb.conf
@@ -0,0 +1,21 @@
+#@TYPE: Machine
+#@NAME: Freescale i.MX53 Quick Start Board
+#@SOC: i.MX53
+#@DESCRIPTION: Machine configuration for Freescale i.MX53 Quick Start Board
+#@MAINTAINER: Trevor Woerner <trevor.woerner@linaro.org>
+
+include conf/machine/include/imx-base.inc
+include conf/machine/include/tune-cortexa8.inc
+
+SOC_FAMILY = "mx5:mx53"
+
+# Disable perf features as 2.6.35.3 fails to build otherwise
+PERF_FEATURES_ENABLE = ""
+
+KERNEL_DEVICETREE = "imx53-qsb.dtb imx53-qsrb.dtb"
+
+UBOOT_MACHINE = "mx53loco_config"
+
+MACHINE_FIRMWARE = "linux-firmware-ar3k \
+                     linux-firmware-ath6k"
+MACHINE_FEATURES += " wifi bluetooth"
diff --git a/conf/machine/imx6dlsabreauto.conf b/conf/machine/imx6dlsabreauto.conf
new file mode 100644
index 000000000..8c0fe8587
--- /dev/null
+++ b/conf/machine/imx6dlsabreauto.conf
@@ -0,0 +1,19 @@
+#@TYPE: Machine
+#@NAME: Freescale i.MX6DL SABRE Automotive
+#@SOC: i.MX6DL
+#@DESCRIPTION: Machine configuration for Freescale i.MX6DL SABRE Automotive
+#@MAINTAINER: Daiane Angolini <daiane.angolini@freescale.com>
+
+require conf/machine/include/imx6sabreauto-common.inc
+
+SOC_FAMILY = "mx6:mx6dl"
+
+KERNEL_DEVICETREE = "imx6dl-sabreauto.dtb imx6dl-sabreauto-gpmi-weim.dtb imx6dl-sabreauto-ecspi.dtb "
+KERNEL_DEVICETREE += "imx6dl-sabreauto-flexcan1.dtb "
+
+UBOOT_CONFIG ??= "sd"
+UBOOT_CONFIG[sd] = "mx6dlsabreauto_config,sdcard"
+UBOOT_CONFIG[eimnor] = "mx6dlsabreauto_eimnor_config"
+UBOOT_CONFIG[nand] = "mx6dlsabreauto_nand_config,ubifs"
+UBOOT_CONFIG[spinor] = "mx6dlsabreauto_spinor_config"
+UBOOT_CONFIG[mfgtool] = "mx6dlsabreauto_config"
diff --git a/conf/machine/imx6dlsabresd.conf b/conf/machine/imx6dlsabresd.conf
new file mode 100644
index 000000000..da3ee54b7
--- /dev/null
+++ b/conf/machine/imx6dlsabresd.conf
@@ -0,0 +1,16 @@
+#@TYPE: Machine
+#@NAME: Freescale i.MX6DL SABRE Smart Device
+#@SOC: i.MX6DL
+#@DESCRIPTION: Machine configuration for Freescale i.MX6DL SABRE Smart Device
+#@MAINTAINER: Otavio Salvador <otavio@ossystems.com.br>
+
+require conf/machine/include/imx6sabresd-common.inc
+
+SOC_FAMILY = "mx6:mx6dl"
+
+KERNEL_DEVICETREE = "imx6dl-sabresd.dtb imx6dl-sabresd-ldo.dtb imx6dl-sabresd-hdcp.dtb \
+                     imx6dl-sabresd-pf200.dtb imx6dl-sabresd-enetirq.dtb"
+
+UBOOT_CONFIG ??= "sd"
+UBOOT_CONFIG[sd] = "mx6dlsabresd_config,sdcard"
+UBOOT_CONFIG[mfgtool] = "mx6dlsabresd_config"
diff --git a/conf/machine/imx6qsabreauto.conf b/conf/machine/imx6qsabreauto.conf
new file mode 100644
index 000000000..b8fdce4b7
--- /dev/null
+++ b/conf/machine/imx6qsabreauto.conf
@@ -0,0 +1,20 @@
+#@TYPE: Machine
+#@NAME: Freescale i.MX6Q SABRE Automotive
+#@SOC: i.MX6Q
+#@DESCRIPTION: Machine configuration for Freescale i.MX6Q SABRE Automotive
+#@MAINTAINER: Daiane Angolini <daiane.angolini@freescale.com>
+
+require conf/machine/include/imx6sabreauto-common.inc
+
+SOC_FAMILY = "mx6:mx6q"
+
+KERNEL_DEVICETREE = "imx6q-sabreauto.dtb imx6q-sabreauto-gpmi-weim.dtb imx6q-sabreauto-ecspi.dtb "
+KERNEL_DEVICETREE += "imx6q-sabreauto-flexcan1.dtb "
+
+UBOOT_CONFIG ??= "sd"
+UBOOT_CONFIG[sd] = "mx6qsabreauto_config,sdcard"
+UBOOT_CONFIG[eimnor] = "mx6qsabreauto_eimnor_config"
+UBOOT_CONFIG[nand] = "mx6qsabreauto_nand_config,ubifs"
+UBOOT_CONFIG[spinor] = "mx6qsabreauto_spinor_config"
+UBOOT_CONFIG[sata] = "mx6qsabreauto_sata_config"
+UBOOT_CONFIG[mfgtool] = "mx6qsabreauto_config"
diff --git a/conf/machine/imx6qsabresd.conf b/conf/machine/imx6qsabresd.conf
new file mode 100644
index 000000000..72d1da5d7
--- /dev/null
+++ b/conf/machine/imx6qsabresd.conf
@@ -0,0 +1,17 @@
+#@TYPE: Machine
+#@NAME: Freescale i.MX6Q SABRE Smart Device
+#@SOC: i.MX6Q
+#@DESCRIPTION: Machine configuration for Freescale i.MX6Q SABRE Smart Device
+#@MAINTAINER: Otavio Salvador <otavio@ossystems.com.br>
+
+require conf/machine/include/imx6sabresd-common.inc
+
+SOC_FAMILY = "mx6:mx6q"
+
+KERNEL_DEVICETREE = "imx6q-sabresd.dtb imx6q-sabresd-ldo.dtb imx6q-sabresd-hdcp.dtb \
+                     imx6q-sabresd-enetirq.dtb imx6q-sabresd-uart.dtb"
+
+UBOOT_CONFIG ??= "sd"
+UBOOT_CONFIG[sd] = "mx6qsabresd_config,sdcard"
+UBOOT_CONFIG[sata] = "mx6qsabresd_sata_config"
+UBOOT_CONFIG[mfgtool] = "mx6qsabresd_config"
diff --git a/conf/machine/imx6slevk.conf b/conf/machine/imx6slevk.conf
new file mode 100644
index 000000000..9ca57353c
--- /dev/null
+++ b/conf/machine/imx6slevk.conf
@@ -0,0 +1,24 @@
+#@TYPE: Machine
+#@NAME: Freescale i.MX6SL Evaluation Kit
+#@SOC: i.MX6SL
+#@DESCRIPTION: Machine configuration for Freescale i.MX6SL Evaluation Kit
+#@MAINTAINER: Otavio Salvador <otavio@ossystems.com.br>
+
+include conf/machine/include/imx-base.inc
+include conf/machine/include/tune-cortexa9.inc
+
+SOC_FAMILY = "mx6:mx6sl"
+
+KERNEL_DEVICETREE = "imx6sl-evk.dtb imx6sl-evk-csi.dtb imx6sl-evk-ldo.dtb \
+                     imx6sl-evk-pf200.dtb imx6sl-evk-uart.dtb"
+
+UBOOT_CONFIG ??= "sd"
+UBOOT_CONFIG[sd] = "mx6slevk_config,sdcard"
+UBOOT_CONFIG[spinor] = "mx6slevk_spinor_config"
+UBOOT_CONFIG[mfgtool] = "mx6slevk_config"
+
+SERIAL_CONSOLE = "115200 ttymxc0"
+
+MACHINE_FEATURES += " pci wifi bluetooth"
+
+MACHINE_FIRMWARE += "linux-firmware-ath6k"
diff --git a/conf/machine/imx6solosabreauto.conf b/conf/machine/imx6solosabreauto.conf
new file mode 100644
index 000000000..ead787d00
--- /dev/null
+++ b/conf/machine/imx6solosabreauto.conf
@@ -0,0 +1,21 @@
+#@TYPE: Machine
+#@NAME: Freescale i.MX6Solo SABRE Automotive
+#@SOC: i.MX6S
+#@DESCRIPTION: Machine configuration for Freescale i.MX6Solo SABRE Automotive
+
+require conf/machine/include/imx6sabresd-common.inc
+
+SOC_FAMILY = "mx6:mx6dl"
+
+KERNEL_DEVICETREE = "imx6dl-sabreauto.dtb"
+
+PREFERRED_PROVIDER_u-boot = "u-boot-imx"
+PREFERRED_PROVIDER_virtual/bootloader = "u-boot-imx"
+KERNEL_IMAGETYPE = "zImage"
+
+UBOOT_CONFIG ??= "sd"
+UBOOT_CONFIG[sd] = "mx6solosabreauto_config,sdcard"
+UBOOT_CONFIG[eimnor] = "mx6solosabreauto_eimnor_config"
+UBOOT_CONFIG[nand] = "mx6solosabreauto_nand_config,ubifs"
+UBOOT_CONFIG[spinor] = "mx6solosabreauto_spinor_config"
+UBOOT_CONFIG[mfgtool] = "mx6solosabreauto_config"
diff --git a/conf/machine/imx6solosabresd.conf b/conf/machine/imx6solosabresd.conf
new file mode 100644
index 000000000..b123d8ce4
--- /dev/null
+++ b/conf/machine/imx6solosabresd.conf
@@ -0,0 +1,19 @@
+#@TYPE: Machine
+#@NAME: Freescale i.MX6Solo SABRE Smart Device
+#@SOC: i.MX6S
+#@DESCRIPTION: Machine configuration for Freescale i.MX6Solo SABRE Smart Device
+#@MAINTAINER: Otavio Salvador <otavio@ossystems.com.br>
+
+require conf/machine/include/imx6sabresd-common.inc
+
+SOC_FAMILY = "mx6:mx6dl"
+
+KERNEL_DEVICETREE = "imx6dl-sabresd.dtb imx6dl-sabresd-ldo.dtb"
+
+PREFERRED_PROVIDER_u-boot = "u-boot-imx"
+PREFERRED_PROVIDER_virtual/bootloader = "u-boot-imx"
+KERNEL_IMAGETYPE = "zImage"
+
+UBOOT_CONFIG ??= "sd"
+UBOOT_CONFIG[sd] = "mx6solosabresd_config,sdcard"
+UBOOT_CONFIG[mfgtool] = "mx6solosabresd_config"
diff --git a/conf/machine/imx6sxsabreauto.conf b/conf/machine/imx6sxsabreauto.conf
new file mode 100644
index 000000000..2d9ba0d86
--- /dev/null
+++ b/conf/machine/imx6sxsabreauto.conf
@@ -0,0 +1,20 @@
+#@TYPE: Machine
+#@NAME: Freescale i.MX6SoloX Sabre Automotive
+#@SOC: i.MX6SX
+#@DESCRIPTION: Machine configuration for Freescale i.MX6SoloX Sabre Automotive
+#@MAINTAINER: Lauren Post <Lauren.Post@freescale.com>
+
+require conf/machine/include/imx6sabreauto-common.inc
+
+SOC_FAMILY = "mx6:mx6sx"
+
+KERNEL_DEVICETREE = "imx6sx-sabreauto.dtb imx6sx-sabreauto-m4.dtb"
+
+PREFERRED_PROVIDER_u-boot = "u-boot-imx"
+PREFERRED_PROVIDER_virtual/bootloader = "u-boot-imx"
+
+UBOOT_CONFIG ??= "sd"
+UBOOT_CONFIG[sd] = "mx6sxsabreauto_config,sdcard"
+UBOOT_CONFIG[qspi1] = "mx6sxsabreauto_qspi1_config"
+UBOOT_CONFIG[nand] = "mx6sxsabreauto_nand_config"
+UBOOT_CONFIG[mfgtool] = "mx6sxsabreauto_config"
diff --git a/conf/machine/imx6sxsabresd.conf b/conf/machine/imx6sxsabresd.conf
new file mode 100644
index 000000000..62e3afba1
--- /dev/null
+++ b/conf/machine/imx6sxsabresd.conf
@@ -0,0 +1,22 @@
+#@TYPE: Machine
+#@NAME: Freescale i.MX6SoloX SabreSD
+#@SOC: i.MX6SX
+#@DESCRIPTION: Machine configuration for Freescale i.MX6SoloX Sabre SD
+#@MAINTAINER: Lauren Post <Lauren.Post@freescale.com>
+
+require conf/machine/include/imx6sabresd-common.inc
+
+SOC_FAMILY = "mx6:mx6sx"
+
+KERNEL_DEVICETREE = "imx6sx-sdb.dtb imx6sx-sdb-emmc.dtb imx6sx-sdb-m4.dtb \
+                     imx6sx-sdb-sai.dtb imx6sx-sdb-lcdif1.dtb \
+                     imx6sx-sdb-reva-ldo.dtb imx6sx-sdb-reva.dtb"
+
+UBOOT_ENTRYPOINT = "0x80008000"
+
+UBOOT_CONFIG ??= "sd"
+UBOOT_CONFIG[sd] = "mx6sxsabresd_config,sdcard"
+UBOOT_CONFIG[emmc] = "mx6sxsabresd_emmc_config,sdcard"
+UBOOT_CONFIG[qspi2] = "mx6sxsabresd_qspi2_config"
+UBOOT_CONFIG[m4fastup] = "mx6sxsabresd_m4fastup_config"
+UBOOT_CONFIG[mfgtool] = "mx6sxsabresd_config"
diff --git a/conf/machine/include/fsl-default-settings.inc b/conf/machine/include/fsl-default-settings.inc
new file mode 100644
index 000000000..b36e75a59
--- /dev/null
+++ b/conf/machine/include/fsl-default-settings.inc
@@ -0,0 +1,3 @@
+# Freescale BSP default settings
+
+IMAGE_CLASSES += "image_types_fsl"
diff --git a/conf/machine/include/fsl-default-versions.inc b/conf/machine/include/fsl-default-versions.inc
new file mode 100644
index 000000000..d2a4e93c4
--- /dev/null
+++ b/conf/machine/include/fsl-default-versions.inc
@@ -0,0 +1 @@
+# Freescale BSP default versions
diff --git a/conf/machine/include/imx-base.inc b/conf/machine/include/imx-base.inc
new file mode 100644
index 000000000..ecb2f772a
--- /dev/null
+++ b/conf/machine/include/imx-base.inc
@@ -0,0 +1,128 @@
+# Provides the i.MX common settings
+
+include conf/machine/include/fsl-default-settings.inc
+include conf/machine/include/fsl-default-versions.inc
+
+include conf/machine/include/soc-family.inc
+
+# Set specific make target and binary suffix
+PREFERRED_PROVIDER_u-boot ??= "u-boot-fslc"
+PREFERRED_PROVIDER_virtual/bootloader ??= "u-boot-fslc"
+UBOOT_MAKE_TARGET = "u-boot.imx"
+UBOOT_SUFFIX ?= "imx"
+
+UBOOT_ENTRYPOINT_mx3 = "0x80008000"
+UBOOT_ENTRYPOINT_mx51  = "0x90008000"
+UBOOT_ENTRYPOINT_mx53  = "0x70008000"
+UBOOT_ENTRYPOINT_mx6  = "0x10008000"
+UBOOT_ENTRYPOINT_mx6sl = "0x80008000"
+UBOOT_ENTRYPOINT_mx6sx = "0x80008000"
+UBOOT_ENTRYPOINT_vf = "0x80008000"
+
+PREFERRED_PROVIDER_virtual/xserver = "xserver-xorg"
+XSERVER_DRIVER = "xf86-video-fbdev"
+XSERVER_DRIVER_mx5 = "xf86-video-imxfb"
+XSERVER_DRIVER_mx6 = "xf86-video-imxfb-vivante"
+XSERVER = "xserver-xorg \
+           xf86-input-evdev \
+           ${XSERVER_DRIVER}"
+
+PREFERRED_VERSION_directfb_mx6 = "1.7.4"
+
+# Ship kernel modules
+MACHINE_EXTRA_RRECOMMENDS = "kernel-modules"
+
+# Tunes for hard/soft float-point selection. Note that we allow building for
+# thumb support giving distros the chance to enable thumb by setting
+# ARM_INSTRUCTION_SET = "thumb"
+#
+# handled by software
+# DEFAULTTUNE_mx6 ?= "cortexa9t-neon"
+# handled by hardware
+DEFAULTTUNE_mx6 ?= "cortexa9thf-neon"
+
+# Sub-architecture support
+MACHINE_SOCARCH_SUFFIX ?= ""
+MACHINE_SOCARCH_SUFFIX_mx3 = "-mx3"
+MACHINE_SOCARCH_SUFFIX_mx5 = "-mx5"
+MACHINE_SOCARCH_SUFFIX_mx6q = "-mx6qdl"
+MACHINE_SOCARCH_SUFFIX_mx6dl = "-mx6qdl"
+MACHINE_SOCARCH_SUFFIX_mx6sx = "-mx6sx"
+MACHINE_SOCARCH_SUFFIX_mx6sl = "-mx6sl"
+MACHINE_SOCARCH_SUFFIX_vf60 = "-vf60"
+MACHINE_SOCARCH_SUFFIX_vf50 = "-vf50"
+
+MACHINE_ARCH_FILTER = "virtual/kernel"
+MACHINE_SOCARCH_FILTER = "libfslcodec libfslvpuwrap libfslparser"
+MACHINE_SOCARCH_FILTER_append_mx5 = " virtual/libgles1 virtual/libgles2 virtual/egl virtual/mesa virtual/libgl"
+MACHINE_SOCARCH_FILTER_append_mx6 = " virtual/libopenvg virtual/libgles1 virtual/libgles2 virtual/egl virtual/mesa virtual/libgl virtual/libg2d"
+
+INHERIT += "fsl-dynamic-packagearch"
+
+# Firmware
+MACHINE_FIRMWARE ?= ""
+MACHINE_FIRMWARE_append_mx6q = " firmware-imx-vpu-imx6q"
+MACHINE_FIRMWARE_append_mx6dl = " firmware-imx-vpu-imx6d"
+MACHINE_FIRMWARE_append_mx53 = " firmware-imx-vpu-imx53 firmware-imx-sdma-imx53"
+MACHINE_FIRMWARE_append_mx51 = " firmware-imx-vpu-imx51 firmware-imx-sdma-imx51"
+
+# FIXME: Needs addition of firmware-imx of official BSPs
+#MACHINE_FIRMWARE_append_mx35 = " firmware-imx-sdma-imx35"
+#MACHINE_FIRMWARE_append_mx31 = " firmware-imx-sdma-imx31"
+#MACHINE_FIRMWARE_append_mx27 = " firmware-imx-vpu-imx27"
+#MACHINE_FIRMWARE_append_mx25 = " firmware-imx-sdma-imx25"
+
+MACHINE_EXTRA_RRECOMMENDS += "${MACHINE_FIRMWARE}"
+
+# Extra audio support
+# FIXME: Add support for ALL SoC families
+MACHINE_EXTRA_RRECOMMENDS_append_mx6 = " ${@base_contains('DISTRO_FEATURES', 'alsa', 'fsl-alsa-plugins', '', d)}"
+
+# Extra udev rules
+MACHINE_EXTRA_RRECOMMENDS += "udev-rules-imx"
+
+# GStreamer 1.0 plugins
+MACHINE_GSTREAMER_1_0_PLUGIN ?= ""
+MACHINE_GSTREAMER_1_0_PLUGIN_mx6q ?= "gstreamer1.0-plugins-imx-meta"
+MACHINE_GSTREAMER_1_0_PLUGIN_mx6dl ?= "gstreamer1.0-plugins-imx-meta"
+
+# mx5 GPU libraries
+GPU_FLAVOUR = "${@base_contains('DISTRO_FEATURES', 'x11', 'x11-', '', d)}"
+PREFERRED_PROVIDER_virtual/egl_mx5 ?= "amd-gpu-${GPU_FLAVOUR}bin-mx51"
+PREFERRED_PROVIDER_virtual/libgles1_mx5 ?= "amd-gpu-${GPU_FLAVOUR}bin-mx51"
+PREFERRED_PROVIDER_virtual/libgles2_mx5 ?= "amd-gpu-${GPU_FLAVOUR}bin-mx51"
+PREFERRED_PROVIDER_amd-gpu-mx51 ?= "amd-gpu-${GPU_FLAVOUR}bin-mx51"
+
+# mx6 GPU libraries
+PREFERRED_PROVIDER_virtual/egl_mx6 ?= "imx-gpu-viv"
+PREFERRED_PROVIDER_virtual/libgles1_mx6q ?= "imx-gpu-viv"
+PREFERRED_PROVIDER_virtual/libgles1_mx6dl ?= "imx-gpu-viv"
+PREFERRED_PROVIDER_virtual/libgles1_mx6sx ?= "imx-gpu-viv"
+PREFERRED_PROVIDER_virtual/libgles1_mx6sl ?= "mesa"
+PREFERRED_PROVIDER_virtual/libgles2_mx6q ?= "imx-gpu-viv"
+PREFERRED_PROVIDER_virtual/libgles2_mx6dl ?= "imx-gpu-viv"
+PREFERRED_PROVIDER_virtual/libgles2_mx6sx ?= "imx-gpu-viv"
+PREFERRED_PROVIDER_virtual/libgles2_mx6sl ?= "mesa"
+PREFERRED_PROVIDER_virtual/libgl_mx6q ?= "imx-gpu-viv"
+PREFERRED_PROVIDER_virtual/libgl_mx6dl ?= "imx-gpu-viv"
+PREFERRED_PROVIDER_virtual/libgl_mx6sx ?= "imx-gpu-viv"
+PREFERRED_PROVIDER_virtual/libgl_mx6sl ?= "mesa"
+PREFERRED_PROVIDER_virtual/libg2d_mx6 ?= "imx-gpu-viv"
+
+# Handle default kernel
+IMX_DEFAULT_KERNEL = "linux-imx"
+IMX_DEFAULT_KERNEL_mx3 = "linux-fslc"
+IMX_DEFAULT_KERNEL_mx6 = "linux-fslc-mx6"
+PREFERRED_PROVIDER_virtual/kernel ??= "${IMX_DEFAULT_KERNEL}"
+
+SDCARD_ROOTFS ?= "${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext3"
+IMAGE_FSTYPES ?= "tar.bz2 ext3 sdcard"
+
+SERIAL_CONSOLE = "115200 ttymxc0"
+
+KERNEL_IMAGETYPE = "zImage"
+
+MACHINE_FEATURES = "apm usbgadget usbhost vfat alsa touchscreen"
+
+# Add the ability to specify _imx machines
+MACHINEOVERRIDES =. "imx:"
diff --git a/conf/machine/include/imx6sabreauto-common.inc b/conf/machine/include/imx6sabreauto-common.inc
new file mode 100644
index 000000000..b4f37b3c9
--- /dev/null
+++ b/conf/machine/include/imx6sabreauto-common.inc
@@ -0,0 +1,10 @@
+# Provides the i.MX6 SABRE AUTO common settings
+
+require conf/machine/include/imx-base.inc
+require conf/machine/include/tune-cortexa9.inc
+
+SERIAL_CONSOLE = "115200 ttymxc3"
+
+MACHINE_FIRMWARE_append_mx6 = " linux-firmware-ath6k"
+
+MACHINE_FEATURES += " pci wifi bluetooth"
diff --git a/conf/machine/include/imx6sabresd-common.inc b/conf/machine/include/imx6sabresd-common.inc
new file mode 100644
index 000000000..40e3cde6c
--- /dev/null
+++ b/conf/machine/include/imx6sabresd-common.inc
@@ -0,0 +1,10 @@
+# Provides the i.MX6 SABRE SD common settings
+
+require conf/machine/include/imx-base.inc
+require conf/machine/include/tune-cortexa9.inc
+
+SERIAL_CONSOLE = "115200 ttymxc0"
+
+MACHINE_FIRMWARE_append_mx6 = " linux-firmware-ath6k"
+
+MACHINE_FEATURES += " pci wifi bluetooth"
diff --git a/conf/machine/include/mxs-base.inc b/conf/machine/include/mxs-base.inc
new file mode 100644
index 000000000..ecf4aed4a
--- /dev/null
+++ b/conf/machine/include/mxs-base.inc
@@ -0,0 +1,40 @@
+# Provides the i.MXS common settings
+
+include conf/machine/include/fsl-default-settings.inc
+include conf/machine/include/fsl-default-versions.inc
+
+include conf/machine/include/soc-family.inc
+include conf/machine/include/tune-arm926ejs.inc
+
+SOC_FAMILY = "mxs"
+
+PREFERRED_PROVIDER_virtual/kernel ??= "linux-imx"
+PREFERRED_PROVIDER_virtual/kernel_mx23 ?= "linux-fslc"
+
+PREFERRED_PROVIDER_u-boot ??= "u-boot-fslc"
+PREFERRED_PROVIDER_virtual/bootloader ??= "u-boot-fslc"
+UBOOT_ENTRYPOINT = "0x40008000"
+UBOOT_MAKE_TARGET = "u-boot.sb"
+UBOOT_SUFFIX = "sb"
+
+PREFERRED_PROVIDER_virtual/xserver = "xserver-xorg"
+XSERVER = "xserver-xorg \
+           xf86-input-evdev \
+           xf86-video-fbdev"
+
+# Sub-architecture support
+MACHINE_SOCARCH_SUFFIX ?= ""
+
+MACHINE_ARCH_FILTER = "virtual/kernel"
+
+INHERIT += "fsl-dynamic-packagearch"
+
+# Ship kernel modules
+MACHINE_EXTRA_RRECOMMENDS = "kernel-modules"
+
+SERIAL_CONSOLE = "115200 ttyAMA0"
+
+KERNEL_IMAGETYPE = "zImage"
+
+# Add the ability to specify _imx machines
+MACHINEOVERRIDES =. "imx:"
diff --git a/conf/machine/include/qoriq-arm.inc b/conf/machine/include/qoriq-arm.inc
new file mode 100644
index 000000000..20a759450
--- /dev/null
+++ b/conf/machine/include/qoriq-arm.inc
@@ -0,0 +1,17 @@
+require conf/machine/include/soc-family.inc
+
+# Freescale BSP default providers
+PREFERRED_PROVIDER_u-boot_ls102xa ?= "u-boot-ls1"
+PREFERRED_PROVIDER_virtual/bootloader_ls102xa ?= "u-boot-ls1"
+PREFERRED_PROVIDER_virtual/kernel_ls102xa ?= "linux-ls1"
+
+# Define the default image type
+IMAGE_CLASSES ?= "image_types_uboot"
+KERNEL_IMAGETYPE ?= "uImage"
+
+UBOOT_ENTRYPOINT_ls102xa = "0x80008000"
+
+MACHINE_FEATURES = "pci ext2 ext3 serial"
+MACHINE_EXTRA_RRECOMMENDS = "udev-extraconf"
+
+DEFAULTTUNE_ls102xa ?= "cortexa7hf-neon"
diff --git a/conf/machine/ls1021atwr.conf b/conf/machine/ls1021atwr.conf
new file mode 100644
index 000000000..4478e9530
--- /dev/null
+++ b/conf/machine/ls1021atwr.conf
@@ -0,0 +1,26 @@
+#@TYPE: Machine
+#@NAME: Freescale LS1021ATWR board
+#@SOC: ls102xa
+#@DESCRIPTION: Machine configuration for running LS1021ATWR in 32-bit mode
+#@MAINTAINER: Zhenhua Luo <zhenhua.luo@freescale.com>
+
+require conf/machine/include/qoriq-arm.inc
+require conf/machine/include/tune-cortexa7.inc
+
+SOC_FAMILY = "ls102xa"
+
+UBOOT_CONFIG ??= "nor"
+UBOOT_CONFIG[nor] = "ls1021atwr_nor_config"
+UBOOT_CONFIG[sdcard] = "ls1021atwr_sdcard_config,sdcard"
+UBOOT_CONFIG[lpuart] = "ls1021atwr_nor_lpuart_config"
+UBOOT_CONFIG[qspi] = "ls1021atwr_qspi_config"
+UBOOT_CONFIG[secure-boot] = "ls1021atwr_nor_SECURE_BOOT_config"
+
+QE_UCODE="iram_Type_A_LS1021a_r1.0.bin"
+
+KERNEL_DEVICETREE ?= "ls1021a-twr.dtb"
+
+SERIAL_CONSOLES ?= "115200;ttyS0 115200;ttyS1 115200;ttyEHV0 115200;ttyLP0 115200;ttyAMA0"
+SERIAL_CONSOLES_CHECK ?= "${SERIAL_CONSOLES}"
+USE_VT ?= "0"
+
diff --git a/conf/machine/twr-vf65gs10.conf b/conf/machine/twr-vf65gs10.conf
new file mode 100644
index 000000000..d1e14e02a
--- /dev/null
+++ b/conf/machine/twr-vf65gs10.conf
@@ -0,0 +1,23 @@
+#@TYPE: Machine
+#@NAME: Freescale Vybrid TWR-VF65GS10
+#@SOC: VF610
+#@DESCRIPTION: Machine configuration for Freescale Vybrid TWR-VF65GS10
+#@MAINTAINER: Anthony Felice <tony.felice@timesys.com>
+
+include conf/machine/include/imx-base.inc
+include conf/machine/include/tune-cortexa5.inc
+
+SOC_FAMILY = "vf:vf60"
+
+PREFERRED_PROVIDER_virtual/kernel ?= "linux-timesys"
+PREFERRED_PROVIDER_virtual/kernel-module-mcc ?= "kernel-module-mcc"
+PREFERRED_PROVIDER_virtual/kernel-module-mcc-dev ?= "kernel-module-mcc"
+
+UBOOT_MACHINE = "vf610twr_config"
+
+SDCARD_ROOTFS ?= "${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext3"
+IMAGE_FSTYPES ?= "tar.bz2 ext3 sdcard"
+
+SERIAL_CONSOLE = "115200 ttyLP1"
+
+MACHINE_FEATURES = "apm usbgadget usbhost vfat alsa touchscreen"