ostree and otaimg enhancements

override_image_types_ostree.inc - do_image_ostree task:
-add dirs, cleandirs flags, to avoid mktemp, rm, cd, and to
also remove at clean
-add subimages, imgsuffix flags, to use automatic link creation
-create image in IMGDEPLOYDIR, instead of DEPLOY_DIR_IMAGE
to use the automatic deploy and clean mechanism (also helps
in cleaning old images)

override_image_types_ota.inc - do_image_otaimg task:
-add dirs, cleandirs flags, to avoid mktemp, rm, cd, and to
also remove at clean
-avoid untar-ing the ostree image, and use OSTREE_ROOTFS
-create image in IMGDEPLOYDIR, instead of DEPLOY_DIR_IMAGE
to use the automatic deploy and clean mechanism

Move OSTREE_REPO to "${WORKDIR}/ostree-repo", instead of
DEPLOY_DIR_IMAGE, this repo is needed for otaimg creation

sota_xeon-d.bbclass sota_atom-c3000.bbclass:
-set ROOTFS_sota to IMGDEPLOYDIR insted of DEPLOY_DIR_IMAGE,
as this is where the otaimg is now created; also use IMAGE_LINK_NAME
istead of IMAGE_NAME, to have the correct reference to the image,
even if the image was built in a previous run (IMAGE_NAME differs
in this case)

Change-Id: I44e87311d1819b80d34f924630d09e429d411d41
Signed-off-by: Matei Valeanu <Matei.Valeanu@enea.com>

5 files changed, 118 insertions, 14 deletions

diff --git a/classes/override_image_types_ostree.inc b/classes/override_image_types_ostree.inc
index ac584e5..241afcd 100644
--- a/classes/override_image_types_ostree.inc
+++ b/classes/override_image_types_ostree.inc
@@ -1,3 +1,18 @@
+# overrides meta-updater/classes/image_types_ostree.bbclass
+# - add do_image_ostree flags:
+#   - dirs, cleandirs: to avoid mktemp, rm, cd, and to also remove at clean
+#   - subimages, imgsuffix: to use automatic link creation
+# - override of IMAGE_CMD_ostree
+#   - use the added flags
+#   - IMGDEPLOYDIR, instead of DEPLOY_DIR_IMAGE
+
+OSTREE_ROOTFS="${WORKDIR}/ostree-root"
+do_image_ostree[dirs] = "${OSTREE_ROOTFS}"
+do_image_ostree[cleandirs] = "${OSTREE_ROOTFS}"
+do_image_ostree[subimages] = "rootfs.ostree.tar.bz2"
+do_image_ostree[imgsuffix] = "."
+export OSTREE_ROOTFS
+
 IMAGE_CMD_ostree () {
     if [ -z "$OSTREE_REPO" ]; then
         bbfatal "OSTREE_REPO should be set in your local.conf"
@@ -7,13 +22,10 @@ IMAGE_CMD_ostree () {
         bbfatal "OSTREE_BRANCHNAME should be set in your local.conf"
     fi
 
-    OSTREE_ROOTFS=`mktemp -du ${WORKDIR}/ostree-root-XXXXX`
-    cp -a ${IMAGE_ROOTFS} ${OSTREE_ROOTFS}
+    cp -a ${IMAGE_ROOTFS}/* ${OSTREE_ROOTFS}
     chmod a+rx ${OSTREE_ROOTFS}
     sync
 
-    cd ${OSTREE_ROOTFS}
-
     for d in var/*; do
       if [ "${d}" != "var/local" ]; then
         rm -rf ${d}
@@ -125,16 +137,11 @@ IMAGE_CMD_ostree () {
     # Copy image manifest
     cat ${IMAGE_MANIFEST} | cut -d " " -f1,3 > usr/package.manifest
 
-    cd ${WORKDIR}
-
     # Create a tarball that can be then commited to OSTree repo
-    OSTREE_TAR=${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ostree.tar.bz2
+    OSTREE_TAR=${IMGDEPLOYDIR}/${IMAGE_NAME}.rootfs.ostree.tar.bz2
     tar -C ${OSTREE_ROOTFS} --xattrs --xattrs-include='*' -cjf ${OSTREE_TAR} .
     sync
 
-    rm -f ${DEPLOY_DIR_IMAGE}/${IMAGE_LINK_NAME}.rootfs.ostree.tar.bz2
-    ln -s ${IMAGE_NAME}.rootfs.ostree.tar.bz2 ${DEPLOY_DIR_IMAGE}/${IMAGE_LINK_NAME}.rootfs.ostree.tar.bz2
-
     if ! ostree --repo=${OSTREE_REPO} refs 2>&1 > /dev/null; then
         ostree --repo=${OSTREE_REPO} init --mode=archive-z2
     fi
@@ -145,6 +152,4 @@ IMAGE_CMD_ostree () {
            --skip-if-unchanged \
            --branch=${OSTREE_BRANCHNAME} \
            --subject="Commit-id: ${IMAGE_NAME}"
-
-    rm -rf ${OSTREE_ROOTFS}
 }
diff --git a/classes/override_image_types_ota.inc b/classes/override_image_types_ota.inc
new file mode 100644
index 0000000..17508b2
--- /dev/null
+++ b/classes/override_image_types_ota.inc
@@ -0,0 +1,98 @@
+# overrides meta-updater/classes/image_types_ota.bbclass
+# - add do_image_otaimg flags:
+#   - dirs, cleandirs: to avoid mktemp, rm, cd, and to also remove at clean
+# - override of IMAGE_CMD_otaimg
+#   - use the added flags
+#   - avoid untar-ing the ostree image, and use OSTREE_ROOTFS
+#   - IMGDEPLOYDIR, instead of DEPLOY_DIR_IMAGE
+
+OSTREE_REPO = "${WORKDIR}/ostree-repo"
+PHYS_SYSROOT = "${WORKDIR}/ota-sysroot"
+
+do_image_otaimg[dirs] = "${PHYS_SYSROOT}"
+do_image_otaimg[cleandirs] = "${PHYS_SYSROOT}"
+
+IMAGE_CMD_otaimg () {
+        if ${@bb.utils.contains('IMAGE_FSTYPES', 'otaimg', 'true', 'false', d)}; then
+                if [ -z "$OSTREE_REPO" ]; then
+                        bbfatal "OSTREE_REPO should be set in your local.conf"
+                fi
+
+                if [ -z "$OSTREE_OSNAME" ]; then
+                        bbfatal "OSTREE_OSNAME should be set in your local.conf"
+                fi
+
+                if [ -z "$OSTREE_BRANCHNAME" ]; then
+                        bbfatal "OSTREE_BRANCHNAME should be set in your local.conf"
+                fi
+
+                ostree admin --sysroot=${PHYS_SYSROOT} init-fs ${PHYS_SYSROOT}
+                ostree admin --sysroot=${PHYS_SYSROOT} os-init ${OSTREE_OSNAME}
+
+                mkdir -p ${PHYS_SYSROOT}/boot/loader.0
+                ln -s loader.0 ${PHYS_SYSROOT}/boot/loader
+
+                if [ "${OSTREE_BOOTLOADER}" = "grub" ]; then
+                        mkdir -p ${PHYS_SYSROOT}/boot/grub2
+                        ln -s ../loader/grub.cfg ${PHYS_SYSROOT}/boot/grub2/grub.cfg
+                elif [ "${OSTREE_BOOTLOADER}" = "u-boot" ]; then
+                        touch ${PHYS_SYSROOT}/boot/loader/uEnv.txt
+                else
+                        bberror "Invalid bootloader: ${OSTREE_BOOTLOADER}"
+                fi;
+
+                ostree_target_hash=$(cat ${OSTREE_REPO}/refs/heads/${OSTREE_BRANCHNAME})
+
+                ostree --repo=${PHYS_SYSROOT}/ostree/repo pull-local --remote=${OSTREE_OSNAME} ${OSTREE_REPO} ${ostree_target_hash}
+                export OSTREE_BOOT_PARTITION="/boot"
+                kargs_list=""
+                for arg in ${OSTREE_KERNEL_ARGS}; do
+                        kargs_list="${kargs_list} --karg-append=$arg"
+                done
+
+                ostree admin --sysroot=${PHYS_SYSROOT} deploy ${kargs_list} --os=${OSTREE_OSNAME} ${ostree_target_hash}
+
+                cp -a ${IMAGE_ROOTFS}/var/sota ${PHYS_SYSROOT}/ostree/deploy/${OSTREE_OSNAME}/var/ || true
+                # Create /var/sota if it doesn't exist yet
+                mkdir -p ${PHYS_SYSROOT}/ostree/deploy/${OSTREE_OSNAME}/var/sota
+                # Ensure the permissions are correctly set
+                chmod 700 ${PHYS_SYSROOT}/ostree/deploy/${OSTREE_OSNAME}/var/sota
+
+                cp -a ${OSTREE_ROOTFS}/var/local ${PHYS_SYSROOT}/ostree/deploy/${OSTREE_OSNAME}/var/ || true
+                cp -a ${OSTREE_ROOTFS}/usr/homedirs/home ${PHYS_SYSROOT}/ || true
+                # Ensure that /var/local exists (AGL symlinks /usr/local to /var/local)
+                install -d ${PHYS_SYSROOT}/ostree/deploy/${OSTREE_OSNAME}/var/local
+                # Set package version for the first deployment
+                target_version=${ostree_target_hash}
+                if [ -n "${GARAGE_TARGET_VERSION}" ]; then
+                        target_version=${GARAGE_TARGET_VERSION}
+                elif [ -e "${STAGING_DATADIR_NATIVE}/target_version" ]; then
+                        target_version=$(cat "${STAGING_DATADIR_NATIVE}/target_version")
+                fi
+                mkdir -p ${PHYS_SYSROOT}/ostree/deploy/${OSTREE_OSNAME}/var/sota/import
+                echo "{\"${ostree_target_hash}\":\"${GARAGE_TARGET_NAME}-${target_version}\"}" > ${PHYS_SYSROOT}/ostree/deploy/${OSTREE_OSNAME}/var/sota/import/installed_versions
+
+                # Calculate image type
+                OTA_ROOTFS_SIZE=$(calculate_size `du -ks ${PHYS_SYSROOT} | cut -f 1`  "${IMAGE_OVERHEAD_FACTOR}" "${IMAGE_ROOTFS_SIZE}" "${IMAGE_ROOTFS_MAXSIZE}" `expr ${IMAGE_ROOTFS_EXTRA_SPACE}` "${IMAGE_ROOTFS_ALIGNMENT}")
+
+                if [ $OTA_ROOTFS_SIZE -lt 0 ]; then
+                        exit -1
+                fi
+                eval local COUNT=\"0\"
+                eval local MIN_COUNT=\"60\"
+                if [ $OTA_ROOTFS_SIZE -lt $MIN_COUNT ]; then
+                        eval COUNT=\"$MIN_COUNT\"
+                fi
+
+                # create image
+                dd if=/dev/zero of=${IMGDEPLOYDIR}/${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.otaimg seek=${OTA_ROOTFS_SIZE} count=${COUNT} bs=1024
+                mkfs.ext4 -O ^64bit ${IMGDEPLOYDIR}/${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.otaimg -L otaroot -d ${PHYS_SYSROOT}
+                rm -f ${DEPLOY_DIR_IMAGE}/${IMAGE_LINK_NAME}.otaimg
+                ln -s ${IMGDEPLOYDIR}/${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.otaimg ${DEPLOY_DIR_IMAGE}/${IMAGE_LINK_NAME}.otaimg
+                # for forward compatibility
+                rm -f ${DEPLOY_DIR_IMAGE}/${IMAGE_LINK_NAME}.ota-ext4
+                ln -s ${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.otaimg ${DEPLOY_DIR_IMAGE}/${IMAGE_LINK_NAME}.ota-ext4
+        fi
+}
+
+IMAGE_TYPEDEP_otaimg = "ostree"
diff --git a/classes/sota_atom-c3000.bbclass b/classes/sota_atom-c3000.bbclass
index f9b4864..dff4294 100644
--- a/classes/sota_atom-c3000.bbclass
+++ b/classes/sota_atom-c3000.bbclass
@@ -7,7 +7,7 @@ WKS_FILE_sota = "efiimage-sota.wks"
 OSTREE_INITRAMFS_FSTYPES ?= "ext4.gz"
 
 # Set .otaimg to be used as source for generating hddimg
-ROOTFS_sota = "${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.otaimg"
+ROOTFS_sota = "${IMGDEPLOYDIR}/${IMAGE_LINK_NAME}.otaimg"
 
 # OSTree initrd needs 'ramdisk_size' and 'rw' parameters in order to boot
 OSTREE_KERNEL_ARGS ?= "rw"
diff --git a/classes/sota_xeon-d.bbclass b/classes/sota_xeon-d.bbclass
index f9b4864..dff4294 100644
--- a/classes/sota_xeon-d.bbclass
+++ b/classes/sota_xeon-d.bbclass
@@ -7,7 +7,7 @@ WKS_FILE_sota = "efiimage-sota.wks"
 OSTREE_INITRAMFS_FSTYPES ?= "ext4.gz"
 
 # Set .otaimg to be used as source for generating hddimg
-ROOTFS_sota = "${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.otaimg"
+ROOTFS_sota = "${IMGDEPLOYDIR}/${IMAGE_LINK_NAME}.otaimg"
 
 # OSTree initrd needs 'ramdisk_size' and 'rw' parameters in order to boot
 OSTREE_KERNEL_ARGS ?= "rw"
diff --git a/images/enea-nfv-access-host-common.inc b/images/enea-nfv-access-host-common.inc
index ef6d3de..b2dd5a2 100644
--- a/images/enea-nfv-access-host-common.inc
+++ b/images/enea-nfv-access-host-common.inc
@@ -4,6 +4,7 @@ REQUIRE_FILES = " \
     "
 REQUIRE_FILES_append_df-efi-secure-boot = " \
     classes/override_image_types_ostree.inc \
+    classes/override_image_types_ota.inc \
     classes/override_grub-efi_secureboot.inc \
     images/secure-boot.inc \
     "