From 36a71a9c620e4a9510725af3a9e731e6529f744c Mon Sep 17 00:00:00 2001
From: Jorn Baayen <jorn@openedhand.com>
Date: Thu, 20 Jul 2006 10:52:14 +0000
Subject: added pango 1.13.3

git-svn-id: https://svn.o-hand.com/repos/poky/trunk@518 311d38ba-8fff-0310-9ca6-ca027cbcb966
---
 openembedded/packages/pango/pango_1.13.3.bb | 49 +++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)
 create mode 100644 openembedded/packages/pango/pango_1.13.3.bb

(limited to 'openembedded')

diff --git a/openembedded/packages/pango/pango_1.13.3.bb b/openembedded/packages/pango/pango_1.13.3.bb
new file mode 100644
index 0000000000..de6346b1cb
--- /dev/null
+++ b/openembedded/packages/pango/pango_1.13.3.bb
@@ -0,0 +1,49 @@
+LICENSE = "LGPL"
+SECTION = "x11/libs"
+# Xt needed to keep autoconf's check for X11 happy
+DEPENDS = "glib-2.0 fontconfig freetype zlib libx11 libxft libxt gtk-doc cairo"
+DESCRIPTION = "The goal of the Pango project is to provide an \
+Open Source framework for the layout and rendering of \
+internationalized text."
+PR = "r0"
+
+# seems to go wrong with default cflags
+FULL_OPTIMIZATION_arm = "-O2"
+
+SRC_URI = "http://download.gnome.org/sources/pango/1.13/pango-${PV}.tar.bz2 \
+	   file://no-tests.patch;patch=1"
+
+inherit autotools pkgconfig
+
+EXTRA_OECONF = "--disable-glibtest \
+		--enable-explicit-deps=no \
+	        --disable-debug"
+
+FILES_${PN} = "/etc ${bindir} ${libdir}/libpango*.so.*"
+
+LIBV = "1.5.0"
+
+do_stage () {
+	for lib in pango pangox pangoft2 pangoxft pangocairo; do
+		oe_libinstall -so -C pango lib$lib-1.0 ${STAGING_LIBDIR}/
+	done
+	install -d ${STAGING_INCDIR}/pango
+	install -m 0644 ${S}/pango/pango*.h ${STAGING_INCDIR}/pango/
+}
+
+postinst_prologue() {
+if [ "x$D" != "x" ]; then
+  exit 1
+fi
+
+}
+
+PACKAGES_DYNAMIC = "pango-module-*"
+
+python populate_packages_prepend () {
+	prologue = bb.data.getVar("postinst_prologue", d, 1)
+
+	modules_root = bb.data.expand('${libdir}/pango/${LIBV}/modules', d)
+
+	do_split_packages(d, modules_root, '^pango-(.*)\.so$', 'pango-module-%s', 'Pango module %s', prologue + 'pango-querymodules > /etc/pango/pango.modules')
+}
-- 
cgit v1.2.3-54-g00ecf