1 files changed, 52 insertions, 0 deletions

diff --git a/meta/recipes-support/apr/apr-util_1.5.1.bb b/meta/recipes-support/apr/apr-util_1.5.1.bb
new file mode 100644
index 0000000000..e547fe018f
--- /dev/null
+++ b/meta/recipes-support/apr/apr-util_1.5.1.bb
@@ -0,0 +1,52 @@
+DESCRIPTION = "Apache Portable Runtime (APR) companion library"
+HOMEPAGE = "http://apr.apache.org/"
+SECTION = "libs"
+DEPENDS = "apr expat gdbm"
+
+BBCLASSEXTEND = "native"
+
+LICENSE = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=519e0a18e03f7c023070568c14b077bb \
+                    file://include/apu_version.h;endline=17;md5=806685a84e71f10c80144c48eb35df42"
+
+PR = "r0"
+
+SRC_URI = "${APACHE_MIRROR}/apr/${BPN}-${PV}.tar.gz \
+           file://configfix.patch \
+           file://configure_fixes.patch"
+
+SRC_URI[md5sum] = "490c2e26e2dc95fd0983ad71112ddac6"
+SRC_URI[sha256sum] = "0cf4e48d93ceb9a5e314f48fe127211b71d30234665587e2eaffbb4fc13d931d"
+
+EXTRA_OECONF = "--with-apr=${STAGING_BINDIR_CROSS}/apr-1-config \ 
+                --without-odbc \
+                --without-pgsql \
+                --with-dbm=gdbm \
+                --with-gdbm=${STAGING_DIR_HOST}${prefix} \
+                --without-sqlite2 \
+                --without-sqlite3 \
+                --with-expat=${STAGING_DIR_HOST}${prefix}"
+
+
+inherit autotools lib_package binconfig
+
+OE_BINCONFIG_EXTRA_MANGLE = " -e 's:location=source:location=installed:'"
+
+do_configure_append() {
+        if [ "${CLASSOVERRIDE}" = "class-target" ]; then
+                cp ${STAGING_DATADIR}/apr/apr_rules.mk ${S}/build/rules.mk
+        fi
+}
+do_configure_prepend_class-native() {
+        cp ${STAGING_DATADIR_NATIVE}/apr/apr_rules.mk ${S}/build/rules.mk
+}
+do_configure_append_class-native() {
+        sed -i "s#LIBTOOL=\$(SHELL) \$(apr_builddir)#LIBTOOL=\$(SHELL) ${STAGING_BINDIR_NATIVE}#" ${S}/build/rules.mk
+        # sometimes there isn't SHELL
+        sed -i "s#LIBTOOL=\$(apr_builddir)#LIBTOOL=${STAGING_BINDIR_NATIVE}#" ${S}/build/rules.mk
+}
+
+FILES_${PN}     += "${libdir}/apr-util-1/apr_dbm_gdbm-1.so"
+FILES_${PN}-dev += "${libdir}/aprutil.exp ${libdir}/apr-util-1/apr_dbm_gdbm.so* ${libdir}/apr-util-1/apr_dbm_gdbm.la"
+FILES_${PN}-dbg += "${libdir}/apr-util-1/.debug/*"
+FILES_${PN}-staticdev += "${libdir}/apr-util-1/apr_dbm_gdbm.a"