3 files changed, 51 insertions, 0 deletions

diff --git a/meta/recipes-extended/sysstat/sysstat.inc b/meta/recipes-extended/sysstat/sysstat.inc
new file mode 100644
index 0000000000..09a5d28d4a
--- /dev/null
+++ b/meta/recipes-extended/sysstat/sysstat.inc
@@ -0,0 +1,44 @@
+SUMMARY = "System performance tools"
+DESCRIPTION = "The sysstat utilities are a collection of performance monitoring tools for Linux."
+HOMEPAGE = "http://sebastien.godard.pagesperso-orange.fr/"
+LICENSE = "GPLv2+"
+SECTION = "console/utils"
+
+SRC_URI = "http://pagesperso-orange.fr/sebastien.godard/sysstat-${PV}.tar.gz \
+           file://99_sysstat \
+          "
+
+inherit autotools-brokensep gettext
+
+EXTRA_OECONF += "--disable-sensors"
+EXTRA_OEMAKE += 'LFLAGS=""'
+
+do_configure_prepend() {
+    export sa_lib_dir=${libdir}/sa
+}
+
+do_install() {
+        autotools_do_install
+
+        # don't install /var/log/sa when populating rootfs. Do it through volatile
+
+        rm -rf ${D}/var
+        install -d ${D}/etc/default/volatiles
+        install -m 0644 ${WORKDIR}/99_sysstat ${D}/etc/default/volatiles
+}
+
+pkg_postinst_${PN} () {
+        if [ -n "$D" ]; then
+                exit 0
+        fi
+        if [ -e /etc/init.d/populate-volatile.sh ]; then
+                /etc/init.d/populate-volatile.sh update
+        fi
+}
+
+
+FILES_${PN} += "${libdir}/sa"
+FILES_${PN}-dbg += "${libdir}/sa/.debug/"
+
+TARGET_CC_ARCH += "${LDFLAGS}"
+LDFLAGS_append_libc-uclibc = " -lintl"
diff --git a/meta/recipes-extended/sysstat/sysstat/99_sysstat b/meta/recipes-extended/sysstat/sysstat/99_sysstat
new file mode 100644
index 0000000000..0b0ec30de0
--- /dev/null
+++ b/meta/recipes-extended/sysstat/sysstat/99_sysstat
@@ -0,0 +1 @@
+d root root 0755 /var/log/sa none
diff --git a/meta/recipes-extended/sysstat/sysstat_10.2.1.bb b/meta/recipes-extended/sysstat/sysstat_10.2.1.bb
new file mode 100644
index 0000000000..654457dbe1
--- /dev/null
+++ b/meta/recipes-extended/sysstat/sysstat_10.2.1.bb
@@ -0,0 +1,6 @@
+require sysstat.inc
+
+LIC_FILES_CHKSUM = "file://COPYING;md5=8ca43cbc842c2336e835926c2166c28b"
+
+SRC_URI[md5sum] = "039dcd235dfcfb3d4acc0a05730f9512"
+SRC_URI[sha256sum] = "3bfd1b4c5b99314585709c092096234b6e181741729f601d18d0ed7f0612612a"