From 3321c7090f15096252266c146ea51cc5055d8ac8 Mon Sep 17 00:00:00 2001
From: Richard Purdie <richard@openedhand.com>
Date: Thu, 7 Dec 2006 15:19:27 +0000
Subject: pango: Add 1.5.1 from OE.dev

git-svn-id: https://svn.o-hand.com/repos/poky/trunk@1017 311d38ba-8fff-0310-9ca6-ca027cbcb966
---
 meta/packages/pango/pango_1.15.1.bb | 51 +++++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)
 create mode 100644 meta/packages/pango/pango_1.15.1.bb

diff --git a/meta/packages/pango/pango_1.15.1.bb b/meta/packages/pango/pango_1.15.1.bb
new file mode 100644
index 0000000000..8847b88549
--- /dev/null
+++ b/meta/packages/pango/pango_1.15.1.bb
@@ -0,0 +1,51 @@
+DESCRIPTION = "The goal of the Pango project is to provide an \
+Open Source framework for the layout and rendering of \
+internationalized text."
+LICENSE = "LGPL"
+SECTION = "x11/libs"
+
+DEPENDS = "glib-2.0 fontconfig freetype zlib virtual/libx11 libxft gtk-doc cairo"
+
+PR = "r0"
+
+PACKAGES_DYNAMIC = "pango-module-*"
+
+RRECOMMENDS_${PN} = "pango-module-basic-x pango-module-basic-fc" 
+
+# seems to go wrong with default cflags
+FULL_OPTIMIZATION_arm = "-O2"
+
+SRC_URI = "http://ftp.gnome.org/pub/GNOME/sources/pango/1.15/pango-${PV}.tar.bz2 \
+	   file://no-tests.patch;patch=1 \
+		"
+inherit autotools pkgconfig
+
+EXTRA_OECONF = "--disable-glibtest \
+		--enable-explicit-deps=no \
+	        --disable-debug"
+
+LEAD_SONAME = "libpango-1.0*"
+LIBV = "1.6.0"
+
+FILES_${PN} = "/etc ${bindir}/* ${libdir}/libpango*.so.*"
+FILES_${PN}-dbg += "${libdir}/pango/${LIBV}/modules/.debug"
+FILES_${PN}-dev += "${libdir}/pango/${LIBV}/modules/*.la"
+
+do_stage () {
+	autotools_stage_all
+}
+
+postinst_prologue() {
+if [ "x$D" != "x" ]; then
+  exit 1
+fi
+
+}
+
+python populate_packages_prepend () {
+	prologue = bb.data.getVar("postinst_prologue", d, 1)
+
+	modules_root = bb.data.expand('${libdir}/pango/${LIBV}/modules', d)
+
+	do_split_packages(d, modules_root, '^pango-(.*)\.so$', 'pango-module-%s', 'Pango module %s', prologue + 'pango-querymodules > /etc/pango/pango.modules')
+}
-- 
cgit v1.2.3-54-g00ecf