blob: c684b8348e5fded26cafc7cbe6dc2271c8f90535 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
|
SUMMARY = "Gummiboot is a simple UEFI boot manager which executes configured EFI images."
HOMEPAGE = "http://freedesktop.org/wiki/Software/gummiboot"
LICENSE = "LGPLv2.1"
LIC_FILES_CHKSUM = "file://LICENSE;md5=4fbd65380cdd255951079008b364516c"
DEPENDS = "gnu-efi util-linux"
inherit autotools pkgconfig manpages
inherit deploy
PV = "48+git${SRCPV}"
SRCREV = "2bcd919c681c952eb867ef1bdb458f1bc49c2d55"
SRC_URI = "git://anongit.freedesktop.org/gummiboot \
file://fix-objcopy.patch \
file://0001-console-Fix-C-syntax-errors-for-function-declaration.patch \
"
PACKAGECONFIG[manpages] = "--enable-manpages, --disable-manpages, libxslt-native xmlto-native"
# Note: Add COMPATIBLE_HOST here is only because it depends on gnu-efi
# which has set the COMPATIBLE_HOST, the gummiboot itself may work on
# more hosts.
COMPATIBLE_HOST = "(x86_64.*|i.86.*)-linux"
S = "${WORKDIR}/git"
EXTRA_OECONF = "--with-efi-includedir=${STAGING_INCDIR} \
--with-efi-ldsdir=${STAGING_LIBDIR} \
--with-efi-libdir=${STAGING_LIBDIR}"
EXTRA_OEMAKE += "gummibootlibdir=${libdir}/gummiboot"
TUNE_CCARGS_remove = "-mfpmath=sse"
do_deploy () {
install ${B}/gummiboot*.efi ${DEPLOYDIR}
}
addtask deploy before do_build after do_compile
|
