summaryrefslogtreecommitdiffstats
path: root/meta/recipes-extended/cpio/cpio_v2.inc
blob: b571986ef77ab0863bd036bf03b1729b824d91f4 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
DESCRIPTION = "GNU cpio is a program to manage archives of files"
HOMEPAGE = "http://www.gnu.org/software/cpio/"
SECTION = "base"

DEPENDS = "texinfo-native"

SRC_URI = "${GNU_MIRROR}/cpio/cpio-${PV}.tar.gz \
    file://statdef.patch \
    "

inherit autotools gettext

S = "${WORKDIR}/cpio-${PV}"

do_install () {
    autotools_do_install
    install -d ${D}${base_bindir}/
    mv "${D}${bindir}/cpio" "${D}${base_bindir}/cpio.${PN}"
    case ${TARGET_OS} in
        *-uclibc*) ;;
        *) mv "${D}${libexecdir}/rmt" "${D}${libexecdir}/rmt.${PN}" ;;
    esac
}

pkg_postinst_${PN} () {
    update-alternatives --install ${base_bindir}/cpio cpio cpio.${PN} 100
    if [ -f ${libexecdir}/rmt.${PN} ]
    then
        update-alternatives --install ${libexecdir}/rmt rmt rmt.${PN} 50
    fi
}

pkg_prerm_${PN} () {
    update-alternatives --remove cpio cpio.${PN}
    if [ -f ${libexecdir}/rmt.${PN} ]
    then
        update-alternatives --remove rmt rmt.${PN}
    fi
}