diff options
Diffstat (limited to 'meta/recipes-sato/webkit/webkitgtk_2.40.5.bb')
-rw-r--r-- | meta/recipes-sato/webkit/webkitgtk_2.40.5.bb | 164 |
1 files changed, 164 insertions, 0 deletions
diff --git a/meta/recipes-sato/webkit/webkitgtk_2.40.5.bb b/meta/recipes-sato/webkit/webkitgtk_2.40.5.bb new file mode 100644 index 0000000000..7bf32e8610 --- /dev/null +++ b/meta/recipes-sato/webkit/webkitgtk_2.40.5.bb | |||
@@ -0,0 +1,164 @@ | |||
1 | SUMMARY = "WebKit web rendering engine for the GTK+ platform" | ||
2 | HOMEPAGE = "https://www.webkitgtk.org/" | ||
3 | BUGTRACKER = "https://bugs.webkit.org/" | ||
4 | |||
5 | LICENSE = "BSD-2-Clause & LGPL-2.0-or-later" | ||
6 | LIC_FILES_CHKSUM = "file://Source/JavaScriptCore/COPYING.LIB;md5=d0c6d6397a5d84286dda758da57bd691 \ | ||
7 | file://Source/WebCore/LICENSE-APPLE;md5=4646f90082c40bcf298c285f8bab0b12 \ | ||
8 | file://Source/WebCore/LICENSE-LGPL-2;md5=36357ffde2b64ae177b2494445b79d21 \ | ||
9 | file://Source/WebCore/LICENSE-LGPL-2.1;md5=a778a33ef338abbaf8b8a7c36b6eec80 \ | ||
10 | " | ||
11 | |||
12 | SRC_URI = "https://www.webkitgtk.org/releases/${BPN}-${PV}.tar.xz \ | ||
13 | file://0001-FindGObjectIntrospection.cmake-prefix-variables-obta.patch \ | ||
14 | file://reproducibility.patch \ | ||
15 | file://0d3344e17d258106617b0e6d783d073b188a2548.patch \ | ||
16 | file://check-GST_GL_HAVE_PLATFORM_GLX.patch \ | ||
17 | " | ||
18 | SRC_URI[sha256sum] = "7de051a263668621d91a61a5eb1c3771d1a7cec900043d4afef06c326c16037f" | ||
19 | |||
20 | inherit cmake pkgconfig gobject-introspection perlnative features_check upstream-version-is-even gi-docgen | ||
21 | |||
22 | ANY_OF_DISTRO_FEATURES = "${GTK3DISTROFEATURES}" | ||
23 | REQUIRED_DISTRO_FEATURES = "${@bb.utils.contains('DISTRO_FEATURES', 'wayland', 'opengl', '', d)}" | ||
24 | |||
25 | CVE_PRODUCT = "webkitgtk webkitgtk\+" | ||
26 | |||
27 | DEPENDS += " \ | ||
28 | ruby-native \ | ||
29 | gperf-native \ | ||
30 | unifdef-native \ | ||
31 | cairo \ | ||
32 | harfbuzz \ | ||
33 | jpeg \ | ||
34 | atk \ | ||
35 | libwebp \ | ||
36 | gtk4 \ | ||
37 | libxslt \ | ||
38 | libtasn1 \ | ||
39 | libnotify \ | ||
40 | gstreamer1.0 \ | ||
41 | gstreamer1.0-plugins-base \ | ||
42 | glib-2.0-native \ | ||
43 | gettext-native \ | ||
44 | " | ||
45 | |||
46 | PACKAGECONFIG_SOUP ?= "soup3" | ||
47 | PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'systemd wayland x11', d)} \ | ||
48 | ${@bb.utils.contains('DISTRO_FEATURES', 'x11 opengl', 'webgl opengl', '', d)} \ | ||
49 | ${@bb.utils.contains('DISTRO_FEATURES', 'x11', '', 'webgl gles2', d)} \ | ||
50 | ${@bb.utils.contains('DISTRO_FEATURES', 'opengl', 'opengl-or-es', '', d)} \ | ||
51 | enchant \ | ||
52 | libsecret \ | ||
53 | ${PACKAGECONFIG_SOUP} \ | ||
54 | " | ||
55 | |||
56 | PACKAGECONFIG[wayland] = "-DENABLE_WAYLAND_TARGET=ON,-DENABLE_WAYLAND_TARGET=OFF,wayland libwpe wpebackend-fdo wayland-native" | ||
57 | PACKAGECONFIG[angle] = "-DUSE_ANGLE_WEBGL=ON,-DUSE_ANGLE_WEBGL=OFF" | ||
58 | PACKAGECONFIG[x11] = "-DENABLE_X11_TARGET=ON,-DENABLE_X11_TARGET=OFF,virtual/libx11 libxcomposite libxdamage libxrender libxt" | ||
59 | PACKAGECONFIG[geoclue] = "-DENABLE_GEOLOCATION=ON,-DENABLE_GEOLOCATION=OFF,geoclue" | ||
60 | PACKAGECONFIG[enchant] = "-DENABLE_SPELLCHECK=ON,-DENABLE_SPELLCHECK=OFF,enchant2" | ||
61 | PACKAGECONFIG[gles2] = "-DENABLE_GLES2=ON,-DENABLE_GLES2=OFF,virtual/libgles2" | ||
62 | PACKAGECONFIG[webgl] = "-DENABLE_WEBGL=ON,-DENABLE_WEBGL=OFF,virtual/egl" | ||
63 | PACKAGECONFIG[opengl] = "-DENABLE_GRAPHICS_CONTEXT_GL=ON,-DENABLE_GRAPHICS_CONTEXT_GL=OFF,virtual/egl" | ||
64 | PACKAGECONFIG[opengl-or-es] = "-DUSE_OPENGL_OR_ES=ON,-DUSE_OPENGL_OR_ES=OFF" | ||
65 | PACKAGECONFIG[libsecret] = "-DUSE_LIBSECRET=ON,-DUSE_LIBSECRET=OFF,libsecret" | ||
66 | PACKAGECONFIG[libhyphen] = "-DUSE_LIBHYPHEN=ON,-DUSE_LIBHYPHEN=OFF,libhyphen" | ||
67 | PACKAGECONFIG[woff2] = "-DUSE_WOFF2=ON,-DUSE_WOFF2=OFF,woff2" | ||
68 | PACKAGECONFIG[openjpeg] = "-DUSE_OPENJPEG=ON,-DUSE_OPENJPEG=OFF,openjpeg" | ||
69 | PACKAGECONFIG[systemd] = "-DUSE_SYSTEMD=ON,-DUSE_SYSTEMD=off,systemd" | ||
70 | PACKAGECONFIG[reduce-size] = "-DCMAKE_BUILD_TYPE=MinSizeRel,-DCMAKE_BUILD_TYPE=Release,," | ||
71 | PACKAGECONFIG[lcms] = "-DUSE_LCMS=ON,-DUSE_LCMS=OFF,lcms" | ||
72 | PACKAGECONFIG[soup2] = "-DUSE_SOUP2=ON,-DUSE_SOUP2=OFF,libsoup-2.4,,,soup3" | ||
73 | PACKAGECONFIG[soup3] = ",,libsoup,,,soup2" | ||
74 | PACKAGECONFIG[journald] = "-DENABLE_JOURNALD_LOG=ON,-DENABLE_JOURNALD_LOG=OFF,systemd" | ||
75 | PACKAGECONFIG[avif] = "-DUSE_AVIF_LOG=ON,-DUSE_AVIF=OFF,libavif" | ||
76 | PACKAGECONFIG[media-recorder] = "-DENABLE_MEDIA_RECORDER=ON,-DENABLE_MEDIA_RECORDER=OFF,gstreamer1.0-plugins-bad" | ||
77 | |||
78 | EXTRA_OECMAKE = " \ | ||
79 | -DPORT=GTK \ | ||
80 | ${@bb.utils.contains('GI_DATA_ENABLED', 'True', '-DENABLE_INTROSPECTION=ON', '-DENABLE_INTROSPECTION=OFF', d)} \ | ||
81 | ${@bb.utils.contains('GIDOCGEN_ENABLED', 'True', '-DENABLE_DOCUMENTATION=ON', '-DENABLE_DOCUMENTATION=OFF', d)} \ | ||
82 | -DENABLE_MINIBROWSER=ON \ | ||
83 | -DENABLE_BUBBLEWRAP_SANDBOX=OFF \ | ||
84 | -DENABLE_GAMEPAD=OFF \ | ||
85 | -DUSE_GTK4=ON \ | ||
86 | " | ||
87 | |||
88 | # Javascript JIT is not supported on ARC | ||
89 | EXTRA_OECMAKE:append:arc = " -DENABLE_JIT=OFF " | ||
90 | # By default 25-bit "medium" calls are used on ARC | ||
91 | # which is not enough for binaries larger than 32 MiB | ||
92 | CFLAGS:append:arc = " -mlong-calls" | ||
93 | CXXFLAGS:append:arc = " -mlong-calls" | ||
94 | |||
95 | # Needed for non-mesa graphics stacks when x11 is disabled | ||
96 | CXXFLAGS += "${@bb.utils.contains('DISTRO_FEATURES', 'x11', '', '-DEGL_NO_X11=1', d)}" | ||
97 | |||
98 | # Javascript JIT is not supported on powerpc | ||
99 | EXTRA_OECMAKE:append:powerpc = " -DENABLE_JIT=OFF " | ||
100 | EXTRA_OECMAKE:append:powerpc64 = " -DENABLE_JIT=OFF " | ||
101 | |||
102 | # ARM JIT code does not build on ARMv4/5/6 anymore | ||
103 | EXTRA_OECMAKE:append:armv5 = " -DENABLE_JIT=OFF " | ||
104 | EXTRA_OECMAKE:append:armv6 = " -DENABLE_JIT=OFF " | ||
105 | EXTRA_OECMAKE:append:armv4 = " -DENABLE_JIT=OFF " | ||
106 | |||
107 | EXTRA_OECMAKE:append:mipsarch = " -DUSE_LD_GOLD=OFF " | ||
108 | EXTRA_OECMAKE:append:powerpc = " -DUSE_LD_GOLD=OFF " | ||
109 | |||
110 | # JIT and gold linker does not work on RISCV | ||
111 | EXTRA_OECMAKE:append:riscv32 = " -DUSE_LD_GOLD=OFF -DENABLE_JIT=OFF" | ||
112 | EXTRA_OECMAKE:append:riscv64 = " -DUSE_LD_GOLD=OFF" | ||
113 | |||
114 | # JIT not supported on MIPS either | ||
115 | EXTRA_OECMAKE:append:mipsarch = " -DENABLE_JIT=OFF -DENABLE_C_LOOP=ON " | ||
116 | |||
117 | # JIT not supported on X32 | ||
118 | # An attempt was made to upstream JIT support for x32 in | ||
119 | # https://bugs.webkit.org/show_bug.cgi?id=100450, but this was closed as | ||
120 | # unresolved due to limited X32 adoption. | ||
121 | EXTRA_OECMAKE:append:x86-x32 = " -DENABLE_JIT=OFF " | ||
122 | |||
123 | SECURITY_CFLAGS:remove:aarch64 = "-fpie" | ||
124 | SECURITY_CFLAGS:append:aarch64 = " -fPIE" | ||
125 | |||
126 | FILES:${PN} += "${libdir}/webkitgtk-*/injected-bundle/*.so" | ||
127 | |||
128 | RRECOMMENDS:${PN} += "ca-certificates shared-mime-info" | ||
129 | |||
130 | # http://errors.yoctoproject.org/Errors/Details/20370/ | ||
131 | ARM_INSTRUCTION_SET:armv4 = "arm" | ||
132 | ARM_INSTRUCTION_SET:armv5 = "arm" | ||
133 | ARM_INSTRUCTION_SET:armv6 = "arm" | ||
134 | |||
135 | # https://bugzilla.yoctoproject.org/show_bug.cgi?id=9474 | ||
136 | # https://bugs.webkit.org/show_bug.cgi?id=159880 | ||
137 | # JSC JIT can build on ARMv7 with -marm, but doesn't work on runtime. | ||
138 | # Upstream only tests regularly the JSC JIT on ARMv7 with Thumb2 (-mthumb). | ||
139 | ARM_INSTRUCTION_SET:armv7a = "thumb" | ||
140 | ARM_INSTRUCTION_SET:armv7r = "thumb" | ||
141 | ARM_INSTRUCTION_SET:armv7ve = "thumb" | ||
142 | |||
143 | # ANGLE requires SSE support as of webkit 2.40.x on 32 bit x86 | ||
144 | COMPATIBLE_HOST:x86 = "${@bb.utils.contains_any('TUNE_FEATURES', 'core2 corei7', '.*', 'null', d)}" | ||
145 | |||
146 | # introspection inside qemu-arm hangs forever on musl/arm builds | ||
147 | # therefore disable GI_DATA | ||
148 | GI_DATA_ENABLED:libc-musl:armv7a = "False" | ||
149 | GI_DATA_ENABLED:libc-musl:armv7ve = "False" | ||
150 | |||
151 | # Can't be built with ccache | ||
152 | CCACHE_DISABLE = "1" | ||
153 | |||
154 | PACKAGE_PREPROCESS_FUNCS += "src_package_preprocess" | ||
155 | src_package_preprocess () { | ||
156 | # Trim build paths from comments in generated sources to ensure reproducibility | ||
157 | sed -i -e "s,${WORKDIR},,g" \ | ||
158 | ${B}/JavaScriptCore/DerivedSources/*.h \ | ||
159 | ${B}/JavaScriptCore/DerivedSources/yarr/*.h \ | ||
160 | ${B}/JavaScriptCore/PrivateHeaders/JavaScriptCore/*.h \ | ||
161 | ${B}/WebCore/DerivedSources/*.cpp \ | ||
162 | ${B}/WebKitGTK/DerivedSources/webkit/*.cpp | ||
163 | } | ||
164 | |||