summaryrefslogtreecommitdiffstats
path: root/meta/recipes-support/db/db_4.2.52.bb
diff options
context:
space:
mode:
Diffstat (limited to 'meta/recipes-support/db/db_4.2.52.bb')
-rw-r--r--meta/recipes-support/db/db_4.2.52.bb97
1 files changed, 97 insertions, 0 deletions
diff --git a/meta/recipes-support/db/db_4.2.52.bb b/meta/recipes-support/db/db_4.2.52.bb
new file mode 100644
index 0000000000..b3ca493a01
--- /dev/null
+++ b/meta/recipes-support/db/db_4.2.52.bb
@@ -0,0 +1,97 @@
1# Version 4 of the Berkeley DB from Sleepycat
2#
3# At present this package only installs the DB code
4# itself (shared libraries, .a in the dev package),
5# documentation and headers.
6#
7# The headers have the same names as those as v3
8# of the DB, only one version can be used *for dev*
9# at once - DB3 and DB4 can both be installed on the
10# same system at the same time if really necessary.
11SECTION = "libs"
12DESCRIPTION = "Berkeley DB v4."
13HOMEPAGE = "http://www.oracle.com/technology/products/berkeley-db/db/index.html"
14LICENSE = "BSD Sleepycat"
15VIRTUAL_NAME = "virtual/db"
16VIRTUAL_NAME_virtclass-native = "virtual/db-native"
17
18CONFLICTS = "db3"
19CONFLICTS_virtclass-native = "db3-native"
20PR = "r8"
21
22SRC_URI = "http://download.oracle.com/berkeley-db/db-${PV}.tar.gz \
23 file://configure_fixes.patch;patch=1 "
24#SRC_URI_MD5 = "http://downloads.sleepycat.com/db-${PV}.tar.gz.md5"
25#TODO SRC_URI += "file://arm-thumb-mutex.patch;patch=1"
26
27inherit autotools
28
29# Put virtual/db in any appropriate provider of a
30# relational database, use it as a dependency in
31# place of a specific db and use:
32#
33# PREFERRED_PROVIDER_virtual/db
34#
35# to select the correct db in the build (distro) .conf
36PROVIDES += "${VIRTUAL_NAME}"
37
38# bitbake isn't quite clever enough to deal with sleepycat,
39# the distribution sits in the expected directory, but all
40# the builds must occur from a sub-directory. The following
41# persuades bitbake to go to the right place
42S = "${WORKDIR}/db-${PV}/dist"
43B = "${WORKDIR}/db-${PV}/build_unix"
44
45# The executables go in a separate package - typically there
46# is no need to install these unless doing real database
47# management on the system.
48PACKAGES += " ${PN}-bin"
49
50# Package contents
51FILES_${PN} = "${libdir}/libdb-4*so*"
52FILES_${PN}-bin = "${bindir}/*"
53# The dev package has the .so link (as in db3) and the .a's -
54# it is therefore incompatible (cannot be installed at the
55# same time) as the db3 package
56FILES_${PN}-dev = "${includedir} ${libdir}/*"
57
58#configuration - set in local.conf to override
59DB4_CONFIG ?= " --disable-cryptography --disable-queue --disable-replication --disable-verify --enable-hash"
60EXTRA_OECONF = "${DB4_CONFIG}"
61
62# Override the MUTEX setting here, the POSIX library is
63# the default - "POSIX/pthreads/library".
64# Don't ignore the nice SWP instruction on the ARM:
65# These enable the ARM assembler mutex code, this won't
66# work with thumb compilation...
67ARM_MUTEX = "--with-mutex=ARM/gcc-assembly"
68MUTEX = ""
69MUTEX_arm = "${ARM_MUTEX}"
70MUTEX_armeb = "${ARM_MUTEX}"
71EXTRA_OECONF += "${MUTEX}"
72
73ARM_INSTRUCTION_SET = "arm"
74
75# Cancel the site stuff - it's set for db3 and destroys the
76# configure.
77CONFIG_SITE = ""
78do_configure() {
79 rm -f ${S}/config.sub
80 cp ${STAGING_DATADIR_NATIVE}/gnu-config/config.sub ${S}/config.sub
81 oe_runconf
82}
83
84do_install_append() {
85 # The docs end up in /usr/docs - not right.
86 if test -d "${D}/${prefix}/docs"
87 then
88 mkdir -p "${D}/${datadir}"
89 test ! -d "${D}/${docdir}" || rm -rf "${D}/${docdir}"
90 mv "${D}/${prefix}/docs" "${D}/${docdir}"
91 fi
92}
93
94# The db package contains symlinks that trip up insane
95INSANE_SKIP_db = "1"
96
97BBCLASSEXTEND = "native"