summaryrefslogtreecommitdiffstats
path: root/meta/recipes-multimedia/ffmpeg/ffmpeg_3.1.bb
diff options
context:
space:
mode:
Diffstat (limited to 'meta/recipes-multimedia/ffmpeg/ffmpeg_3.1.bb')
-rw-r--r--meta/recipes-multimedia/ffmpeg/ffmpeg_3.1.bb139
1 files changed, 139 insertions, 0 deletions
diff --git a/meta/recipes-multimedia/ffmpeg/ffmpeg_3.1.bb b/meta/recipes-multimedia/ffmpeg/ffmpeg_3.1.bb
new file mode 100644
index 0000000000..2d83ef084f
--- /dev/null
+++ b/meta/recipes-multimedia/ffmpeg/ffmpeg_3.1.bb
@@ -0,0 +1,139 @@
1SUMMARY = "A complete, cross-platform solution to record, convert and stream audio and video."
2DESCRIPTION = "FFmpeg is the leading multimedia framework, able to decode, encode, transcode, \
3 mux, demux, stream, filter and play pretty much anything that humans and machines \
4 have created. It supports the most obscure ancient formats up to the cutting edge."
5HOMEPAGE = "https://www.ffmpeg.org/"
6SECTION = "libs"
7
8LICENSE = "GPLv2+"
9LICENSE_FLAGS = "commercial"
10
11LIC_FILES_CHKSUM = "file://COPYING.GPLv2;md5=b234ee4d69f5fce4486a80fdaf4a4263 \
12 file://COPYING.GPLv3;md5=d32239bcb673463ab874e80d47fae504 \
13 file://COPYING.LGPLv2.1;md5=bd7a443320af8c812e4c18d1b79df004 \
14 file://COPYING.LGPLv3;md5=e6a600fd5e1d9cbde2d983680233ad02"
15
16SRC_URI = "https://www.ffmpeg.org/releases/${BP}.tar.xz"
17
18SRC_URI[md5sum] = "24ef0c0d541c857c8bc39215619b126f"
19SRC_URI[sha256sum] = "919022430e2dad782fabccffdd6c4cae4e7029f84f0701aa662f036a9ca65423"
20
21# Build fails when thumb is enabled: https://bugzilla.yoctoproject.org/show_bug.cgi?id=7717
22ARM_INSTRUCTION_SET = "arm"
23
24# Should be API compatible with libav (which was a fork of ffmpeg)
25# libpostproc was previously packaged from a separate recipe
26PROVIDES = "libav libpostproc"
27
28DEPENDS = "alsa-lib zlib libogg yasm-native"
29
30inherit autotools pkgconfig
31
32PACKAGECONFIG ??= "avdevice avfilter avcodec avformat swresample swscale postproc \
33 bzlib gpl lzma theora x264 \
34 ${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'x11 xv', '', d)}"
35
36# libraries to build in addition to avutil
37PACKAGECONFIG[avdevice] = "--enable-avdevice,--disable-avdevice"
38PACKAGECONFIG[avfilter] = "--enable-avfilter,--disable-avfilter"
39PACKAGECONFIG[avcodec] = "--enable-avcodec,--disable-avcodec"
40PACKAGECONFIG[avformat] = "--enable-avformat,--disable-avformat"
41PACKAGECONFIG[swresample] = "--enable-swresample,--disable-swresample"
42PACKAGECONFIG[swscale] = "--enable-swscale,--disable-swscale"
43PACKAGECONFIG[postproc] = "--enable-postproc,--disable-postproc"
44PACKAGECONFIG[avresample] = "--enable-avresample,--disable-avresample"
45
46# features to support
47PACKAGECONFIG[bzlib] = "--enable-bzlib,--disable-bzlib,bzip2"
48PACKAGECONFIG[faac] = "--enable-libfaac,--disable-libfaac,faac"
49PACKAGECONFIG[gpl] = "--enable-gpl,--disable-gpl"
50PACKAGECONFIG[gsm] = "--enable-libgsm,--disable-libgsm,libgsm"
51PACKAGECONFIG[jack] = "--enable-indev=jack,--disable-indev=jack,jack"
52PACKAGECONFIG[libvorbis] = "--enable-libvorbis,--disable-libvorbis,libvorbis"
53PACKAGECONFIG[lzma] = "--enable-lzma,--disable-lzma,xz"
54PACKAGECONFIG[mp3lame] = "--enable-libmp3lame,--disable-libmp3lame,lame"
55PACKAGECONFIG[openssl] = "--enable-openssl,--disable-openssl,openssl"
56PACKAGECONFIG[schroedinger] = "--enable-libschroedinger,--disable-libschroedinger,schroedinger"
57PACKAGECONFIG[speex] = "--enable-libspeex,--disable-libspeex,speex"
58PACKAGECONFIG[theora] = "--enable-libtheora,--disable-libtheora,libtheora"
59PACKAGECONFIG[vaapi] = "--enable-vaapi,--disable-vaapi,libva"
60PACKAGECONFIG[vpx] = "--enable-libvpx,--disable-libvpx,libvpx"
61PACKAGECONFIG[x11] = "--enable-x11grab,--disable-x11grab,virtual/libx11 libxfixes libxext xproto virtual/libsdl"
62PACKAGECONFIG[x264] = "--enable-libx264,--disable-libx264,x264"
63PACKAGECONFIG[xv] = "--enable-outdev=xv,--disable-outdev=xv,libxv"
64
65# Check codecs that require --enable-nonfree
66USE_NONFREE = "${@bb.utils.contains_any('PACKAGECONFIG', [ 'faac', 'openssl' ], 'yes', '', d)}"
67
68EXTRA_OECONF = " \
69 --disable-stripping \
70 --enable-pic \
71 --enable-shared \
72 --enable-pthreads \
73 ${@bb.utils.contains('USE_NONFREE', 'yes', '--enable-nonfree', '', d)} \
74 \
75 --cross-prefix=${TARGET_PREFIX} \
76 \
77 --ld="${CCLD}" \
78 --arch=${TARGET_ARCH} \
79 --target-os="linux" \
80 --enable-cross-compile \
81 --extra-cflags="${TARGET_CFLAGS} ${HOST_CC_ARCH}${TOOLCHAIN_OPTIONS}" \
82 --extra-ldflags="${TARGET_LDFLAGS}" \
83 --sysroot="${STAGING_DIR_TARGET}" \
84 --enable-hardcoded-tables \
85 ${EXTRA_FFCONF} \
86 --libdir=${libdir} \
87 --shlibdir=${libdir} \
88 --datadir=${datadir}/ffmpeg \
89"
90
91do_configure() {
92 ${S}/configure ${EXTRA_OECONF}
93}
94
95PACKAGES_DYNAMIC += "^lib(av(codec|device|filter|format|util|resample)|swscale|swresample|postproc).*"
96
97# ffmpeg disables PIC on some platforms (e.g. x86-32)
98INSANE_SKIP_${MLPREFIX}libavcodec = "textrel"
99INSANE_SKIP_${MLPREFIX}libavdevice = "textrel"
100INSANE_SKIP_${MLPREFIX}libavfilter = "textrel"
101INSANE_SKIP_${MLPREFIX}libavformat = "textrel"
102INSANE_SKIP_${MLPREFIX}libavutil = "textrel"
103INSANE_SKIP_${MLPREFIX}libavresample = "textrel"
104INSANE_SKIP_${MLPREFIX}libswscale = "textrel"
105INSANE_SKIP_${MLPREFIX}libswresample = "textrel"
106INSANE_SKIP_${MLPREFIX}libpostproc = "textrel"
107
108python populate_packages_prepend() {
109 av_libdir = d.expand('${libdir}')
110 av_pkgconfig = d.expand('${libdir}/pkgconfig')
111
112 # Runtime package
113 do_split_packages(d, av_libdir, '^lib(.*)\.so\..*',
114 output_pattern='lib%s',
115 description='libav %s library',
116 extra_depends='',
117 prepend=True,
118 allow_links=True)
119
120 # Development packages (-dev, -staticdev)
121 do_split_packages(d, av_libdir, '^lib(.*)\.so$',
122 output_pattern='lib%s-dev',
123 description='libav %s development package',
124 extra_depends='${PN}-dev',
125 prepend=True,
126 allow_links=True)
127 do_split_packages(d, av_pkgconfig, '^lib(.*)\.pc$',
128 output_pattern='lib%s-dev',
129 description='libav %s development package',
130 extra_depends='${PN}-dev',
131 prepend=True)
132 do_split_packages(d, av_libdir, '^lib(.*)\.a$',
133 output_pattern='lib%s-staticdev',
134 description='libav %s development package - static library',
135 extra_depends='${PN}-dev',
136 prepend=True,
137 allow_links=True)
138
139}
generated by cgit v1.2.3-54-g00ecf (git 2.39.0) at 2024-11-11 08:04:40 +0000