summaryrefslogtreecommitdiffstats
path: root/meta/recipes-multimedia/gstreamer/gstreamer1.0_1.16.2.bb
diff options
context:
space:
mode:
Diffstat (limited to 'meta/recipes-multimedia/gstreamer/gstreamer1.0_1.16.2.bb')
-rw-r--r--meta/recipes-multimedia/gstreamer/gstreamer1.0_1.16.2.bb91
1 files changed, 91 insertions, 0 deletions
diff --git a/meta/recipes-multimedia/gstreamer/gstreamer1.0_1.16.2.bb b/meta/recipes-multimedia/gstreamer/gstreamer1.0_1.16.2.bb
new file mode 100644
index 0000000000..96a6ade22b
--- /dev/null
+++ b/meta/recipes-multimedia/gstreamer/gstreamer1.0_1.16.2.bb
@@ -0,0 +1,91 @@
1SUMMARY = "GStreamer 1.0 multimedia framework"
2DESCRIPTION = "GStreamer is a multimedia framework for encoding and decoding video and sound. \
3It supports a wide range of formats including mp3, ogg, avi, mpeg and quicktime."
4HOMEPAGE = "http://gstreamer.freedesktop.org/"
5BUGTRACKER = "https://bugzilla.gnome.org/enter_bug.cgi?product=Gstreamer"
6SECTION = "multimedia"
7LICENSE = "LGPLv2+"
8
9DEPENDS = "glib-2.0 glib-2.0-native libcap libxml2 bison-native flex-native make-native"
10
11inherit autotools pkgconfig gettext upstream-version-is-even gobject-introspection gtk-doc ptest
12
13# This way common/m4/introspection.m4 will come first
14# (it has a custom INTROSPECTION_INIT macro, and so must be used instead of our common introspection.m4 file)
15acpaths = "-I ${S}/common/m4 -I ${S}/m4"
16
17LIC_FILES_CHKSUM = "file://COPYING;md5=6762ed442b3822387a51c92d928ead0d \
18 file://gst/gst.h;beginline=1;endline=21;md5=e059138481205ee2c6fc1c079c016d0d"
19
20S = "${WORKDIR}/gstreamer-${PV}"
21
22SRC_URI = " \
23 https://gstreamer.freedesktop.org/src/gstreamer/gstreamer-${PV}.tar.xz \
24 file://0001-introspection.m4-prefix-pkgconfig-paths-with-PKG_CON.patch \
25 file://gtk-doc-tweaks.patch \
26 file://0001-gst-gstpluginloader.c-when-env-var-is-set-do-not-fal.patch \
27 file://add-a-target-to-compile-tests.patch \
28 file://run-ptest \
29"
30SRC_URI[md5sum] = "0e661ed5bdf1d8996e430228d022628e"
31SRC_URI[sha256sum] = "e3f044246783fd685439647373fa13ba14f7ab0b346eadd06437092f8419e94e"
32
33PACKAGECONFIG ??= "${@bb.utils.contains('PTEST_ENABLED', '1', 'tests', '', d)} \
34 "
35
36PACKAGECONFIG[debug] = "--enable-debug,--disable-debug"
37PACKAGECONFIG[tests] = "--enable-tests,--disable-tests"
38PACKAGECONFIG[valgrind] = "--enable-valgrind,--disable-valgrind,valgrind,"
39PACKAGECONFIG[gst-tracer-hooks] = "--enable-gst-tracer-hooks,--disable-gst-tracer-hooks,"
40PACKAGECONFIG[unwind] = "--with-unwind,--without-unwind,libunwind"
41PACKAGECONFIG[dw] = "--with-dw,--without-dw,elfutils"
42
43EXTRA_OECONF = " \
44 --disable-examples \
45"
46
47CACHED_CONFIGUREVARS += "ac_cv_header_valgrind_valgrind_h=no"
48
49# musl libc generates warnings if <sys/poll.h> is included directly
50CACHED_CONFIGUREVARS += "ac_cv_header_sys_poll_h=no"
51
52PACKAGES += "${PN}-bash-completion"
53
54FILES_${PN} += "${libdir}/gstreamer-1.0/*.so"
55FILES_${PN}-dev += "${libdir}/gstreamer-1.0/*.la ${libdir}/gstreamer-1.0/*.a ${libdir}/gstreamer-1.0/include"
56FILES_${PN}-bash-completion += "${datadir}/bash-completion/completions/ ${datadir}/bash-completion/helpers/gst*"
57FILES_${PN}-dbg += "${datadir}/gdb ${datadir}/gstreamer-1.0/gdb"
58
59RDEPENDS_${PN}-ptest += "make"
60
61delete_pkg_m4_file() {
62 # This m4 file is out of date and is missing PKG_CONFIG_SYSROOT_PATH tweaks which we need for introspection
63 rm "${S}/common/m4/pkg.m4" || true
64 rm -f "${S}/common/m4/gtk-doc.m4"
65}
66
67do_configure[prefuncs] += "delete_pkg_m4_file"
68
69do_compile_prepend() {
70 export GIR_EXTRA_LIBS_PATH="${B}/gst/.libs:${B}/libs/gst/base/.libs"
71}
72
73do_compile_ptest() {
74 oe_runmake build-checks
75}
76
77do_install_ptest() {
78 oe_runmake -C tests/check DESTDIR=${D}${PTEST_PATH} install-ptest
79 install -m 644 ${B}/tests/check/Makefile ${D}${PTEST_PATH}
80 install -m 755 ${S}/test-driver ${D}${PTEST_PATH}
81 sed -e 's,--sysroot=${STAGING_DIR_TARGET},,g' \
82 -e 's|${DEBUG_PREFIX_MAP}||g' \
83 -e 's:${HOSTTOOLS_DIR}/::g' \
84 -e 's:${RECIPE_SYSROOT_NATIVE}::g' \
85 -e 's:${BASE_WORKDIR}/${MULTIMACH_TARGET_SYS}::g' \-e 's/^Makefile:/_Makefile:/' \
86 -e 's/^srcdir = \(.*\)/srcdir = ./' -e 's/^top_srcdir = \(.*\)/top_srcdir = ./' \
87 -e 's/^builddir = \(.*\)/builddir = ./' -e 's/^top_builddir = \(.*\)/top_builddir = ./' \
88 -i ${D}${PTEST_PATH}/Makefile
89}
90
91CVE_PRODUCT = "gstreamer"