summaryrefslogtreecommitdiffstats
path: root/meta/recipes-sato/webkit/webkitgtk_2.42.5.bb
diff options
context:
space:
mode:
Diffstat (limited to 'meta/recipes-sato/webkit/webkitgtk_2.42.5.bb')
-rw-r--r--meta/recipes-sato/webkit/webkitgtk_2.42.5.bb184
1 files changed, 184 insertions, 0 deletions
diff --git a/meta/recipes-sato/webkit/webkitgtk_2.42.5.bb b/meta/recipes-sato/webkit/webkitgtk_2.42.5.bb
new file mode 100644
index 0000000000..6790814958
--- /dev/null
+++ b/meta/recipes-sato/webkit/webkitgtk_2.42.5.bb
@@ -0,0 +1,184 @@
1SUMMARY = "WebKit web rendering engine for the GTK+ platform"
2HOMEPAGE = "https://www.webkitgtk.org/"
3BUGTRACKER = "https://bugs.webkit.org/"
4
5LICENSE = "BSD-2-Clause & LGPL-2.0-or-later"
6LIC_FILES_CHKSUM = "file://Source/JavaScriptCore/COPYING.LIB;md5=d0c6d6397a5d84286dda758da57bd691 \
7 file://Source/WebCore/LICENSE-APPLE;md5=4646f90082c40bcf298c285f8bab0b12 \
8 file://Source/WebCore/LICENSE-LGPL-2;md5=36357ffde2b64ae177b2494445b79d21 \
9 file://Source/WebCore/LICENSE-LGPL-2.1;md5=a778a33ef338abbaf8b8a7c36b6eec80 \
10 "
11
12SRC_URI = "https://www.webkitgtk.org/releases/${BPN}-${PV}.tar.xz \
13 file://0001-FindGObjectIntrospection.cmake-prefix-variables-obta.patch \
14 file://reproducibility.patch \
15 file://0d3344e17d258106617b0e6d783d073b188a2548.patch \
16 file://0001-CMake-Add-a-variable-to-control-macro-__PAS_ALWAYS_I.patch \
17 file://no-musttail-arm.patch \
18 file://t6-not-declared.patch \
19 "
20SRC_URI[sha256sum] = "b64278c1f20b8cfdbfb5ff573c37d871aba74a1db26d9b39f74e8953fe61e749"
21
22inherit cmake pkgconfig gobject-introspection perlnative features_check upstream-version-is-even gi-docgen
23
24ANY_OF_DISTRO_FEATURES = "${GTK3DISTROFEATURES}"
25REQUIRED_DISTRO_FEATURES = "opengl"
26
27CVE_PRODUCT = "webkitgtk webkitgtk\+"
28
29DEPENDS += " \
30 ruby-native \
31 gperf-native \
32 unifdef-native \
33 cairo \
34 harfbuzz \
35 jpeg \
36 atk \
37 libwebp \
38 gtk4 \
39 libxslt \
40 libtasn1 \
41 libnotify \
42 gstreamer1.0 \
43 gstreamer1.0-plugins-base \
44 glib-2.0-native \
45 gettext-native \
46 "
47
48PACKAGECONFIG_SOUP ?= "soup3"
49PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'systemd wayland x11', d)} \
50 ${@bb.utils.contains('DISTRO_FEATURES', 'x11 opengl', 'webgl opengl', '', d)} \
51 ${@bb.utils.contains('DISTRO_FEATURES', 'x11', '', 'webgl gles2', d)} \
52 ${@bb.utils.contains('DISTRO_FEATURES', 'opengl', 'opengl-or-es', '', d)} \
53 enchant \
54 libsecret \
55 ${PACKAGECONFIG_SOUP} \
56 "
57
58PACKAGECONFIG[wayland] = "-DENABLE_WAYLAND_TARGET=ON,-DENABLE_WAYLAND_TARGET=OFF,wayland libwpe wpebackend-fdo wayland-native"
59PACKAGECONFIG[angle] = "-DUSE_ANGLE_WEBGL=ON,-DUSE_ANGLE_WEBGL=OFF"
60PACKAGECONFIG[x11] = "-DENABLE_X11_TARGET=ON,-DENABLE_X11_TARGET=OFF,virtual/libx11 libxcomposite libxdamage libxrender libxt"
61PACKAGECONFIG[geoclue] = "-DENABLE_GEOLOCATION=ON,-DENABLE_GEOLOCATION=OFF,geoclue"
62PACKAGECONFIG[enchant] = "-DENABLE_SPELLCHECK=ON,-DENABLE_SPELLCHECK=OFF,enchant2"
63PACKAGECONFIG[gles2] = "-DENABLE_GLES2=ON,-DENABLE_GLES2=OFF,virtual/libgles2"
64PACKAGECONFIG[webgl] = "-DENABLE_WEBGL=ON,-DENABLE_WEBGL=OFF,virtual/egl"
65PACKAGECONFIG[opengl] = "-DENABLE_GRAPHICS_CONTEXT_GL=ON,-DENABLE_GRAPHICS_CONTEXT_GL=OFF,virtual/egl"
66PACKAGECONFIG[opengl-or-es] = "-DUSE_OPENGL_OR_ES=ON,-DUSE_OPENGL_OR_ES=OFF"
67PACKAGECONFIG[libsecret] = "-DUSE_LIBSECRET=ON,-DUSE_LIBSECRET=OFF,libsecret"
68PACKAGECONFIG[libhyphen] = "-DUSE_LIBHYPHEN=ON,-DUSE_LIBHYPHEN=OFF,libhyphen"
69PACKAGECONFIG[woff2] = "-DUSE_WOFF2=ON,-DUSE_WOFF2=OFF,woff2"
70PACKAGECONFIG[openjpeg] = "-DUSE_OPENJPEG=ON,-DUSE_OPENJPEG=OFF,openjpeg"
71PACKAGECONFIG[systemd] = "-DUSE_SYSTEMD=ON,-DUSE_SYSTEMD=off,systemd"
72PACKAGECONFIG[reduce-size] = "-DCMAKE_BUILD_TYPE=MinSizeRel,-DCMAKE_BUILD_TYPE=Release,,"
73PACKAGECONFIG[lcms] = "-DUSE_LCMS=ON,-DUSE_LCMS=OFF,lcms"
74PACKAGECONFIG[soup2] = "-DUSE_SOUP2=ON,-DUSE_SOUP2=OFF,libsoup-2.4,,,soup3"
75PACKAGECONFIG[soup3] = ",,libsoup,,,soup2"
76PACKAGECONFIG[journald] = "-DENABLE_JOURNALD_LOG=ON,-DENABLE_JOURNALD_LOG=OFF,systemd"
77PACKAGECONFIG[avif] = "-DUSE_AVIF_LOG=ON,-DUSE_AVIF=OFF,libavif"
78PACKAGECONFIG[media-recorder] = "-DENABLE_MEDIA_RECORDER=ON,-DENABLE_MEDIA_RECORDER=OFF,gstreamer1.0-plugins-bad"
79PACKAGECONFIG[jpegxl] = "-DUSE_JPEGXL=ON,-DUSE_JPEGXL=OFF,libjxl"
80
81EXTRA_OECMAKE = " \
82 -DPORT=GTK \
83 ${@oe.utils.vartrue('GI_DATA_ENABLED', '-DENABLE_INTROSPECTION=ON', '-DENABLE_INTROSPECTION=OFF', d)} \
84 ${@oe.utils.vartrue('GIDOCGEN_ENABLED', '-DENABLE_DOCUMENTATION=ON', '-DENABLE_DOCUMENTATION=OFF', d)} \
85 ${@oe.utils.vartrue('DEBUG_BUILD', '-DWEBKIT_NO_INLINE_HINTS=ON', '-DWEBKIT_NO_INLINE_HINTS=OFFF', d)} \
86 -DENABLE_MINIBROWSER=ON \
87 -DENABLE_BUBBLEWRAP_SANDBOX=OFF \
88 -DENABLE_GAMEPAD=OFF \
89 -DUSE_GTK4=ON \
90 "
91
92# Unless DEBUG_BUILD is enabled, pass -g1 to massively reduce the size of the
93# debug symbols (4.3GB to 700M at time of writing)
94DEBUG_FLAGS:append = "${@oe.utils.vartrue('DEBUG_BUILD', '', ' -g1', d)}"
95
96# Javascript JIT is not supported on ARC
97EXTRA_OECMAKE:append:arc = " -DENABLE_JIT=OFF "
98# By default 25-bit "medium" calls are used on ARC
99# which is not enough for binaries larger than 32 MiB
100CFLAGS:append:arc = " -mlong-calls"
101CXXFLAGS:append:arc = " -mlong-calls"
102
103# Needed for non-mesa graphics stacks when x11 is disabled
104CXXFLAGS += "${@bb.utils.contains('DISTRO_FEATURES', 'x11', '', '-DEGL_NO_X11=1', d)}"
105
106# Javascript JIT is not supported on powerpc
107EXTRA_OECMAKE:append:powerpc = " -DENABLE_JIT=OFF "
108EXTRA_OECMAKE:append:powerpc64 = " -DENABLE_JIT=OFF "
109
110# ARM JIT code does not build on ARMv4/5/6 anymore
111EXTRA_OECMAKE:append:armv4 = " -DENABLE_JIT=OFF "
112EXTRA_OECMAKE:append:armv5 = " -DENABLE_JIT=OFF "
113EXTRA_OECMAKE:append:armv6 = " -DENABLE_JIT=OFF "
114
115# And for armv7* don't enable it for softfp, because after:
116# https://github.com/WebKit/WebKit/commit/a2ec4ef1997d6fafa6ffc607bffb54e76168a918
117# https://bugs.webkit.org/show_bug.cgi?id=242172
118# softfp armv7* fails because WEBASSEMBLY is left enabled by default and JIT gets
119# explicitly disabled causing:
120# http://errors.yoctoproject.org/Errors/Details/734587/
121# PR was sent upstream, but the end result is the same both JIT and WEBASSEMBLY disabled
122# https://github.com/WebKit/WebKit/pull/17447
123EXTRA_OECMAKE:append:armv7a = " -DENABLE_JIT=${@bb.utils.contains('TUNE_FEATURES', 'callconvention-hard', 'ON', 'OFF', d)}"
124EXTRA_OECMAKE:append:armv7r = " -DENABLE_JIT=${@bb.utils.contains('TUNE_FEATURES', 'callconvention-hard', 'ON', 'OFF', d)}"
125EXTRA_OECMAKE:append:armv7ve = " -DENABLE_JIT=${@bb.utils.contains('TUNE_FEATURES', 'callconvention-hard', 'ON', 'OFF', d)}"
126
127EXTRA_OECMAKE:append:mipsarch = " -DUSE_LD_GOLD=OFF "
128EXTRA_OECMAKE:append:powerpc = " -DUSE_LD_GOLD=OFF "
129
130# JIT and gold linker does not work on RISCV
131EXTRA_OECMAKE:append:riscv32 = " -DUSE_LD_GOLD=OFF -DENABLE_JIT=OFF"
132EXTRA_OECMAKE:append:riscv64 = " -DUSE_LD_GOLD=OFF"
133
134# JIT not supported on MIPS either
135EXTRA_OECMAKE:append:mipsarch = " -DENABLE_JIT=OFF -DENABLE_C_LOOP=ON "
136
137# JIT not supported on X32
138# An attempt was made to upstream JIT support for x32 in
139# https://bugs.webkit.org/show_bug.cgi?id=100450, but this was closed as
140# unresolved due to limited X32 adoption.
141EXTRA_OECMAKE:append:x86-x32 = " -DENABLE_JIT=OFF "
142
143SECURITY_CFLAGS:remove:aarch64 = "-fpie"
144SECURITY_CFLAGS:append:aarch64 = " -fPIE"
145
146FILES:${PN} += "${libdir}/webkitgtk-*/injected-bundle/*.so"
147
148RRECOMMENDS:${PN} += "ca-certificates shared-mime-info"
149
150# http://errors.yoctoproject.org/Errors/Details/20370/
151ARM_INSTRUCTION_SET:armv4 = "arm"
152ARM_INSTRUCTION_SET:armv5 = "arm"
153ARM_INSTRUCTION_SET:armv6 = "arm"
154
155# https://bugzilla.yoctoproject.org/show_bug.cgi?id=9474
156# https://bugs.webkit.org/show_bug.cgi?id=159880
157# JSC JIT can build on ARMv7 with -marm, but doesn't work on runtime.
158# Upstream only tests regularly the JSC JIT on ARMv7 with Thumb2 (-mthumb).
159ARM_INSTRUCTION_SET:armv7a = "thumb"
160ARM_INSTRUCTION_SET:armv7r = "thumb"
161ARM_INSTRUCTION_SET:armv7ve = "thumb"
162
163# ANGLE requires SSE support as of webkit 2.40.x on 32 bit x86
164COMPATIBLE_HOST:x86 = "${@bb.utils.contains_any('TUNE_FEATURES', 'core2 corei7', '.*', 'null', d)}"
165
166# introspection inside qemu-arm hangs forever on musl/arm builds
167# therefore disable GI_DATA
168GI_DATA_ENABLED:libc-musl:armv7a = "False"
169GI_DATA_ENABLED:libc-musl:armv7ve = "False"
170
171# Can't be built with ccache
172CCACHE_DISABLE = "1"
173
174PACKAGE_PREPROCESS_FUNCS += "src_package_preprocess"
175src_package_preprocess () {
176 # Trim build paths from comments in generated sources to ensure reproducibility
177 sed -i -e "s,${WORKDIR},,g" \
178 ${B}/JavaScriptCore/DerivedSources/*.h \
179 ${B}/JavaScriptCore/DerivedSources/yarr/*.h \
180 ${B}/JavaScriptCore/PrivateHeaders/JavaScriptCore/*.h \
181 ${B}/WebCore/DerivedSources/*.cpp \
182 ${B}/WebKitGTK/DerivedSources/webkit/*.cpp
183}
184
generated by cgit v1.2.3-54-g00ecf (git 2.39.0) at 2024-05-28 11:15:16 +0000