1 files changed, 73 insertions, 5 deletions

diff --git a/meta/recipes-extended/sysstat/sysstat_12.6.2.bb b/meta/recipes-extended/sysstat/sysstat_12.6.2.bb
index b5014eaefb..335ddd5746 100644
--- a/meta/recipes-extended/sysstat/sysstat_12.6.2.bb
+++ b/meta/recipes-extended/sysstat/sysstat_12.6.2.bb
@@ -1,9 +1,77 @@
-require sysstat.inc
+SUMMARY = "System performance tools"
+DESCRIPTION = "The sysstat utilities are a collection of performance monitoring tools for Linux."
+HOMEPAGE = "http://sebastien.godard.pagesperso-orange.fr/"
+LICENSE = "GPL-2.0-or-later"
+SECTION = "console/utils"
 
-LIC_FILES_CHKSUM = "file://COPYING;md5=a23a74b3f4caf9616230789d94217acb"
+SRC_URI = "http://pagesperso-orange.fr/sebastien.godard/${BP}.tar.xz \
+           file://99_sysstat \
+           file://sysstat.service \
+           file://0001-configure.in-remove-check-for-chkconfig.patch \
+           file://CVE-2023-33204.patch \
+          "
 
-SRC_URI += "file://0001-configure.in-remove-check-for-chkconfig.patch \
-            file://CVE-2023-33204.patch \
-            "
+LIC_FILES_CHKSUM = "file://COPYING;md5=a23a74b3f4caf9616230789d94217acb"
 
 SRC_URI[sha256sum] = "3e77134aedaa6fc57d9745da67edfd8990e19adee71ac47196229261c563fb48"
+UPSTREAM_CHECK_URI = "http://sebastien.godard.pagesperso-orange.fr/download.html"
+
+DEPENDS += "base-passwd"
+
+# autotools-brokensep as this package doesn't use automake
+inherit autotools-brokensep gettext systemd upstream-version-is-even
+
+PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'systemd', d)}"
+PACKAGECONFIG[lm-sensors] = "--enable-sensors,--disable-sensors,lmsensors,lmsensors-libsensors"
+PACKAGECONFIG[cron] = "--enable-install-cron --enable-copy-only,--disable-install-cron --disable-copy-only"
+PACKAGECONFIG[systemd] = "--with-systemdsystemunitdir=${systemd_system_unitdir}"
+
+EXTRA_OECONF += "--disable-stripping"
+
+SYSTEMD_PACKAGES = "${PN}"
+SYSTEMD_SERVICE:${PN} = "sysstat.service"
+SYSTEMD_AUTO_ENABLE = "enable"
+
+do_configure:prepend() {
+    export sa_lib_dir=${libexecdir}/sa
+}
+
+do_install() {
+        autotools_do_install
+
+        # Don't version the documentation
+        mv ${D}${docdir}/${BP} ${D}${docdir}/${BPN}
+
+        # don't install /var/log/sa when populating rootfs. Do it through volatile
+        rm -rf ${D}/var
+        if ${@bb.utils.contains('DISTRO_FEATURES', 'sysvinit', 'true', 'false', d)}; then
+                install -d ${D}/etc/default/volatiles
+                install -m 0644 ${WORKDIR}/99_sysstat ${D}/etc/default/volatiles
+        fi
+        if ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'true', 'false', d)}; then
+                install -d ${D}${sysconfdir}/tmpfiles.d
+                echo "d ${localstatedir}/log/sa - - - -" \
+                     > ${D}${sysconfdir}/tmpfiles.d/sysstat.conf
+
+                # Unless both cron and systemd are enabled, install our own
+                # systemd unit file. Otherwise the package will install one.
+                if ${@bb.utils.contains('PACKAGECONFIG', 'cron systemd', 'false', 'true', d)}; then
+                        install -d ${D}${systemd_system_unitdir}
+                        install -m 0644 ${WORKDIR}/sysstat.service ${D}${systemd_system_unitdir}
+                        sed -i -e 's#@LIBEXECDIR@#${libexecdir}#g' ${D}${systemd_system_unitdir}/sysstat.service
+                fi
+        fi
+}
+
+pkg_postinst:${PN} () {
+        if [  ! -n "$D" ]; then
+                if [ -e /etc/init.d/populate-volatile.sh ]; then
+                        /etc/init.d/populate-volatile.sh update
+                fi
+        fi
+}
+
+FILES:${PN} += "${systemd_system_unitdir} ${nonarch_base_libdir}/systemd"
+
+TARGET_CC_ARCH += "${LDFLAGS}"
+