1 files changed, 36 insertions, 0 deletions

diff --git a/meta/recipes-extended/stress-ng/stress-ng_0.17.01.bb b/meta/recipes-extended/stress-ng/stress-ng_0.17.01.bb
new file mode 100644
index 0000000000..b6fd96d857
--- /dev/null
+++ b/meta/recipes-extended/stress-ng/stress-ng_0.17.01.bb
@@ -0,0 +1,36 @@
+SUMMARY = "System load testing utility"
+DESCRIPTION = "Deliberately simple workload generator for POSIX systems. It \
+imposes a configurable amount of CPU, memory, I/O, and disk stress on the system."
+HOMEPAGE = "https://github.com/ColinIanKing/stress-ng#readme"
+LICENSE = "GPL-2.0-only"
+LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
+
+SRC_URI = "git://github.com/ColinIanKing/stress-ng.git;protocol=https;branch=master \
+           "
+SRCREV = "c9669b041eff5905da191974ba0102208a59e04e"
+S = "${WORKDIR}/git"
+
+DEPENDS = "coreutils-native libbsd"
+
+PROVIDES = "stress"
+RPROVIDES:${PN} = "stress"
+RREPLACES:${PN} = "stress"
+RCONFLICTS:${PN} = "stress"
+
+inherit bash-completion
+
+EXTRA_OEMAKE = "VERBOSE=1"
+
+do_configure() {
+    mkdir -p configs
+    touch configs/HAVE_APPARMOR
+    oe_runmake makeconfig
+}
+
+do_install() {
+    oe_runmake DESTDIR=${D} BINDIR=${bindir} install
+    ln -s stress-ng ${D}${bindir}/stress
+}
+
+# upstream issue: https://github.com/ColinIanKing/stress-ng/issues/315
+DEBUG_BUILD = "0"