From 954a0bf236bf04455b4d4e0daa69fa2fa713a4ae Mon Sep 17 00:00:00 2001
From: Saul Wold <sgw@linux.intel.com>
Date: Thu, 2 Feb 2012 10:17:52 -0800
Subject: rxvt-unicode: Update to 9.15

(From OE-Core rev: 75789868df9cfc5cb74edfc3fe7d773cfa272ce6)

Signed-off-by: Saul Wold <sgw@linux.intel.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
---
 .../recipes-sato/rxvt-unicode/rxvt-unicode_9.15.bb | 68 ++++++++++++++++++++++
 1 file changed, 68 insertions(+)
 create mode 100644 meta/recipes-sato/rxvt-unicode/rxvt-unicode_9.15.bb

(limited to 'meta/recipes-sato/rxvt-unicode/rxvt-unicode_9.15.bb')

diff --git a/meta/recipes-sato/rxvt-unicode/rxvt-unicode_9.15.bb b/meta/recipes-sato/rxvt-unicode/rxvt-unicode_9.15.bb
new file mode 100644
index 0000000000..2415ba53c4
--- /dev/null
+++ b/meta/recipes-sato/rxvt-unicode/rxvt-unicode_9.15.bb
@@ -0,0 +1,68 @@
+SECTION = "x11/utils"
+DESCRIPTION = "rxvt-unicode is a clone of the well known \
+terminal emulator rxvt, modified to store text in Unicode \
+(either UCS-2 or UCS-4) and to use locale-correct input and \
+output. It also supports mixing multiple fonts at the \
+same time, including Xft fonts."
+LICENSE = "GPLv2+"
+LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263 \
+                    file://src/main.C;beginline=1;endline=31;md5=775485398a09fa7aee6f90464af88432"
+
+DEPENDS = "virtual/libx11 libxt libxft gdk-pixbuf"
+
+PR = "r0"
+
+SRC_URI = "http://dist.schmorp.de/rxvt-unicode/Attic/rxvt-unicode-${PV}.tar.bz2 \
+	   file://xwc.patch \
+	   file://rxvt.desktop \
+	   file://rxvt.png"
+
+SRC_URI[md5sum] = "15595aa326167ac5eb68c28d95432faf"
+SRC_URI[sha256sum] = "ec1aa2932da844979ed8140bd92223defb12042aa5e877e05ac31139ca81f2b1"
+
+inherit autotools update-alternatives
+
+PROVIDES = "virtual/x-terminal-emulator"
+ALTERNATIVE_NAME = "x-terminal-emulator"
+ALTERNATIVE_PATH = "${bindir}/rxvt"
+
+CFLAGS_append = " -fpermissive"
+
+# This is necessary so that the "tic" command executed during the install can
+# link with the correct libary in staging.
+export LD_LIBRARY_PATH = "${STAGING_LIBDIR_NATIVE}"
+
+EXTRA_OECONF = "--enable-menubar --enable-xim \
+		--enable-utmp --enable-wtmp --enable-lastlog \
+		--disable-strings --with-term=rxvt --enable-keepscrolling \
+		--enable-xft --with-name=rxvt --enable-frills \
+		--enable-swapscreen --enable-transparency \
+		--with-codesets=eu \
+		--enable-cursor-blink --enable-pointer-blank \
+		--enable-text-blink --enable-rxvt-scroll \
+		--enable-combining --enable-shared \
+		--enable-xgetdefault \
+                --disable-perl \
+		--with-x=${STAGING_DIR_HOST}${prefix}"
+
+do_configure_prepend () {
+	cp aclocal.m4 acinclude.m4
+}
+
+do_compile_prepend () {
+	echo '#define UTMP_FILE "${localstatedir}/run/utmp"' >> config.h
+	echo '#define WTMP_FILE "${localstatedir}/log/wtmp"' >> config.h
+	echo '#define LASTLOG_FILE "${localstatedir}/log/lastlog"' >> config.h
+	echo '#define HAVE_XLOCALE 1' >> config.h
+}
+
+do_install_append () {
+	install -d ${D}/${datadir}
+	install -d ${D}/${datadir}/applications
+	install -d ${D}/${datadir}/pixmaps/
+
+	install -m 0644 ${WORKDIR}/rxvt.png ${D}/${datadir}/pixmaps
+	install -m 0644 ${WORKDIR}/rxvt.desktop ${D}/${datadir}/applications
+}
+
+FILES_${PN} += "${datadir}/applications/rxvt.desktop ${datadir}/pixmaps/rxvt.png"
-- 
cgit v1.2.3-54-g00ecf