1 files changed, 60 insertions, 0 deletions

diff --git a/meta/recipes-sato/puzzles/puzzles_r9076.bb b/meta/recipes-sato/puzzles/puzzles_r9076.bb
new file mode 100644
index 0000000000..97582e264c
--- /dev/null
+++ b/meta/recipes-sato/puzzles/puzzles_r9076.bb
@@ -0,0 +1,60 @@
+DESCRIPTION="Simon Tatham's Portable Puzzle Collection"
+HOMEPAGE="http://www.chiark.greenend.org.uk/~sgtatham/puzzles/"
+
+DEPENDS = "gtk+ libxt"
+PR = "r0"
+MOD_PV = "${@bb.data.getVar('PV',d,1)[1:]}"
+
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://LICENCE;md5=9928b60f3b78be315b7ab699c1b03ff5"
+
+SRC_URI = "http://www.chiark.greenend.org.uk/~sgtatham/puzzles/puzzles-${PV}.tar.gz"
+
+SRC_URI[md5sum] = "69a3b81f5fe815f4e6fbb089af9c04f3"
+SRC_URI[sha256sum] = "26343db44dd656cc182e20c78dae0c013bb2f43f6c79c327510ea629a8eb7bbc"
+#SRC_URI = "svn://ixion.tartarus.org/main;module=puzzles;rev=${MOD_PV}"
+
+S = "${WORKDIR}/${PN}-${PV}"
+
+do_configure () {
+        ./mkfiles.pl
+}
+
+do_compile_prepend = " \
+        export XLDFLAGS='${LDFLAGS} `${STAGING_BINDIR_NATIVE}/pkg-config gtk+-2.0 --libs`'; \
+        export CFLAGS='${CFLAGS} -I./ `${STAGING_BINDIR_NATIVE}/pkg-config gtk+-2.0 --cflags`'; "
+
+FILES_${PN} = "${prefix}/games/* ${datadir}/applications/*"
+FILES_${PN}-dbg += "${prefix}/games/.debug"
+
+do_install () {
+    rm -rf ${D}/*
+    export prefix=${D}
+    export DESTDIR=${D}
+    install -d ${D}/${prefix}/
+    install -d ${D}/${prefix}/games/
+    oe_runmake install
+    
+    install -d ${D}/${datadir}/
+    install -d ${D}/${datadir}/applications/
+
+    cd ${D}/${prefix}/games 
+    for prog in *; do
+        if [ -x $prog ]; then
+            # Convert prog to Title Case
+            title=$(echo $prog | sed 's/\(^\| \)./\U&/g')
+            echo "making ${D}/${datadir}/applications/$prog.desktop"
+            cat <<STOP > ${D}/${datadir}/applications/$prog.desktop
+[Desktop Entry]
+Name=$title
+Exec=${prefix}/games/$prog
+Icon=applications-games
+Terminal=false
+Type=Application
+Categories=Game;
+StartupNotify=true
+X-MB-SingleInstance=true
+STOP
+        fi
+    done
+}