meta-openstack: add new python-avahi recipe

OE-core commit 36e9ed89950 ("avahi-ui: remove support for building a python
module") removed the python avahi bindings because nothing in OE-core used
them. These bindings are very useful however when configuring targets from
salt using the zeroconf protocol.

An added benefit of having a python-avahi recipe separate from avahi-ui is
that we don't need X11 in DISTRO_FEATURES anymore to use python-avahi, it's
just two simple python files, there was no need for all that complexity in
avahi-ui in the first place to get the python avahi bindings.

Signed-off-by: Ioan-Adrian Ratiu <adrian.ratiu@ni.com>
Signed-off-by: Bruce Ashfield <bruce.ashfield@windriver.com>

1 files changed, 34 insertions, 0 deletions

diff --git a/meta-openstack/recipes-devtools/python/python-avahi_0.6.32.bb b/meta-openstack/recipes-devtools/python/python-avahi_0.6.32.bb
new file mode 100644
index 0000000..c129337
--- /dev/null
+++ b/meta-openstack/recipes-devtools/python/python-avahi_0.6.32.bb
@@ -0,0 +1,34 @@
+SUMMARY = "Python bindings for the avahi zeroconf client"
+HOMEPAGE = "https://github.com/lathiat/avahi"
+SECTION = "devel/python"
+
+LICENSE = "GPLv2+"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=2d5025d4aa3495befef8f17206a5b0a1"
+
+SRC_URI = "https://github.com/lathiat/avahi/releases/download/v${PV}/avahi-${PV}.tar.gz"
+
+SRC_URI[md5sum] = "22b5e705d3eabb31d26f2e1e7b074013"
+SRC_URI[sha256sum] = "d54991185d514a0aba54ebeb408d7575b60f5818a772e28fa0e18b98bc1db454"
+
+S = "${WORKDIR}/avahi-${PV}"
+
+inherit python-dir pythonnative
+
+# we only need the python bindings
+do_install () {
+        install -d ${D}${PYTHON_SITEPACKAGES_DIR}/avahi
+
+        sed -i'' -e "s,@PYTHON\@,${bindir}/python,g" \
+                ${S}/avahi-python/avahi/__init__.py  \
+                ${S}/avahi-python/avahi-bookmarks.in
+
+        install -m 0775 ${S}/avahi-python/avahi/__init__.py \
+                ${D}${PYTHON_SITEPACKAGES_DIR}/avahi/__init__.py
+
+        install -m 0775 ${S}/avahi-python/avahi-bookmarks.in \
+                ${D}${PYTHON_SITEPACKAGES_DIR}/avahi/avahi-bookmarks
+}
+
+RDEPENDS_${PN} += "python-core python-dbus"
+
+FILES_${PN} = "${PYTHON_SITEPACKAGES_DIR}/avahi"