summaryrefslogtreecommitdiffstats
path: root/meta/recipes-extended/screen/screen_4.4.0.bb
diff options
context:
space:
mode:
Diffstat (limited to 'meta/recipes-extended/screen/screen_4.4.0.bb')
-rw-r--r--meta/recipes-extended/screen/screen_4.4.0.bb51
1 files changed, 51 insertions, 0 deletions
diff --git a/meta/recipes-extended/screen/screen_4.4.0.bb b/meta/recipes-extended/screen/screen_4.4.0.bb
new file mode 100644
index 0000000000..e970c5b0fc
--- /dev/null
+++ b/meta/recipes-extended/screen/screen_4.4.0.bb
@@ -0,0 +1,51 @@
1SUMMARY = "Multiplexing terminal manager"
2DESCRIPTION = "Screen is a full-screen window manager \
3that multiplexes a physical terminal between several \
4processes, typically interactive shells."
5HOMEPAGE = "http://www.gnu.org/software/screen/"
6BUGTRACKER = "https://savannah.gnu.org/bugs/?func=additem&group=screen"
7
8SECTION = "console/utils"
9
10LICENSE = "GPLv3+"
11LIC_FILES_CHKSUM = "file://COPYING;md5=d32239bcb673463ab874e80d47fae504 \
12 file://screen.h;endline=26;md5=3971142989289a8198a544220703c2bf"
13
14DEPENDS = "ncurses \
15 ${@bb.utils.contains('DISTRO_FEATURES', 'pam', 'libpam', '', d)}"
16RDEPENDS_${PN} = "base-files"
17
18SRC_URI = "${GNU_MIRROR}/screen/screen-${PV}.tar.gz \
19 file://fix-parallel-make.patch \
20 ${@bb.utils.contains('DISTRO_FEATURES', 'pam', 'file://screen.pam', '', d)} \
21 file://Remove-redundant-compiler-sanity-checks.patch \
22 file://Provide-cross-compile-alternatives-for-AC_TRY_RUN.patch \
23 file://Skip-host-file-system-checks-when-cross-compiling.patch \
24 file://Avoid-mis-identifying-systems-as-SVR4.patch \
25 file://0002-comm.h-now-depends-on-term.h.patch \
26 "
27
28SRC_URI[md5sum] = "d26e11a3648c2b11aaefa215a55dfd39"
29SRC_URI[sha256sum] = "ef722a54759a3bf23aad272bbf33c414c1078cad6bcd982fada93c0d7917218b"
30
31inherit autotools texinfo
32
33PACKAGECONFIG ??= ""
34PACKAGECONFIG[utempter] = "ac_cv_header_utempter_h=yes,ac_cv_header_utempter_h=no,libutempter,"
35
36EXTRA_OECONF = "--with-pty-mode=0620 --with-pty-group=5 \
37 ${@bb.utils.contains('DISTRO_FEATURES', 'pam', '--enable-pam', '--disable-pam', d)}"
38
39do_install_append () {
40 if [ "${@bb.utils.contains('DISTRO_FEATURES', 'pam', 'pam', '', d)}" = "pam" ]; then
41 install -D -m 644 ${WORKDIR}/screen.pam ${D}/${sysconfdir}/pam.d/screen
42 fi
43}
44
45pkg_postinst_${PN} () {
46 grep -q "^${bindir}/screen$" $D${sysconfdir}/shells || echo ${bindir}/screen >> $D${sysconfdir}/shells
47}
48
49pkg_postrm_${PN} () {
50 printf "$(grep -v "^${bindir}/screen$" $D${sysconfdir}/shells)\n" > $D${sysconfdir}/shells
51}