From c527fd1f14c27855a37f2e8ac5346ce8d940ced2 Mon Sep 17 00:00:00 2001
From: Tudor Florea <tudor.florea@enea.com>
Date: Thu, 16 Oct 2014 03:05:19 +0200
Subject: initial commit for Enea Linux 4.0-140929

Migrated from the internal git server on the daisy-enea-point-release branch

Signed-off-by: Tudor Florea <tudor.florea@enea.com>
---
 meta/classes/uboot-config.bbclass | 61 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 61 insertions(+)
 create mode 100644 meta/classes/uboot-config.bbclass

(limited to 'meta/classes/uboot-config.bbclass')

diff --git a/meta/classes/uboot-config.bbclass b/meta/classes/uboot-config.bbclass
new file mode 100644
index 0000000000..8ac1b71bc2
--- /dev/null
+++ b/meta/classes/uboot-config.bbclass
@@ -0,0 +1,61 @@
+# Handle U-Boot config for a machine
+#
+# The format to specify it, in the machine, is:
+#
+# UBOOT_CONFIG ??= <default>
+# UBOOT_CONFIG[foo] = "config,images"
+#
+# or
+#
+# UBOOT_MACHINE = "config"
+#
+# Copyright 2013, 2014 (C) O.S. Systems Software LTDA.
+
+python () {
+    ubootmachine = d.getVar("UBOOT_MACHINE", True)
+    ubootconfigflags = d.getVarFlags('UBOOT_CONFIG')
+    # The "doc" varflag is special, we don't want to see it here
+    ubootconfigflags.pop('doc', None)
+
+    if not ubootmachine and not ubootconfigflags:
+        PN = d.getVar("PN", True)
+        FILE = os.path.basename(d.getVar("FILE", True))
+        bb.debug(1, "To build %s, see %s for instructions on \
+                 setting up your machine config" % (PN, FILE))
+        raise bb.parse.SkipPackage("Either UBOOT_MACHINE or UBOOT_CONFIG must be set in the %s machine configuration." % d.getVar("MACHINE", True))
+
+    if ubootmachine and ubootconfigflags:
+        raise bb.parse.SkipPackage("You cannot use UBOOT_MACHINE and UBOOT_CONFIG at the same time.")
+
+    if not ubootconfigflags:
+        return
+
+    ubootconfig = (d.getVar('UBOOT_CONFIG', True) or "").split()
+    if len(ubootconfig) > 1:
+        raise bb.parse.SkipPackage('You can only have a single default for UBOOT_CONFIG.')
+    elif len(ubootconfig) == 0:
+        raise bb.parse.SkipPackage('You must set a default in UBOOT_CONFIG.')
+    ubootconfig = ubootconfig[0]
+
+    for f, v in ubootconfigflags.items():
+        if f == 'defaultval':
+            continue
+
+        items = v.split(',')
+        if items[0] and len(items) > 2:
+            raise bb.parse.SkipPackage('Only config,images can be specified!')
+
+        if ubootconfig == f:
+            bb.debug(1, "Setting UBOOT_MACHINE to %s." % items[0])
+            d.setVar('UBOOT_MACHINE', items[0])
+
+            # IMAGE_FSTYPES appending
+            if len(items) > 1 and items[1]:
+                bb.debug(1, "Appending '%s' to IMAGE_FSTYPES." % items[1])
+                d.appendVar('IMAGE_FSTYPES', ' ' + items[1])
+
+            # Go out as we found a match!
+            break
+    else:
+        raise bb.parse.SkipPackage("UBOOT_CONFIG %s is not supported" % ubootconfig)
+}
-- 
cgit v1.2.3-54-g00ecf