blob: b990ce93c45070dd7ec29ed6319474885f36c52e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
SUMMARY = "GNU awk text processing utility"
DESCRIPTION = "The GNU version of awk, a text processing utility. \
Awk interprets a special-purpose programming language to do \
quick and easy text pattern matching and reformatting jobs."
HOMEPAGE = "www.gnu.org/software/gawk"
BUGTRACKER = "bug-gawk@gnu.org"
SECTION = "console/utils"
# gawk <= 3.1.5: GPLv2
# gawk >= 3.1.6: GPLv3
LICENSE = "GPLv3"
LIC_FILES_CHKSUM = "file://COPYING;md5=d32239bcb673463ab874e80d47fae504"
DEPENDS += "readline"
RDEPENDS_gawk += "gawk-common"
RDEPENDS_pgawk += "gawk-common"
SRC_URI = "${GNU_MIRROR}/gawk/gawk-${PV}.tar.gz \
file://run-ptest \
"
SRC_URI[md5sum] = "45f5b09aa87b4744c4c53bf274e96ed0"
SRC_URI[sha256sum] = "556464bd2e4bc5a0fad4526b59623e4be40b4c2f4c663dfaaf246af6e2ec1d62"
inherit autotools gettext texinfo update-alternatives
PACKAGES += "gawk-common pgawk dgawk"
FILES_${PN} = "${bindir}/gawk* ${bindir}/igawk"
FILES_gawk-common += "${datadir}/awk/* ${libexecdir}/awk/* ${libdir}/${BPN}/*.so"
FILES_pgawk = "${bindir}/pgawk*"
FILES_${PN}-dev += "${libdir}/${BPN}/*.la"
FILES_${PN}-dbg += "${libexecdir}/awk/.debug"
FILES_dgawk = "${bindir}/dgawk*"
ALTERNATIVE_${PN} = "awk"
ALTERNATIVE_TARGET[awk] = "${bindir}/gawk"
ALTERNATIVE_PRIORITY = "100"
do_install_append() {
# remove the link since we don't package it
rm ${D}${bindir}/awk
}
inherit ptest
do_install_ptest() {
mkdir ${D}${PTEST_PATH}/test
for i in `grep -vE "@|^$|#|Gt-dummy" ${S}/test/Maketests |awk -F: '{print $1}'` Maketests; \
do cp ${S}/test/$i* ${D}${PTEST_PATH}/test; \
done
}
|
