summaryrefslogtreecommitdiffstats
path: root/meta/recipes-extended/bzip2/bzip2_1.0.6.bb
diff options
context:
space:
mode:
Diffstat (limited to 'meta/recipes-extended/bzip2/bzip2_1.0.6.bb')
-rw-r--r--meta/recipes-extended/bzip2/bzip2_1.0.6.bb54
1 files changed, 54 insertions, 0 deletions
diff --git a/meta/recipes-extended/bzip2/bzip2_1.0.6.bb b/meta/recipes-extended/bzip2/bzip2_1.0.6.bb
new file mode 100644
index 0000000000..9dd9e6a1f9
--- /dev/null
+++ b/meta/recipes-extended/bzip2/bzip2_1.0.6.bb
@@ -0,0 +1,54 @@
1SUMMARY = "Very high-quality data compression program"
2DESCRIPTION = "bzip2 compresses files using the Burrows-Wheeler block-sorting text compression algorithm, and \
3Huffman coding. Compression is generally considerably better than that achieved by more conventional \
4LZ77/LZ78-based compressors, and approaches the performance of the PPM family of statistical compressors."
5HOMEPAGE = "http://www.bzip.org/"
6SECTION = "console/utils"
7LICENSE = "bzip2"
8LIC_FILES_CHKSUM = "file://LICENSE;beginline=8;endline=37;md5=40d9d1eb05736d1bfc86cfdd9106e6b2"
9PR = "r5"
10
11SRC_URI = "http://www.bzip.org/${PV}/${BPN}-${PV}.tar.gz \
12 file://configure.ac \
13 file://run-ptest \
14 file://Makefile.am"
15
16SRC_URI[md5sum] = "00b516f4704d4a7cb50a1d97e6e8e15b"
17SRC_URI[sha256sum] = "a2848f34fcd5d6cf47def00461fcb528a0484d8edef8208d6d2e2909dc61d9cd"
18
19PACKAGES =+ "libbz2 libbz2-dev libbz2-staticdev"
20
21CFLAGS_append = " -fPIC -fpic -Winline -fno-strength-reduce -D_FILE_OFFSET_BITS=64"
22
23inherit autotools update-alternatives ptest
24
25ALTERNATIVE_PRIORITY = "100"
26ALTERNATIVE_${PN} = "bunzip2 bzcat"
27
28#install binaries to bzip2-native under sysroot for replacement-native
29EXTRA_OECONF_append_class-native = " --bindir=${STAGING_BINDIR_NATIVE}/${PN}"
30do_extraunpack () {
31 cp ${WORKDIR}/configure.ac ${S}/
32 cp ${WORKDIR}/Makefile.am ${S}/
33}
34
35addtask extraunpack after do_unpack before do_patch
36
37do_install_ptest () {
38 cp -f ${B}/Makefile ${D}${PTEST_PATH}/Makefile
39 sed -i -e "s|^Makefile:|_Makefile:|" ${D}${PTEST_PATH}/Makefile
40}
41
42FILES_libbz2 = "${libdir}/lib*${SOLIBS}"
43
44FILES_libbz2-dev = "${includedir} ${libdir}/lib*${SOLIBSDEV}"
45SECTION_libbz2-dev = "devel"
46RDEPENDS_libbz2-dev = "libbz2 (= ${EXTENDPKGV})"
47
48FILES_libbz2-staticdev = "${libdir}/*.a"
49SECTION_libbz2-staticdev = "devel"
50RDEPENDS_libbz2-staticdev = "libbz2-dev (= ${EXTENDPKGV})"
51
52PROVIDES_append_class-native = " bzip2-replacement-native"
53BBCLASSEXTEND = "native nativesdk"
54