memcached: update and move from meta-openstack to main layer

memcached is a general-purpose caching system, not OpenStack-specific.

We also:
  - refresh hugetlbfs patch for 1.6.41
  - 1.6.x configure.ac uses pkg-config macros (AS_IF, AC_CACHE_CHECK) that require pkg.m4 from pkgconfig-native.
  - fix WORKDIR -> UNPACKDIR for config file

Signed-off-by: Bruce Ashfield <bruce.ashfield@gmail.com>

3 files changed, 105 insertions, 0 deletions

diff --git a/recipes-support/memcached/memcached/memcached-add-hugetlbfs-check.patch b/recipes-support/memcached/memcached/memcached-add-hugetlbfs-check.patch
new file mode 100644
index 0000000..c7e2295
--- /dev/null
+++ b/recipes-support/memcached/memcached/memcached-add-hugetlbfs-check.patch
@@ -0,0 +1,30 @@
+memcached: add knob to detect whether hugetlbfs are checked
+
+Add knob to detect whether hugetlbfs are checked or not.
+
+Upstream-Status: Pending
+
+Signed-off-by: Chong Lu <Chong.Lu@windriver.com>
+[Bruce: refreshed for 1.6.41]
+Signed-off-by: Bruce Ashfield <bruce.ashfield@gmail.com>
+---
+ configure.ac | 7 ++++++-
+ 1 file changed, 6 insertions(+), 1 deletion(-)
+
+diff --git a/configure.ac b/configure.ac
+--- a/configure.ac
++++ b/configure.ac
+@@ -560,7 +560,12 @@ fi
+
+ dnl ----------------------------------------------------------------------------
+
+-AC_SEARCH_LIBS(gethugepagesizes, hugetlbfs)
++AC_ARG_ENABLE(hugetlbfs,
++  [AS_HELP_STRING([--enable-hugetlbfs],[Enable hugetlbfs])])
++
++if test "x$enable_hugetlbfs" = "xyes"; then
++  AC_SEARCH_LIBS(gethugepagesizes, hugetlbfs)
++fi
+
+ AC_HEADER_STDBOOL
+ AH_BOTTOM([#if HAVE_STDBOOL_H
diff --git a/recipes-support/memcached/memcached/memcached-config.txt b/recipes-support/memcached/memcached/memcached-config.txt
new file mode 100644
index 0000000..7e6441e
--- /dev/null
+++ b/recipes-support/memcached/memcached/memcached-config.txt
@@ -0,0 +1,5 @@
+PORT="11211"
+USER="nobody"
+MAXCONN="1024"
+CACHESIZE="64"
+OPTIONS=""
diff --git a/recipes-support/memcached/memcached_1.6.41.bb b/recipes-support/memcached/memcached_1.6.41.bb
new file mode 100644
index 0000000..b030ef1
--- /dev/null
+++ b/recipes-support/memcached/memcached_1.6.41.bb
@@ -0,0 +1,70 @@
+SUMMARY = "A high-performance memory object caching system"
+DESCRIPTION = "\
+ memcached optimizes specific high-load serving applications that are designed \
+ to take advantage of its versatile no-locking memory access system. Clients \
+ are available in several different programming languages, to suit the needs \
+ of the specific application. Traditionally this has been used in mod_perl \
+ apps to avoid storing large chunks of data in Apache memory, and to share \
+ this burden across several machines."
+SECTION = "web"
+HOMEPAGE = "http://memcached.org/"
+LICENSE = "BSD-3-Clause"
+
+LIC_FILES_CHKSUM = "file://COPYING;md5=7e5ded7363d335e1bb18013ca08046ff"
+
+inherit autotools pkgconfig systemd
+
+DEPENDS += "libevent"
+RDEPENDS:${PN} += "\
+    bash \
+    perl \
+    perl-module-posix \
+    perl-module-autoloader \
+    perl-module-tie-hash \
+    "
+
+SRC_URI = "http://www.memcached.org/files/${BP}.tar.gz \
+           file://memcached-add-hugetlbfs-check.patch \
+           file://memcached-config.txt \
+           "
+
+SRC_URI[md5sum] = "a9eb0848f052a5c0d18b4a314807dd5c"
+SRC_URI[sha256sum] = "e097073c156eeff9e12655b054f446d57374cfba5c132dcdbe7fac64e728286a"
+
+# set the same COMPATIBLE_HOST as libhugetlbfs
+COMPATIBLE_HOST = '(i.86|x86_64|powerpc|powerpc64|arm).*-linux'
+
+python __anonymous () {
+    endianness = d.getVar('SITEINFO_ENDIANNESS', True)
+    if endianness == 'le':
+        d.setVar('EXTRA_OECONF', "ac_cv_c_endian=little")
+    else:
+        d.setVar('EXTRA_OECONF', "ac_cv_c_endian=big")
+}
+
+PACKAGECONFIG ??= ""
+PACKAGECONFIG[hugetlbfs] = "--enable-hugetlbfs, --disable-hugetlbfs, libhugetlbfs"
+
+inherit update-rc.d
+
+INITSCRIPT_NAME = "memcached"
+INITSCRIPT_PARAMS = "defaults"
+
+SYSTEMD_PACKAGES = "memcached"
+SYSTEMD_SERVICE:${PN} = "memcached.service"
+
+do_install:append() {
+    install -D -m 755 ${S}/scripts/memcached-init ${D}${sysconfdir}/init.d/memcached
+    
+    mkdir -p ${D}/usr/share/memcached/scripts
+    install -m 755 ${S}/scripts/memcached-tool ${D}/usr/share/memcached/scripts
+    install -m 755 ${S}/scripts/start-memcached ${D}/usr/share/memcached/scripts
+
+    install -d ${D}/${sysconfdir}/default
+    install -m 600 ${UNPACKDIR}/memcached-config.txt ${D}/${sysconfdir}/default/memcached
+
+    install -d ${D}/${systemd_system_unitdir}
+    install -m 644 ${S}/scripts/memcached.service ${D}/${systemd_system_unitdir}/.
+    sed -e "s@^EnvironmentFile=.*@EnvironmentFile=${sysconfdir}/default/memcached@" \
+        -i ${D}/${systemd_system_unitdir}/memcached.service
+}