blob: 6da76a30538cc43917ac61577ced0516a63c8160 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
SUMMARY = "Virtual terminal emulator GTK+ widget library"
DESCRIPTION = "VTE provides a virtual terminal widget for GTK applications."
HOMEPAGE = "https://wiki.gnome.org/Apps/Terminal/VTE"
BUGTRACKER = "https://bugzilla.gnome.org/buglist.cgi?product=vte"
LICENSE = "GPL-3.0-only & LGPL-3.0-or-later & MIT"
LICENSE:libvte = "LGPL-3.0-or-later"
LIC_FILES_CHKSUM = " \
file://COPYING.GPL3;md5=cc702cf3444d1f19680c794cc61948f9 \
file://COPYING.LGPL3;md5=b52f2d57d10c4f7ee67a7eb9615d5d24 \
file://COPYING.XTERM;md5=d7fc3a23c16c039afafe2e042030f057 \
"
DEPENDS = "glib-2.0 gtk+3 libpcre2 libxml2-native gperf-native icu"
GNOMEBASEBUILDCLASS = "meson"
GIR_MESON_OPTION = 'gir'
GIDOCGEN_MESON_OPTION = "docs"
inherit gnomebase gi-docgen features_check upstream-version-is-even gobject-introspection
# vapigen.m4 is required when vala is not present (but the one from vala should be used normally)
SRC_URI += "file://0001-Add-W_EXITCODE-macro-for-non-glibc-systems.patch \
file://0001-vtepty.cc-Do-not-typecast-to-GSpawnFlags.patch"
SRC_URI[archive.sha256sum] = "9457134a02f3157fca04f7e0d39bdb0f3099be0a3ce82b7139d0c98a80748f23"
ANY_OF_DISTRO_FEATURES = "${GTK3DISTROFEATURES}"
# Help g-ir-scanner find the .so for linking
do_compile:prepend() {
export GIR_EXTRA_LIBS_PATH="${B}/src/.libs"
}
# Package additional files
FILES:${PN}-dev += "${datadir}/vala/vapi/*"
PACKAGECONFIG ??= "gnutls"
PACKAGECONFIG[vala] = "-Dvapi=true,-Dvapi=false,vala-native vala"
PACKAGECONFIG[gnutls] = "-Dgnutls=true,-Dgnutls=false,gnutls"
PACKAGECONFIG[systemd] = "-D_systemd=true,-D_systemd=false,systemd"
# vala requires gir
PACKAGECONFIG:remove:class-native = "vala"
CFLAGS += "-D_GNU_SOURCE"
PACKAGES =+ "libvte ${PN}-prompt"
FILES:libvte = "${libdir}/*.so.* ${libdir}/girepository-1.0/*"
FILES:${PN}-prompt = " \
${sysconfdir}/profile.d \
${libexecdir}/vte-urlencode-cwd \
"
FILES:${PN}-dev += "${datadir}/glade/"
BBCLASSEXTEND = "native nativesdk"
|
