1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
|
SUMMARY = "Image loading library for GTK+"
HOMEPAGE = "http://www.gtk.org/"
BUGTRACKER = "https://bugzilla.gnome.org/"
LICENSE = "LGPLv2"
LIC_FILES_CHKSUM = "file://COPYING;md5=3bf50002aefd002f49e7bb854063f7e7 \
file://gdk-pixbuf/gdk-pixbuf.h;endline=26;md5=72b39da7cbdde2e665329fef618e1d6b"
SECTION = "libs"
DEPENDS = "glib-2.0 gdk-pixbuf-native shared-mime-info"
MAJ_VER = "${@oe.utils.trim_version("${PV}", 2)}"
SRC_URI = "${GNOME_MIRROR}/${BPN}/${MAJ_VER}/${BPN}-${PV}.tar.xz \
file://run-ptest \
file://fatal-loader.patch \
file://0001-Work-around-thumbnailer-cross-compile-failure.patch \
file://0001-Fix-a-couple-of-decisions-around-cross-compilation.patch \
file://0001-loaders.cache-depend-on-loaders-being-fully-build.patch \
"
SRC_URI_append_class-target = " \
file://0002-Work-around-thumbnailer-cross-compile-failure.patch \
"
SRC_URI_append_class-nativesdk = " \
file://0002-Work-around-thumbnailer-cross-compile-failure.patch \
file://0001-Disable-tests-in-native-builds.patch \
"
SRC_URI_append_class-native = " \
file://0001-Disable-tests-in-native-builds.patch \
"
SRC_URI[md5sum] = "6e84e5485c17ce7c25df77fe76eb2d6a"
SRC_URI[sha256sum] = "ae62ab87250413156ed72ef756347b10208c00e76b222d82d9ed361ed9dde2f3"
inherit meson pkgconfig gettext pixbufcache ptest-gnome upstream-version-is-even gobject-introspection gtk-doc lib_package
GTKDOC_ENABLE_FLAG = "-Dwith_docs=true"
GTKDOC_DISABLE_FLAG = "-Dwith_docs=false"
GI_ENABLE_FLAG = "-Dwith_gir=true"
GI_DISABLE_FLAG = "-Dwith_gir=false"
EXTRA_OEMESON_append_class-nativesdk = " ${GI_DISABLE_FLAG}"
EXTRA_OEMESON_append_class-target = " ${@bb.utils.contains('GI_DATA_ENABLED', 'True', '${GI_ENABLE_FLAG}', \
'${GI_DISABLE_FLAG}', d)} "
EXTRA_OEMESON_append_class-target = " ${@bb.utils.contains('GTKDOC_ENABLED', 'True', '${GTKDOC_ENABLE_FLAG}', \
'${GTKDOC_DISABLE_FLAG}', d)} "
LIBV = "2.10.0"
GDK_PIXBUF_LOADERS ?= "png jpeg"
PACKAGECONFIG ??= "${GDK_PIXBUF_LOADERS}"
PACKAGECONFIG_linuxstdbase = "${@bb.utils.filter('DISTRO_FEATURES', 'x11', d)} ${GDK_PIXBUF_LOADERS}"
PACKAGECONFIG_class-native = "${GDK_PIXBUF_LOADERS}"
PACKAGECONFIG[png] = "-Denable_png=true,-Denable_png=false,libpng"
PACKAGECONFIG[jpeg] = "-Denable_jpeg=true,-Denable_jpeg=false,jpeg"
PACKAGECONFIG[tiff] = "-Denable_tiff=true,-Denable_tiff=false,tiff"
PACKAGECONFIG[jpeg2000] = "-Denable_jasper=true,-Denable_jasper=false,jasper"
PACKAGECONFIG[x11] = ",,virtual/libx11"
PACKAGES =+ "${PN}-xlib"
# For GIO image type sniffing
RDEPENDS_${PN} = "shared-mime-info"
FILES_${PN}-xlib = "${libdir}/*pixbuf_xlib*${SOLIBS}"
ALLOW_EMPTY_${PN}-xlib = "1"
FILES_${PN} += "${libdir}/gdk-pixbuf-2.0/gdk-pixbuf-query-loaders"
FILES_${PN}-bin += "${datadir}/thumbnailers/gdk-pixbuf-thumbnailer.thumbnailer"
FILES_${PN}-dev += " \
${bindir}/gdk-pixbuf-csource \
${bindir}/gdk-pixbuf-pixdata \
${bindir}/gdk-pixbuf-print-mime-types \
${includedir}/* \
${libdir}/gdk-pixbuf-2.0/${LIBV}/loaders/*.la \
"
PACKAGES_DYNAMIC += "^gdk-pixbuf-loader-.*"
PACKAGES_DYNAMIC_class-native = ""
python populate_packages_prepend () {
postinst_pixbufloader = d.getVar("postinst_pixbufloader")
loaders_root = d.expand('${libdir}/gdk-pixbuf-2.0/${LIBV}/loaders')
packages = ' '.join(do_split_packages(d, loaders_root, r'^libpixbufloader-(.*)\.so$', 'gdk-pixbuf-loader-%s', 'GDK pixbuf loader for %s'))
d.setVar('PIXBUF_PACKAGES', packages)
# The test suite exercises all the loaders, so ensure they are all
# dependencies of the ptest package.
d.appendVar("RDEPENDS_%s-ptest" % d.getVar('PN'), " " + packages)
}
do_install_append() {
# Move gdk-pixbuf-query-loaders into libdir so it is always available
# in multilib builds.
mv ${D}/${bindir}/gdk-pixbuf-query-loaders ${D}/${libdir}/gdk-pixbuf-2.0/
# Do not install ptests if ptest is not enabled; gdk-pixbuf has no configuration option for this
if [ "${PTEST_ENABLED}" != "1" ]; then
rm -rf ${D}${datadir}/installed-tests
fi
}
do_install_append_class-native() {
find ${D}${libdir} -name "libpixbufloader-*.la" -exec rm \{\} \;
create_wrapper ${D}/${bindir}/gdk-pixbuf-csource \
GDK_PIXBUF_MODULE_FILE=${STAGING_LIBDIR_NATIVE}/gdk-pixbuf-2.0/${LIBV}/loaders.cache
create_wrapper ${D}/${bindir}/gdk-pixbuf-pixdata \
GDK_PIXBUF_MODULE_FILE=${STAGING_LIBDIR_NATIVE}/gdk-pixbuf-2.0/${LIBV}/loaders.cache
create_wrapper ${D}/${bindir}/gdk-pixbuf-print-mime-types \
GDK_PIXBUF_MODULE_FILE=${STAGING_LIBDIR_NATIVE}/gdk-pixbuf-2.0/${LIBV}/loaders.cache
create_wrapper ${D}/${libdir}/gdk-pixbuf-2.0/gdk-pixbuf-query-loaders \
GDK_PIXBUF_MODULE_FILE=${STAGING_LIBDIR_NATIVE}/gdk-pixbuf-2.0/${LIBV}/loaders.cache \
GDK_PIXBUF_MODULEDIR=${STAGING_LIBDIR_NATIVE}/gdk-pixbuf-2.0/${LIBV}/loaders
}
BBCLASSEXTEND = "native nativesdk"
|