blob: 1630c1282356d73af800f964dda57ef3bb09dba9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
SUMMARY = "gnu-configize"
DESCRIPTION = "Tool that installs the GNU config.guess / config.sub into a directory tree"
SECTION = "devel"
LICENSE = "GPL-3.0-with-autoconf-exception"
LIC_FILES_CHKSUM = "file://config.guess;beginline=7;endline=27;md5=b75d42f59f706ea56d6a8e00216fca6a"
DEPENDS_class-native = "hostperl-runtime-native"
INHIBIT_DEFAULT_DEPS = "1"
SRCREV = "b98424c249119b79d3f709e26eb86f2fd4d5e5f3"
PV = "20190501+git${SRCPV}"
SRC_URI = "git://git.savannah.gnu.org/config.git \
file://gnu-configize.in"
S = "${WORKDIR}/git"
UPSTREAM_CHECK_COMMITS = "1"
CLEANBROKEN = "1"
do_compile[noexec] = "1"
do_install () {
install -d ${D}${datadir}/gnu-config \
${D}${bindir}
cat ${WORKDIR}/gnu-configize.in | \
sed -e 's,@gnu-configdir@,${datadir}/gnu-config,g' \
-e 's,@autom4te_perllibdir@,${datadir}/autoconf,g' > ${D}${bindir}/gnu-configize
# In the native case we want the system perl as perl-native can't have built yet
if [ "${PN}" != "gnu-config-native" -a "${PN}" != "nativesdk-gnu-config" ]; then
sed -i -e 's,/usr/bin/env,${bindir}/env,g' ${D}${bindir}/gnu-configize
fi
chmod 755 ${D}${bindir}/gnu-configize
install -m 0644 config.guess config.sub ${D}${datadir}/gnu-config/
}
PACKAGES = "${PN}"
FILES_${PN} = "${bindir} ${datadir}/gnu-config"
BBCLASSEXTEND = "native nativesdk"
|
