From 1b26bce9675f1beb3d0370f49fc5ed9709c979f6 Mon Sep 17 00:00:00 2001
From: Zhai Edwin <edwin.zhai@intel.com>
Date: Wed, 26 Jan 2011 19:14:35 +0800
Subject: matchbox: Convert all the matchbox components' repo from svn to git
 including: matchbox-wm matchbox-panel-2 matchbox-terminal matchbox-config-gtk
 matchbox-stroke matchbox-desktop matchbox-keyboard matchbox-themes-extra
 libfakekey settings-daemon

Also remove some old recipes.

Signed-off-by: Zhai Edwin <edwin.zhai@intel.com>
---
 .../matchbox-keyboard/matchbox-keyboard_git.bb     | 61 ++++++++++++++++++++++
 1 file changed, 61 insertions(+)
 create mode 100644 meta/recipes-sato/matchbox-keyboard/matchbox-keyboard_git.bb

(limited to 'meta/recipes-sato/matchbox-keyboard/matchbox-keyboard_git.bb')

diff --git a/meta/recipes-sato/matchbox-keyboard/matchbox-keyboard_git.bb b/meta/recipes-sato/matchbox-keyboard/matchbox-keyboard_git.bb
new file mode 100644
index 0000000000..245f999335
--- /dev/null
+++ b/meta/recipes-sato/matchbox-keyboard/matchbox-keyboard_git.bb
@@ -0,0 +1,61 @@
+DESCRIPTION = "Matchbox virtual keyboard for X11"
+HOMEPAGE = "http://matchbox-project.org"
+BUGTRACKER = "http://bugzilla.openedhand.com/"
+
+LICENSE = "GPLv2+"
+LIC_FILES_CHKSUM = "file://COPYING;md5=94d55d512a9ba36caa9b7df079bae19f \
+                    file://src/matchbox-keyboard.h;endline=20;md5=4ba16ff913ad245dd6d95a6c67f72526 \
+                    file://applet/applet.c;endline=20;md5=e9201b3efa0a81a160b88d6feb5cf75b"
+
+DEPENDS = "libfakekey expat libxft gtk+ matchbox-panel-2"
+RDEPENDS_${PN} = "formfactor dbus-wait"
+SECTION = "x11"
+PV = "0.0+git${SRCPV}"
+PR = "r0"
+
+SRC_URI = "git://git.pokylinux.org/${PN};protocol=git \
+           file://configure_fix.patch;patch=1;maxrev=1819 \
+           file://single-instance.patch;patch=1 \
+	   file://80matchboxkeyboard.shbg"
+
+S = "${WORKDIR}/git"
+
+inherit autotools pkgconfig gettext
+
+EXTRA_OECONF = "--disable-cairo --enable-gtk-im --enable-applet"
+
+PACKAGES += "matchbox-keyboard-im matchbox-keyboard-im-dbg \
+             matchbox-keyboard-applet matchbox-keyboard-applet-dbg"
+
+FILES_${PN} = "${bindir}/* \
+	       ${sysconfdir} \
+	       ${datadir}/applications \
+	       ${datadir}/pixmaps \
+	       ${datadir}/matchbox-keyboard"
+
+FILES_matchbox-keyboard-im = "${libdir}/gtk-2.0/*/immodules/*.so"
+FILES_matchbox-keyboard-im-dbg += "${libdir}/gtk-2.0/*/immodules/.debug"
+
+FILES_matchbox-keyboard-applet = "${libdir}/matchbox-panel/*.so"
+FILES_matchbox-keyboard-applet-dbg += "${libdir}/matchbox-panel/.debug"
+
+do_install_append () {
+	install -d ${D}/${sysconfdir}/X11/Xsession.d/
+	install -m 755 ${WORKDIR}/80matchboxkeyboard.shbg ${D}/${sysconfdir}/X11/Xsession.d/
+}
+
+pkg_postinst_matchbox-keyboard-im () {
+if [ "x$D" != "x" ]; then
+  exit 1
+fi
+
+gtk-query-immodules-2.0 > /etc/gtk-2.0/gtk.immodules
+}
+
+pkg_postrm_matchbox-keyboard-im () {
+if [ "x$D" != "x" ]; then
+  exit 1
+fi
+
+gtk-query-immodules-2.0 > /etc/gtk-2.0/gtk.immodules
+}
-- 
cgit v1.2.3-54-g00ecf