mcore-demos: imx-m33-demos: Add package based on 6.1.22-2.0.0

Signed-off-by: Daiane Angolini <daiane.angolini@foundries.io>

3 files changed, 88 insertions, 0 deletions

diff --git a/recipes-fsl/mcore-demos/README b/recipes-fsl/mcore-demos/README
new file mode 100644
index 000000000..d3770e8bb
--- /dev/null
+++ b/recipes-fsl/mcore-demos/README
@@ -0,0 +1,11 @@
+The M4 demo app version of each SoCs are followed:
+* 2.13.0 -- i.MX 7ULP, 8MQ, 8MM
+* 2.9.0 -- i.MX 8DXL, 8QM, 8QXP
+* 1.0.1 -- i.MX 7D
+
+The M7 demo app version of each SoCs are followed:
+* 2.13.0 -- i.MX 8MNULite, 8MN
+* 2.13.1 -- i.MX 8MP
+
+The M33 demo app version of each SoCs are followed:
+* 2.14.0 -- i.MX 8ULP,i.MX 93
diff --git a/recipes-fsl/mcore-demos/imx-m33-demos_2.14.0.bb b/recipes-fsl/mcore-demos/imx-m33-demos_2.14.0.bb
new file mode 100644
index 000000000..4b937a273
--- /dev/null
+++ b/recipes-fsl/mcore-demos/imx-m33-demos_2.14.0.bb
@@ -0,0 +1,15 @@
+# Copyright 2023 NXP
+# Released under the MIT license (see COPYING.MIT for the terms)
+
+require imx-mcore-demos.inc
+
+LIC_FILES_CHKSUM:mx8ulp-nxp-bsp = "file://COPYING;md5=63a38e9f392d8813d6f1f4d0d6fbe657"
+LIC_FILES_CHKSUM:mx93-nxp-bsp = "file://COPYING;md5=63a38e9f392d8813d6f1f4d0d6fbe657"
+
+SRC_URI[imx8ulp.md5sum] = "8c084435f30319948e037be3b5c4d807"
+SRC_URI[imx8ulp.sha256sum] = "c2f086257251b222ec60307e51874974ec1f4166736a747546055fdac991647b"
+
+SRC_URI[imx93.md5sum] = "5eb97a5afed0aafda98ea5bdc665811c"
+SRC_URI[imx93.sha256sum] = "54ca75f62baf0f197f77837822fe8fb0e4fa2e2450c81dca60d24ca5f59d48bd"
+
+COMPATIBLE_MACHINE = "(mx8ulp-nxp-bsp|mx93-nxp-bsp)"
diff --git a/recipes-fsl/mcore-demos/imx-mcore-demos.inc b/recipes-fsl/mcore-demos/imx-mcore-demos.inc
new file mode 100644
index 000000000..844ed8821
--- /dev/null
+++ b/recipes-fsl/mcore-demos/imx-mcore-demos.inc
@@ -0,0 +1,62 @@
+# Copyright 2017-2021 NXP
+# Released under the MIT license (see COPYING.MIT for the terms)
+
+SUMMARY = "i.MX M4/M7/M33 core Demo images"
+SECTION = "app"
+LICENSE = "Proprietary"
+
+inherit deploy fsl-eula-unpack
+
+SOC                ?= "INVALID"
+SOC:mx7ulp-nxp-bsp  = "imx7ulp"
+SOC:mx8dxl-nxp-bsp  = "imx8dxl"
+SOC:mx8mm-nxp-bsp   = "imx8mm"
+SOC:mx8mn-nxp-bsp   = "imx8mn"
+SOC:mx8mnul-nxp-bsp = "imx8mnddr3l"
+SOC:mx8mp-nxp-bsp   = "imx8mp"
+SOC:mx8mpul-nxp-bsp = "imx8mp"
+SOC:mx8mq-nxp-bsp   = "imx8mq"
+SOC:mx8qm-nxp-bsp   = "imx8qm"
+SOC:mx8qxp-nxp-bsp  = "imx8qx"
+SOC:mx8dx-nxp-bsp   = "imx8qx"
+SOC:mx8ulp-nxp-bsp  = "imx8ulp"
+SOC:mx93-nxp-bsp    = "imx93"
+
+MCORE_TYPE  ?= "m4"
+MCORE_TYPE:mx8mn-nxp-bsp  = "m7"
+MCORE_TYPE:mx8mnul-nxp-bsp = "m7"
+MCORE_TYPE:mx8mp-nxp-bsp  = "m7"
+MCORE_TYPE:mx8mpul-nxp-bsp  = "m7"
+MCORE_TYPE:mx8ulp-nxp-bsp  = "m33"
+MCORE_TYPE:mx93-nxp-bsp  = "m33"
+
+SRC_URI = "${FSL_MIRROR}/${SOC}-${MCORE_TYPE}-demo-${PV}.bin;name=${SOC};fsl-eula=true"
+
+S = "${WORKDIR}/${SOC}-${MCORE_TYPE}-demo-${PV}"
+
+#SRC_URI="https://www.nxp.com/lgfiles/NMG/MAD/YOCTO//imx93-m33-demo-2.14.0.bin;fsl-eula=true;name=imx93"
+
+
+SCR = "SCR-${SOC}-${MCORE_TYPE}-demo.txt"
+
+do_install () {
+    # install elf format binary to /lib/firmware
+    install -d ${D}${base_libdir}/firmware
+    install -m 0644 ${S}/*.elf ${D}${base_libdir}/firmware
+}
+
+DEPLOY_FILE_EXT       ?= "bin"
+DEPLOY_FILE_EXT:mx7ulp-nxp-bsp = "img"
+
+do_deploy () {
+   # Install the demo binaries
+   install -m 0644 ${S}/*.${DEPLOY_FILE_EXT} ${DEPLOYDIR}/
+}
+
+addtask deploy after do_install
+
+PACKAGE_ARCH = "${MACHINE_SOCARCH}"
+
+FILES:${PN} = "${nonarch_base_libdir}/firmware"
+
+INSANE_SKIP:${PN} = "arch"