summaryrefslogtreecommitdiffstats
path: root/meta/recipes-support/gnutls/gnutls_3.6.13.bb
diff options
context:
space:
mode:
Diffstat (limited to 'meta/recipes-support/gnutls/gnutls_3.6.13.bb')
-rw-r--r--meta/recipes-support/gnutls/gnutls_3.6.13.bb71
1 files changed, 71 insertions, 0 deletions
diff --git a/meta/recipes-support/gnutls/gnutls_3.6.13.bb b/meta/recipes-support/gnutls/gnutls_3.6.13.bb
new file mode 100644
index 0000000000..2ed012f9d6
--- /dev/null
+++ b/meta/recipes-support/gnutls/gnutls_3.6.13.bb
@@ -0,0 +1,71 @@
1SUMMARY = "GNU Transport Layer Security Library"
2HOMEPAGE = "http://www.gnu.org/software/gnutls/"
3BUGTRACKER = "https://savannah.gnu.org/support/?group=gnutls"
4
5LICENSE = "GPLv3+ & LGPLv2.1+"
6LICENSE_${PN} = "LGPLv2.1+"
7LICENSE_${PN}-xx = "LGPLv2.1+"
8LICENSE_${PN}-bin = "GPLv3+"
9LICENSE_${PN}-openssl = "GPLv3+"
10
11LIC_FILES_CHKSUM = "file://LICENSE;md5=71391c8e0c1cfe68077e7fce3b586283 \
12 file://doc/COPYING;md5=c678957b0c8e964aa6c70fd77641a71e \
13 file://doc/COPYING.LESSER;md5=a6f89e2100d9b6cdffcea4f398e37343"
14
15DEPENDS = "nettle gmp virtual/libiconv libunistring"
16DEPENDS_append_libc-musl = " argp-standalone"
17
18SHRT_VER = "${@d.getVar('PV').split('.')[0]}.${@d.getVar('PV').split('.')[1]}"
19
20SRC_URI = "https://www.gnupg.org/ftp/gcrypt/gnutls/v${SHRT_VER}/gnutls-${PV}.tar.xz \
21 file://arm_eabi.patch \
22 file://CVE-2020-13777-a.patch \
23 file://CVE-2020-13777-b.patch \
24 file://CVE-2020-13777-c.patch \
25 file://CVE-2020-24659.patch \
26"
27
28SRC_URI[md5sum] = "bb1fe696a11543433785b4fc70ca225f"
29SRC_URI[sha256sum] = "32041df447d9f4644570cf573c9f60358e865637d69b7e59d1159b7240b52f38"
30
31inherit autotools texinfo pkgconfig gettext lib_package gtk-doc
32
33PACKAGECONFIG ??= "libidn"
34
35# You must also have CONFIG_SECCOMP enabled in the kernel for
36# seccomp to work.
37PACKAGECONFIG[seccomp] = "ac_cv_libseccomp=yes,ac_cv_libseccomp=no,libseccomp"
38PACKAGECONFIG[libidn] = "--with-idn,--without-idn,libidn2"
39PACKAGECONFIG[libtasn1] = "--with-included-libtasn1=no,--with-included-libtasn1,libtasn1"
40PACKAGECONFIG[p11-kit] = "--with-p11-kit,--without-p11-kit,p11-kit"
41PACKAGECONFIG[tpm] = "--with-tpm,--without-tpm,trousers"
42
43EXTRA_OECONF = " \
44 --enable-doc \
45 --disable-libdane \
46 --disable-guile \
47 --disable-rpath \
48 --enable-local-libopts \
49 --enable-openssl-compatibility \
50 --with-libpthread-prefix=${STAGING_DIR_HOST}${prefix} \
51 --with-default-trust-store-file=${sysconfdir}/ssl/certs/ca-certificates.crt \
52"
53
54# Otherwise the tools try and use HOSTTOOLS_DIR/bash as a shell.
55export POSIX_SHELL="${base_bindir}/sh"
56
57LDFLAGS_append_libc-musl = " -largp"
58
59do_configure_prepend() {
60 for dir in . lib; do
61 rm -f ${dir}/aclocal.m4 ${dir}/m4/libtool.m4 ${dir}/m4/lt*.m4
62 done
63}
64
65PACKAGES =+ "${PN}-openssl ${PN}-xx"
66
67FILES_${PN}-dev += "${bindir}/gnutls-cli-debug"
68FILES_${PN}-openssl = "${libdir}/libgnutls-openssl.so.*"
69FILES_${PN}-xx = "${libdir}/libgnutlsxx.so.*"
70
71BBCLASSEXTEND = "native nativesdk"