1 files changed, 39 insertions, 0 deletions

diff --git a/meta/recipes-support/gnupg/gnupg_2.0.26.bb b/meta/recipes-support/gnupg/gnupg_2.0.26.bb
new file mode 100644
index 0000000000..92dd3bd643
--- /dev/null
+++ b/meta/recipes-support/gnupg/gnupg_2.0.26.bb
@@ -0,0 +1,39 @@
+SUMMARY = "GNU Privacy Guard - encryption and signing tools (2.x)"
+HOMEPAGE = "http://www.gnupg.org/"
+LICENSE = "GPLv3 & LGPLv3"
+LIC_FILES_CHKSUM = "file://COPYING;md5=f27defe1e96c2e1ecd4e0c9be8967949 \
+                    file://COPYING.LIB;md5=6a6a8e020838b23406c81b19c1d46df6"
+
+DEPENDS = "${PTH} libassuan libksba zlib bzip2 readline libgcrypt"
+PTH = "pth"
+PTH_libc-uclibc = "npth"
+
+inherit autotools gettext texinfo pkgconfig
+
+SRC_URI = "ftp://ftp.gnupg.org/gcrypt/${BPN}/${BPN}-${PV}.tar.bz2 \
+           file://pkgconfig.patch"
+
+SRC_URI[md5sum] = "fa7e704aad33eb114d1840164455aec1"
+SRC_URI[sha256sum] = "7758e30dc382ae7a7167ed41b7f936aa50af5ea2d6fccdef663b5b750b65b8e0"
+
+EXTRA_OECONF = "--disable-ldap \
+                --disable-ccid-driver \
+                --without-libcurl \
+                --with-zlib=${STAGING_LIBDIR}/.. \
+                --with-bzip2=${STAGING_LIBDIR}/.. \
+                --with-readline=${STAGING_LIBDIR}/.. \
+               "
+RRECOMMENDS_${PN} = "pinentry"
+
+do_configure_prepend () {
+        # Else these could be used in prefernce to those in aclocal-copy
+        rm -f ${S}/m4/gpg-error.m4
+        rm -f ${S}/m4/libassuan.m4
+        rm -f ${S}/m4/ksba.m4
+        rm -f ${S}/m4/libgcrypt.m4
+}
+
+do_install_append() {
+        ln -sf gpg2 ${D}${bindir}/gpg
+        ln -sf gpgv2 ${D}${bindir}/gpgv
+}