diff options
Diffstat (limited to 'meta/recipes-multimedia/alsa/alsa-tools_1.2.5.bb')
-rw-r--r-- | meta/recipes-multimedia/alsa/alsa-tools_1.2.5.bb | 88 |
1 files changed, 88 insertions, 0 deletions
diff --git a/meta/recipes-multimedia/alsa/alsa-tools_1.2.5.bb b/meta/recipes-multimedia/alsa/alsa-tools_1.2.5.bb new file mode 100644 index 0000000000..8f9c77e4fc --- /dev/null +++ b/meta/recipes-multimedia/alsa/alsa-tools_1.2.5.bb | |||
@@ -0,0 +1,88 @@ | |||
1 | SUMMARY = "Advanced tools for certain ALSA sound card drivers" | ||
2 | DESCRIPTION = "Package containing a number of tools ranging from envy24control \ | ||
3 | which provides complete control over all devices with an envy24 chip, to \ | ||
4 | firmware loaders for pcmcia, USB and the hdsp devices." | ||
5 | HOMEPAGE = "http://www.alsa-project.org" | ||
6 | BUGTRACKER = "http://alsa-project.org/main/index.php/Bug_Tracking" | ||
7 | SECTION = "console/utils" | ||
8 | LICENSE = "GPLv2 & LGPLv2+" | ||
9 | DEPENDS = "alsa-lib" | ||
10 | |||
11 | LIC_FILES_CHKSUM = "file://hdsploader/COPYING;md5=59530bdf33659b29e73d4adb9f9f6552 \ | ||
12 | file://ld10k1/COPYING.LIB;md5=a916467b91076e631dd8edb7424769c7 \ | ||
13 | " | ||
14 | |||
15 | SRC_URI = "https://www.alsa-project.org/files/pub/tools/${BP}.tar.bz2" | ||
16 | |||
17 | SRC_URI[sha256sum] = "35a71027a01f4d7de4722e223520e940de68b3c570b6c671691567ae28f9893e" | ||
18 | |||
19 | inherit autotools-brokensep pkgconfig | ||
20 | # brokensep as as10k1 (and probably more) fail out of tree | ||
21 | CLEANBROKEN = "1" | ||
22 | |||
23 | # Here we use PACKAGECONFIG options to pick which directories we configure/build. | ||
24 | # Remember on upgrades to check that no new tools have been added. | ||
25 | PACKAGECONFIG ??= "as10k1 hdajacksensetest hda-verb hdsploader ld10k1 mixartloader pcxhrloader \ | ||
26 | sb16_csp seq--sbiload sscape_ctl us428control usx2yloader vxloader \ | ||
27 | ${@bb.utils.contains_any('DISTRO_FEATURES', '${GTK3DISTROFEATURES}', 'hdajackretask', '', d)} \ | ||
28 | " | ||
29 | |||
30 | PACKAGECONFIG[as10k1] = "" | ||
31 | PACKAGECONFIG[echomixer] = ",,gtk+" | ||
32 | PACKAGECONFIG[envy24control] = ",,gtk+" | ||
33 | PACKAGECONFIG[hda-verb] = "" | ||
34 | PACKAGECONFIG[hdajackretask] = ",,gtk+3" | ||
35 | PACKAGECONFIG[hdajacksensetest] = ",,glib-2.0" | ||
36 | PACKAGECONFIG[hdspconf] = ",,fltk" | ||
37 | PACKAGECONFIG[hdsploader] = "" | ||
38 | PACKAGECONFIG[hdspmixer] = ",,fltk" | ||
39 | PACKAGECONFIG[ld10k1] = "" | ||
40 | PACKAGECONFIG[mixartloader] = "" | ||
41 | PACKAGECONFIG[pcxhrloader] = "" | ||
42 | PACKAGECONFIG[qlo10k1] = ",,qt-x11-free" | ||
43 | PACKAGECONFIG[rmedigicontrol] = ",,gtk+" | ||
44 | PACKAGECONFIG[sb16_csp] = "" | ||
45 | PACKAGECONFIG[seq--sbiload] = "" | ||
46 | PACKAGECONFIG[sscape_ctl] = "" | ||
47 | PACKAGECONFIG[us428control] = "" | ||
48 | PACKAGECONFIG[usx2yloader] = "" | ||
49 | PACKAGECONFIG[vxloader] = "" | ||
50 | |||
51 | # At the time of writing pyalsa is not packaged for OE, so this is not expected | ||
52 | # to work. | ||
53 | PACKAGECONFIG[hwmixvolume] = ",,,python-core python-pygobject pyalsa" | ||
54 | |||
55 | python do_configure() { | ||
56 | for subdir in d.getVar("PACKAGECONFIG").split(): | ||
57 | subdir = subdir.replace("--", "/") | ||
58 | bb.note("Configuring %s" % subdir) | ||
59 | dd = d.createCopy() | ||
60 | dd.setVar("S", os.path.join(d.getVar("S"), subdir)) | ||
61 | bb.build.exec_func("autotools_do_configure", dd) | ||
62 | } | ||
63 | |||
64 | python do_compile() { | ||
65 | for subdir in d.getVar("PACKAGECONFIG").split(): | ||
66 | subdir = subdir.replace("--", "/") | ||
67 | bb.note("Compiling %s" % subdir) | ||
68 | dd = d.createCopy() | ||
69 | dd.setVar("S", os.path.join(d.getVar("S"), subdir)) | ||
70 | bb.build.exec_func("autotools_do_compile", dd) | ||
71 | } | ||
72 | |||
73 | python do_install() { | ||
74 | for subdir in d.getVar("PACKAGECONFIG").split(): | ||
75 | subdir = subdir.replace("--", "/") | ||
76 | bb.note("Installing %s" % subdir) | ||
77 | dd = d.createCopy() | ||
78 | dd.setVar("S", os.path.join(d.getVar("S"), subdir)) | ||
79 | bb.build.exec_func("autotools_do_install", dd) | ||
80 | |||
81 | # Just remove bash-needing init script that isn't installed as an init script | ||
82 | try: | ||
83 | os.remove(oe.path.join(d.getVar("D"), d.getVar("sbindir"), "ld10k1d")) | ||
84 | except: | ||
85 | pass | ||
86 | } | ||
87 | |||
88 | FILES_${PN} += "${datadir}" | ||