summaryrefslogtreecommitdiffstats
path: root/meta/recipes-gnome/gtk-engines/gtk-engines_2.20.2.bb
blob: 233a6ee773601bbeb23447904b6550d60133edc7 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
DESCRIPTION = "GTK theme engines"
HOMEPAGE = "http://www.gnome.org/"
BUGTRACKER = "https://bugzilla.gnome.org/"

LICENSE = "LGPLv2.1"
LIC_FILES_CHKSUM = "file://COPYING;md5=2d5025d4aa3495befef8f17206a5b0a1"

SECTION = "x11/base"
DEPENDS = "gtk+"

PR = "r1"

PACKAGES_DYNAMIC = "gtk-engine-* gtk-theme-*"

RDEPENDS_gtk-theme-redmond = "gtk-engine-redmond95"
RDEPENDS_gtk-theme-metal = "gtk-engine-metal"
RDEPENDS_gtk-theme-mist = "gtk-engine-mist"
RDEPENDS_gtk-theme-crux = "gtk-engine-crux-engine"
RDEPENDS_gtk-theme-lighthouseblue = "gtk-engine-lighthouseblue"
RDEPENDS_gtk-theme-thinice = "gtk-engine-thinice"
RDEPENDS_gtk-theme-industrial = "gtk-engine-industrial"
RDEPENDS_gtk-theme-clearlooks = "gtk-engine-clearlooks"

FILES_${PN}-dev += "${libdir}/gtk-2.0/*/engines/*.la"
FILES_${PN}-dbg += "${libdir}/gtk-2.0/*/engines/.debug"

CFLAGS_prepend = "-DHAVE_ANIMATION "

inherit gnome

python populate_packages_prepend() {
	import os.path

	engines_root = os.path.join(d.getVar('libdir', 1), "gtk-2.0/2.10.0/engines")
	themes_root = os.path.join(d.getVar('datadir', 1), "themes")

	do_split_packages(d, engines_root, '^lib(.*)\.so$', 'gtk-engine-%s', 'GTK %s theme engine', extra_depends='')
	do_split_packages(d, themes_root, '(.*)', 'gtk-theme-%s', 'GTK theme %s', allow_dirs=True, extra_depends='')
	# TODO: mark theme packages as arch all
}

SRC_URI[archive.md5sum] = "5deb287bc6075dc21812130604c7dc4f"
SRC_URI[archive.sha256sum] = "15b680abca6c773ecb85253521fa100dd3b8549befeecc7595b10209d62d66b5"