blob: 0645193803d8b55a550d55d0f84ceb4720dbfc24 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
|
DESCRIPTION = "A Client for Wi-Fi Protected Access (WPA)."
HOMEPAGE = "http://hostap.epitest.fi/wpa_supplicant/"
BUGTRACKER = "http://hostap.epitest.fi/bugz/"
SECTION = "network"
LICENSE = "GPLv2 | BSD"
LIC_FILES_CHKSUM = "file://../COPYING;md5=c54ce9345727175ff66d17b67ff51f58 \
file://../README;md5=9bee93996fecdb70f807baceb29d84b9 \
file://wpa_supplicant.c;beginline=1;endline=17;md5=372fb65dc23b228aec4e40e64de3e467"
DEPENDS = "gnutls dbus libnl"
RRECOMMENDS_${PN} = "wpa-supplicant-passphrase wpa-supplicant-cli"
SRC_URI = "http://hostap.epitest.fi/releases/wpa_supplicant-${PV}.tar.gz \
file://defconfig-gnutls \
file://wpa-supplicant.sh \
file://wpa_supplicant.conf \
file://wpa_supplicant.conf-sane \
file://99_wpa_supplicant"
S = "${WORKDIR}/wpa_supplicant-${PV}/wpa_supplicant"
PACKAGES_prepend = "wpa-supplicant-passphrase wpa-supplicant-cli "
FILES_wpa-supplicant-passphrase = "${bindir}/wpa_passphrase"
FILES_wpa-supplicant-cli = "${sbindir}/wpa_cli"
FILES_${PN} += "${datadir}/dbus-1/system-services/* ${systemd_unitdir}/system/*"
CONFFILES_${PN} += "${sysconfdir}/wpa_supplicant.conf"
do_configure () {
echo "CFLAGS +=\"-I${STAGING_INCDIR}/libnl3\"" >> ${WORKDIR}/defconfig-gnutls
install -m 0755 ${WORKDIR}/defconfig-gnutls .config
}
export EXTRA_CFLAGS = "${CFLAGS}"
export BINDIR = "${sbindir}"
do_compile () {
unset CFLAGS CPPFLAGS CXXFLAGS
oe_runmake
}
do_install () {
install -d ${D}${sbindir}
install -m 755 wpa_supplicant ${D}${sbindir}
install -m 755 wpa_cli ${D}${sbindir}
install -d ${D}${bindir}
install -m 755 wpa_passphrase ${D}${bindir}
install -d ${D}${docdir}/wpa_supplicant
install -m 644 README ${WORKDIR}/wpa_supplicant.conf ${D}${docdir}/wpa_supplicant
install -d ${D}${sysconfdir}
install -m 600 ${WORKDIR}/wpa_supplicant.conf-sane ${D}${sysconfdir}/wpa_supplicant.conf
install -d ${D}${sysconfdir}/network/if-pre-up.d/
install -d ${D}${sysconfdir}/network/if-post-down.d/
install -d ${D}${sysconfdir}/network/if-down.d/
install -m 755 ${WORKDIR}/wpa-supplicant.sh ${D}${sysconfdir}/network/if-pre-up.d/wpa-supplicant
cd ${D}${sysconfdir}/network/ && \
ln -sf ../if-pre-up.d/wpa-supplicant if-post-down.d/wpa-supplicant
install -d ${D}/${sysconfdir}/dbus-1/system.d
install -m 644 ${S}/dbus/dbus-wpa_supplicant.conf ${D}/${sysconfdir}/dbus-1/system.d
install -d ${D}/${datadir}/dbus-1/system-services
install -m 644 ${S}/dbus/*.service ${D}/${datadir}/dbus-1/system-services
install -d ${D}/${systemd_unitdir}/system
install -m 644 ${S}/systemd/wpa_supplicant.service ${D}/${systemd_unitdir}/system
install -d ${D}/etc/default/volatiles
install -m 0644 ${WORKDIR}/99_wpa_supplicant ${D}/etc/default/volatiles
}
pkg_postinst_wpa-supplicant () {
# If we're offline, we don't need to do this.
if [ "x$D" != "x" ]; then
exit 0
fi
DBUSPID=`pidof dbus-daemon`
if [ "x$DBUSPID" != "x" ]; then
/etc/init.d/dbus-1 reload || true
fi
}
|
