1 files changed, 54 insertions, 0 deletions

diff --git a/meta/recipes-support/curl/curl_7.26.0.bb b/meta/recipes-support/curl/curl_7.26.0.bb
new file mode 100644
index 0000000000..f04b4008d6
--- /dev/null
+++ b/meta/recipes-support/curl/curl_7.26.0.bb
@@ -0,0 +1,54 @@
+DESCRIPTION = "Command line tool and library for client-side URL transfers."
+HOMEPAGE = "http://curl.haxx.se/"
+BUGTRACKER = "http://curl.haxx.se/mail/list.cgi?list=curl-tracker"
+SECTION = "console/network"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://COPYING;beginline=7;md5=3a34942f4ae3fbf1a303160714e664ac"
+
+DEPENDS = "zlib gnutls"
+DEPENDS_virtclass-native = "zlib-native openssl-native"
+DEPENDS_virtclass-nativesdk = "zlib-nativesdk"
+PR = "r0"
+
+SRC_URI = "http://curl.haxx.se/download/curl-${PV}.tar.bz2 \
+           file://pkgconfig_fix.patch"
+
+SRC_URI[md5sum] = "bfa80f01b3d300359cfb4d409b6136a3"
+SRC_URI[sha256sum] = "fced262f16eb6bfcdcea15e04a7905ffcb5ff04b14a19ca35b9df86d6720d26a"
+
+inherit autotools pkgconfig binconfig
+
+EXTRA_OECONF = "--with-zlib=${STAGING_LIBDIR}/../ \
+                --without-libssh2 \
+                --with-random=/dev/urandom \
+                --without-libidn \
+                --enable-crypto-auth \
+                ${CURLGNUTLS} \
+                "
+
+CURLGNUTLS = " --with-gnutls=${STAGING_LIBDIR}/../ --without-ssl"
+CURLGNUTLS_virtclass-native = "--without-gnutls --with-ssl"
+CURLGNUTLS_virtclass-nativesdk = "--without-gnutls --without-ssl"
+
+do_configure_prepend() {
+        sed -i s:OPT_GNUTLS/bin:OPT_GNUTLS:g configure.ac
+}
+
+PACKAGES =+ "${PN}-certs libcurl libcurl-dev libcurl-staticdev libcurl-doc"
+
+FILES_${PN}-certs = "${datadir}/curl/curl-*"
+PACKAGE_ARCH_${PN}-certs = "all"
+
+FILES_lib${BPN} = "${libdir}/lib*.so.*"
+RRECOMMENDS_lib${BPN} += "${PN}-certs"
+FILES_lib${BPN}-dev = "${includedir} \
+                      ${libdir}/lib*.so \
+                      ${libdir}/lib*.la \
+                      ${libdir}/pkgconfig \
+                      ${datadir}/aclocal \
+                      ${bindir}/*-config"
+FILES_lib${BPN}-staticdev = "${libdir}/lib*.a"
+FILES_lib${BPN}-doc = "${mandir}/man3 \
+                      ${mandir}/man1/curl-config.1"
+
+BBCLASSEXTEND = "native nativesdk"