clang: Add recipes for cross-canadian and crosssdk variants

These are manipulating nativesdk clang to be used as SDK cross
compiler option

Signed-off-by: Khem Raj <raj.khem@gmail.com>

2 files changed, 59 insertions, 0 deletions

diff --git a/recipes-devtools/clang/clang-cross-canadian_git.bb b/recipes-devtools/clang/clang-cross-canadian_git.bb
new file mode 100644
index 0000000..b6e74fd
--- /dev/null
+++ b/recipes-devtools/clang/clang-cross-canadian_git.bb
@@ -0,0 +1,29 @@
+# Copyright (C) 2014 Khem Raj <raj.khem@gmail.com>
+# Released under the MIT license (see COPYING.MIT for the terms)
+
+DESCRIPTION = "Clang/LLVM based C/C++ compiler (cross-canadian for ${TARGET_ARCH} target)"
+HOMEPAGE = "http://clang.llvm.org/"
+LICENSE = "NCSA"
+LIC_FILES_CHKSUM = "file://${COREBASE}/meta/files/common-licenses/NCSA;md5=1b5fdec70ee13ad8a91667f16c1959d7"
+SECTION = "devel"
+
+PN = "clang-cross-canadian-${TRANSLATED_TARGET_ARCH}"
+
+require clang.inc
+inherit cross-canadian
+
+DEPENDS += "nativesdk-clang binutils-cross-canadian-${TRANSLATED_TARGET_ARCH} virtual/${HOST_PREFIX}binutils-crosssdk"
+# We have to point gcc at a sysroot but we don't need to rebuild if this changes
+# e.g. we switch between different machines with different tunes.
+EXTRA_OECONF_PATHS[vardepsexclude] = "TUNE_PKGARCH"
+TARGET_ARCH[vardepsexclude] = "TUNE_ARCH"
+
+S = "${WORKDIR}"
+
+do_install() {
+        install -d  ${D}${bindir}
+        ln -sf ../clang ${D}${bindir}/${TARGET_PREFIX}clang
+        ln -sf ../clang++ ${D}${bindir}/${TARGET_PREFIX}clang++
+}
+
+SSTATE_SCAN_FILES += "*-clang *-clang++"
diff --git a/recipes-devtools/clang/clang-crosssdk_git.bb b/recipes-devtools/clang/clang-crosssdk_git.bb
new file mode 100644
index 0000000..375f767
--- /dev/null
+++ b/recipes-devtools/clang/clang-crosssdk_git.bb
@@ -0,0 +1,30 @@
+# Copyright (C) 2014 Khem Raj <raj.khem@gmail.com>
+# Released under the MIT license (see COPYING.MIT for the terms)
+
+DESCRIPTION = "SDK Cross compiler wrappers for LLVM based C/C++ compiler"
+HOMEPAGE = "http://clang.llvm.org/"
+LICENSE = "NCSA"
+LIC_FILES_CHKSUM = "file://${COREBASE}/meta/files/common-licenses/NCSA;md5=1b5fdec70ee13ad8a91667f16c1959d7"
+SECTION = "devel"
+
+PN = "clang-crosssdk-${TARGET_ARCH}"
+
+require clang.inc
+inherit crosssdk
+DEPENDS += "nativesdk-clang binutils-crosssdk-${TARGET_ARCH}"
+
+S = "${WORKDIR}"
+
+do_install() {
+        install -d  ${D}${bindir}
+        ln -sf ../clang ${D}${bindir}/${TARGET_PREFIX}clang
+        ln -sf ../clang++ ${D}${bindir}/${TARGET_PREFIX}clang++
+}
+
+SYSROOT_PREPROCESS_FUNCS += "clangcrosssdk_sysroot_preprocess"
+
+clangcrosssdk_sysroot_preprocess () {
+        sysroot_stage_dir ${D}${bindir_crossscripts} ${SYSROOT_DESTDIR}${bindir}
+}
+SSTATE_SCAN_FILES += "*-clang *-clang++"
+PACKAGES = ""