1 files changed, 44 insertions, 0 deletions

diff --git a/meta/recipes-graphics/xorg-lib/libxt_1.1.4.bb b/meta/recipes-graphics/xorg-lib/libxt_1.1.4.bb
new file mode 100644
index 0000000000..9c1aaa4370
--- /dev/null
+++ b/meta/recipes-graphics/xorg-lib/libxt_1.1.4.bb
@@ -0,0 +1,44 @@
+SUMMARY = "Xt: X Toolkit Intrinsics library"
+
+DESCRIPTION = "The Intrinsics are a programming library tailored to the \
+special requirements of user interface construction within a network \
+window system, specifically the X Window System. The Intrinsics and a \
+widget set make up an X Toolkit. The Intrinsics provide the base \
+mechanism necessary to build a wide variety of interoperating widget \
+sets and application environments. The Intrinsics are a layer on top of \
+Xlib, the C Library X Interface. They extend the fundamental \
+abstractions provided by the X Window System while still remaining \
+independent of any particular user interface policy or style."
+
+require xorg-lib-common.inc
+
+LICENSE = "MIT & MIT-style"
+LIC_FILES_CHKSUM = "file://COPYING;md5=6565b1e0094ea1caae0971cc4035f343"
+
+
+DEPENDS += "util-linux libxcb libsm virtual/libx11 kbproto libxdmcp"
+PROVIDES = "xt"
+
+PE = "1"
+
+XORG_PN = "libXt"
+
+SRC_URI +=  "file://libxt_fix_for_x32.patch"
+
+BBCLASSEXTEND = "native"
+
+EXTRA_OECONF += "--disable-xkb"
+
+do_compile() {
+        (
+                unset CC LD CXX CCLD CFLAGS
+                oe_runmake -C util 'XT_CFLAGS=' 'CC=${BUILD_CC}' 'LD=${BUILD_LD}' 'CXX=${BUILD_CXX}' 'CCLD=${BUILD_CCLD}' 'CFLAGS=-D_GNU_SOURCE -I${STAGING_INCDIR_NATIVE} ${BUILD_CFLAGS}' 'LDFLAGS=${BUILD_LDFLAGS}' 'CXXFLAGS=${BUILD_CXXFLAGS}' 'CPPFLAGS=${BUILD_CPPFLAGS}' makestrs
+        )
+        if [ "$?" != "0" ]; then
+                exit 1
+        fi
+        oe_runmake
+}
+
+SRC_URI[md5sum] = "03149823ae57bb02d0cec90d5b97d56c"
+SRC_URI[sha256sum] = "843a97a988f5654872682a4120486d987d853a71651515472f55519ffae2dd57"