summaryrefslogtreecommitdiffstats
path: root/meta/recipes-sato/webkit/webkitgtk_2.30.5.bb
diff options
context:
space:
mode:
Diffstat (limited to 'meta/recipes-sato/webkit/webkitgtk_2.30.5.bb')
-rw-r--r--meta/recipes-sato/webkit/webkitgtk_2.30.5.bb147
1 files changed, 0 insertions, 147 deletions
diff --git a/meta/recipes-sato/webkit/webkitgtk_2.30.5.bb b/meta/recipes-sato/webkit/webkitgtk_2.30.5.bb
deleted file mode 100644
index 2928b8e55b..0000000000
--- a/meta/recipes-sato/webkit/webkitgtk_2.30.5.bb
+++ /dev/null
@@ -1,147 +0,0 @@
1SUMMARY = "WebKit web rendering engine for the GTK+ platform"
2HOMEPAGE = "https://www.webkitgtk.org/"
3BUGTRACKER = "https://bugs.webkit.org/"
4
5LICENSE = "BSD & LGPLv2+"
6LIC_FILES_CHKSUM = "file://Source/JavaScriptCore/COPYING.LIB;md5=d0c6d6397a5d84286dda758da57bd691 \
7 file://Source/WebCore/LICENSE-APPLE;md5=4646f90082c40bcf298c285f8bab0b12 \
8 file://Source/WebCore/LICENSE-LGPL-2;md5=36357ffde2b64ae177b2494445b79d21 \
9 file://Source/WebCore/LICENSE-LGPL-2.1;md5=a778a33ef338abbaf8b8a7c36b6eec80 \
10 "
11
12SRC_URI = "https://www.webkitgtk.org/releases/${BPN}-${PV}.tar.xz \
13 file://0001-FindGObjectIntrospection.cmake-prefix-variables-obta.patch \
14 file://0001-When-building-introspection-files-add-CMAKE_C_FLAGS-.patch \
15 file://0001-Fix-racy-parallel-build-of-WebKit2-4.0.gir.patch \
16 file://0001-Tweak-gtkdoc-settings-so-that-gtkdoc-generation-work.patch \
17 file://0001-Enable-THREADS_PREFER_PTHREAD_FLAG.patch \
18 file://0001-Fix-build-with-musl.patch \
19 file://include_array.patch \
20 file://include_xutil.patch \
21 "
22SRC_URI[sha256sum] = "7d0dab08e3c5ae07bec80b2822ef42e952765d5724cac86eb23999bfed5a7f1f"
23
24inherit cmake pkgconfig gobject-introspection perlnative features_check upstream-version-is-even gtk-doc
25
26ANY_OF_DISTRO_FEATURES = "${GTK3DISTROFEATURES}"
27REQUIRED_DISTRO_FEATURES = "${@bb.utils.contains('DISTRO_FEATURES', 'wayland', 'opengl', '', d)}"
28
29CVE_PRODUCT = "webkitgtk webkitgtk\+"
30
31DEPENDS = "zlib libsoup-2.4 curl libxml2 cairo libxslt libgcrypt \
32 gtk+3 gstreamer1.0 gstreamer1.0-plugins-base flex-native gperf-native sqlite3 \
33 pango icu bison-native gawk intltool-native libwebp \
34 atk udev harfbuzz jpeg libpng librsvg libtheora libvorbis \
35 ruby-native libnotify gstreamer1.0-plugins-bad \
36 gettext-native glib-2.0 glib-2.0-native libtasn1 \
37 "
38
39PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'systemd wayland x11', d)} \
40 ${@bb.utils.contains('DISTRO_FEATURES', 'x11 opengl', 'webgl opengl', '', d)} \
41 ${@bb.utils.contains('DISTRO_FEATURES', 'x11', '', 'webgl gles2', d)} \
42 enchant \
43 libsecret \
44 "
45
46PACKAGECONFIG[wayland] = "-DENABLE_WAYLAND_TARGET=ON,-DENABLE_WAYLAND_TARGET=OFF,wayland libwpe wpebackend-fdo wayland-native"
47PACKAGECONFIG[x11] = "-DENABLE_X11_TARGET=ON,-DENABLE_X11_TARGET=OFF,virtual/libx11 libxcomposite libxdamage libxrender libxt"
48PACKAGECONFIG[geoclue] = "-DENABLE_GEOLOCATION=ON,-DENABLE_GEOLOCATION=OFF,geoclue"
49PACKAGECONFIG[enchant] = "-DENABLE_SPELLCHECK=ON,-DENABLE_SPELLCHECK=OFF,enchant2"
50PACKAGECONFIG[gles2] = "-DENABLE_GLES2=ON,-DENABLE_GLES2=OFF,virtual/libgles2"
51PACKAGECONFIG[webgl] = "-DENABLE_WEBGL=ON,-DENABLE_WEBGL=OFF,virtual/libgl"
52PACKAGECONFIG[opengl] = "-DENABLE_GRAPHICS_CONTEXT_GL=ON,-DENABLE_GRAPHICS_CONTEXT_GL=OFF,virtual/libgl"
53PACKAGECONFIG[libsecret] = "-DUSE_LIBSECRET=ON,-DUSE_LIBSECRET=OFF,libsecret"
54PACKAGECONFIG[libhyphen] = "-DUSE_LIBHYPHEN=ON,-DUSE_LIBHYPHEN=OFF,libhyphen"
55PACKAGECONFIG[woff2] = "-DUSE_WOFF2=ON,-DUSE_WOFF2=OFF,woff2"
56PACKAGECONFIG[openjpeg] = "-DUSE_OPENJPEG=ON,-DUSE_OPENJPEG=OFF,openjpeg"
57PACKAGECONFIG[systemd] = "-DUSE_SYSTEMD=ON,-DUSE_SYSTEMD=off,systemd"
58
59# webkitgtk is full of /usr/bin/env python, particular for generating docs
60do_configure[postfuncs] += "setup_python_link"
61setup_python_link() {
62 if [ ! -e ${STAGING_BINDIR_NATIVE}/python ]; then
63 ln -s `which python3` ${STAGING_BINDIR_NATIVE}/python
64 fi
65}
66
67EXTRA_OECMAKE = " \
68 -DPORT=GTK \
69 -DCMAKE_BUILD_TYPE=Release \
70 ${@bb.utils.contains('GI_DATA_ENABLED', 'True', '-DENABLE_INTROSPECTION=ON', '-DENABLE_INTROSPECTION=OFF', d)} \
71 ${@bb.utils.contains('GTKDOC_ENABLED', 'True', '-DENABLE_GTKDOC=ON', '-DENABLE_GTKDOC=OFF', d)} \
72 -DENABLE_MINIBROWSER=ON \
73 -DPYTHON_EXECUTABLE=`which python3` \
74 -DENABLE_BUBBLEWRAP_SANDBOX=OFF \
75 "
76
77# Javascript JIT is not supported on ARC
78EXTRA_OECMAKE_append_arc = " -DENABLE_JIT=OFF "
79# By default 25-bit "medium" calls are used on ARC
80# which is not enough for binaries larger than 32 MiB
81CFLAGS_append_arc = " -mlong-calls"
82CXXFLAGS_append_arc = " -mlong-calls"
83
84# Javascript JIT is not supported on powerpc
85EXTRA_OECMAKE_append_powerpc = " -DENABLE_JIT=OFF "
86EXTRA_OECMAKE_append_powerpc64 = " -DENABLE_JIT=OFF "
87
88# ARM JIT code does not build on ARMv4/5/6 anymore
89EXTRA_OECMAKE_append_armv5 = " -DENABLE_JIT=OFF "
90EXTRA_OECMAKE_append_armv6 = " -DENABLE_JIT=OFF "
91EXTRA_OECMAKE_append_armv4 = " -DENABLE_JIT=OFF "
92
93EXTRA_OECMAKE_append_mipsarch = " -DUSE_LD_GOLD=OFF "
94EXTRA_OECMAKE_append_powerpc = " -DUSE_LD_GOLD=OFF "
95
96# JIT and gold linker does not work on RISCV
97EXTRA_OECMAKE_append_riscv32 = " -DUSE_LD_GOLD=OFF -DENABLE_JIT=OFF"
98EXTRA_OECMAKE_append_riscv64 = " -DUSE_LD_GOLD=OFF -DENABLE_JIT=OFF"
99
100# JIT not supported on MIPS either
101EXTRA_OECMAKE_append_mipsarch = " -DENABLE_JIT=OFF -DENABLE_C_LOOP=ON "
102
103# JIT not supported on X32
104# An attempt was made to upstream JIT support for x32 in
105# https://bugs.webkit.org/show_bug.cgi?id=100450, but this was closed as
106# unresolved due to limited X32 adoption.
107EXTRA_OECMAKE_append_x86-x32 = " -DENABLE_JIT=OFF "
108
109SECURITY_CFLAGS_remove_aarch64 = "-fpie"
110SECURITY_CFLAGS_append_aarch64 = " -fPIE"
111
112FILES_${PN} += "${libdir}/webkit2gtk-4.0/injected-bundle/libwebkit2gtkinjectedbundle.so"
113
114RRECOMMENDS_${PN} += "ca-certificates shared-mime-info"
115
116# http://errors.yoctoproject.org/Errors/Details/20370/
117ARM_INSTRUCTION_SET_armv4 = "arm"
118ARM_INSTRUCTION_SET_armv5 = "arm"
119ARM_INSTRUCTION_SET_armv6 = "arm"
120
121# https://bugzilla.yoctoproject.org/show_bug.cgi?id=9474
122# https://bugs.webkit.org/show_bug.cgi?id=159880
123# JSC JIT can build on ARMv7 with -marm, but doesn't work on runtime.
124# Upstream only tests regularly the JSC JIT on ARMv7 with Thumb2 (-mthumb).
125ARM_INSTRUCTION_SET_armv7a = "thumb"
126ARM_INSTRUCTION_SET_armv7r = "thumb"
127ARM_INSTRUCTION_SET_armv7ve = "thumb"
128
129# introspection inside qemu-arm hangs forever on musl/arm builds
130# therefore disable GI_DATA
131GI_DATA_ENABLED_libc-musl_armv7a = "False"
132GI_DATA_ENABLED_libc-musl_armv7ve = "False"
133
134# Can't be built with ccache
135CCACHE_DISABLE = "1"
136
137PACKAGE_PREPROCESS_FUNCS += "src_package_preprocess"
138src_package_preprocess () {
139 # Trim build paths from comments in generated sources to ensure reproducibility
140 sed -i -e "s,${WORKDIR},,g" \
141 ${B}/DerivedSources/webkit2gtk/webkit2/*.cpp \
142 ${B}/DerivedSources/ForwardingHeaders/JavaScriptCore/*.h \
143 ${B}/DerivedSources/JavaScriptCore/*.h \
144 ${B}/DerivedSources/JavaScriptCore/yarr/*.h \
145 ${B}/DerivedSources/MiniBrowser/*.c
146}
147
generated by cgit v1.2.3-54-g00ecf (git 2.39.0) at 2024-04-25 06:23:47 +0000