summaryrefslogtreecommitdiffstats
path: root/meta/recipes-extended/at/at_3.1.13.bb
diff options
context:
space:
mode:
Diffstat (limited to 'meta/recipes-extended/at/at_3.1.13.bb')
-rw-r--r--meta/recipes-extended/at/at_3.1.13.bb63
1 files changed, 63 insertions, 0 deletions
diff --git a/meta/recipes-extended/at/at_3.1.13.bb b/meta/recipes-extended/at/at_3.1.13.bb
new file mode 100644
index 0000000000..bcc08aa2f1
--- /dev/null
+++ b/meta/recipes-extended/at/at_3.1.13.bb
@@ -0,0 +1,63 @@
1SUMMARY = "Delayed job execution and batch processing"
2DESCRIPTION = "At allows for commands to be run at a particular time. Batch will execute commands when \
3the system load levels drop to a particular level."
4SECTION = "base"
5LICENSE="GPLv2+"
6LIC_FILES_CHKSUM = "file://COPYING;md5=4325afd396febcb659c36b49533135d4"
7DEPENDS = "flex initscripts \
8 ${@base_contains('DISTRO_FEATURES', 'pam', 'libpam', '', d)}"
9RDEPENDS_${PN} = "${@base_contains('DISTRO_FEATURES', 'pam', '${PAM_DEPS}', '', d)}"
10PAM_DEPS = "libpam libpam-runtime pam-plugin-env pam-plugin-limits"
11
12RCONFLICTS_${PN} = "atd"
13RREPLACES_${PN} = "atd"
14PR = "r0"
15
16SRC_URI = "${DEBIAN_MIRROR}/main/a/at/at_${PV}.orig.tar.gz \
17 file://configure.patch \
18 file://use-ldflags.patch \
19 file://fix_parallel_build_error.patch \
20 file://posixtm.c \
21 file://posixtm.h \
22 file://file_replacement_with_gplv2.patch \
23 file://S99at \
24 ${@base_contains('DISTRO_FEATURES', 'pam', '${PAM_SRC_URI}', '', d)}"
25
26PAM_SRC_URI = "file://pam.conf.patch \
27 file://configure-add-enable-pam.patch"
28
29SRC_URI[md5sum] = "1da61af6c29e323abaaf13ee1a8dad79"
30SRC_URI[sha256sum] = "3a8b90868d615d21a92f4986ea9a823886329af8fae8dd7ab4eed9b273bca072"
31
32EXTRA_OECONF += "ac_cv_path_SENDMAIL=/bin/true \
33 --with-daemon_username=root \
34 --with-daemon_groupname=root \
35 --with-jobdir=/var/spool/at/jobs \
36 --with-atspool=/var/spool/at/spool \
37 ${@base_contains('DISTRO_FEATURES', 'pam', '--with-pam', '--without-pam', d)} "
38
39inherit autotools
40
41PARALLEL_MAKE = ""
42
43do_compile_prepend () {
44 cp -f ${WORKDIR}/posixtm.[ch] ${S}
45}
46
47do_install () {
48 oe_runmake "IROOT=${D}" install
49
50 install -d ${D}${sysconfdir}/init.d
51 install -d ${D}${sysconfdir}/rcS.d
52 install -m 0755 ${WORKDIR}/S99at ${D}${sysconfdir}/init.d/atd
53 ln -sf ../init.d/atd ${D}${sysconfdir}/rcS.d/S99at
54 cp -r ${D}/usr/doc/at ${D}${docdir}/
55 rm -rf ${D}/usr/doc
56
57 for feature in ${DISTRO_FEATURES}; do
58 if [ "$feature" = "pam" ]; then
59 install -D -m 0644 ${WORKDIR}/${P}/pam.conf ${D}${sysconfdir}/pam.d/atd
60 break
61 fi
62 done
63}