summaryrefslogtreecommitdiffstats
path: root/meta/recipes-devtools/python/python3_3.9.2.bb
diff options
context:
space:
mode:
Diffstat (limited to 'meta/recipes-devtools/python/python3_3.9.2.bb')
-rw-r--r--meta/recipes-devtools/python/python3_3.9.2.bb382
1 files changed, 0 insertions, 382 deletions
diff --git a/meta/recipes-devtools/python/python3_3.9.2.bb b/meta/recipes-devtools/python/python3_3.9.2.bb
deleted file mode 100644
index af1843a180..0000000000
--- a/meta/recipes-devtools/python/python3_3.9.2.bb
+++ /dev/null
@@ -1,382 +0,0 @@
1SUMMARY = "The Python Programming Language"
2HOMEPAGE = "http://www.python.org"
3DESCRIPTION = "Python is a programming language that lets you work more quickly and integrate your systems more effectively."
4LICENSE = "PSFv2"
5SECTION = "devel/python"
6
7LIC_FILES_CHKSUM = "file://LICENSE;md5=c22d2438294c784731bf9dd224a467b7"
8
9SRC_URI = "http://www.python.org/ftp/python/${PV}/Python-${PV}.tar.xz \
10 file://run-ptest \
11 file://create_manifest3.py \
12 file://get_module_deps3.py \
13 file://python3-manifest.json \
14 file://check_build_completeness.py \
15 file://reformat_sysconfig.py \
16 file://cgi_py.patch \
17 file://0001-Do-not-add-usr-lib-termcap-to-linker-flags-to-avoid-.patch \
18 ${@bb.utils.contains('PACKAGECONFIG', 'tk', '', 'file://avoid_warning_about_tkinter.patch', d)} \
19 file://0001-Do-not-use-the-shell-version-of-python-config-that-w.patch \
20 file://python-config.patch \
21 file://0001-Makefile.pre-use-qemu-wrapper-when-gathering-profile.patch \
22 file://0001-python3-use-cc_basename-to-replace-CC-for-checking-c.patch \
23 file://0001-Makefile-fix-Issue36464-parallel-build-race-problem.patch \
24 file://0001-bpo-36852-proper-detection-of-mips-architecture-for-.patch \
25 file://crosspythonpath.patch \
26 file://0001-Use-FLAG_REF-always-for-interned-strings.patch \
27 file://0001-test_locale.py-correct-the-test-output-format.patch \
28 file://0017-setup.py-do-not-report-missing-dependencies-for-disa.patch \
29 file://0001-setup.py-pass-missing-libraries-to-Extension-for-mul.patch \
30 file://0001-Makefile-do-not-compile-.pyc-in-parallel.patch \
31 file://0020-configure.ac-setup.py-do-not-add-a-curses-include-pa.patch \
32 file://0001-Lib-sysconfig.py-use-libdir-values-from-configuratio.patch \
33 "
34
35SRC_URI_append_class-native = " \
36 file://0001-distutils-sysconfig-append-STAGING_LIBDIR-python-sys.patch \
37 file://12-distutils-prefix-is-inside-staging-area.patch \
38 file://0001-Don-t-search-system-for-headers-libraries.patch \
39 "
40SRC_URI[sha256sum] = "3c2034c54f811448f516668dce09d24008a0716c3a794dd8639b5388cbde247d"
41
42# exclude pre-releases for both python 2.x and 3.x
43UPSTREAM_CHECK_REGEX = "[Pp]ython-(?P<pver>\d+(\.\d+)+).tar"
44UPSTREAM_CHECK_URI = "https://www.python.org/downloads/source/"
45
46CVE_PRODUCT = "python"
47
48# Upstream consider this expected behaviour
49CVE_CHECK_WHITELIST += "CVE-2007-4559"
50# This is not exploitable when glibc has CVE-2016-10739 fixed.
51CVE_CHECK_WHITELIST += "CVE-2019-18348"
52
53# This is windows only issue.
54CVE_CHECK_WHITELIST += "CVE-2020-15523"
55
56PYTHON_MAJMIN = "3.9"
57
58S = "${WORKDIR}/Python-${PV}"
59
60BBCLASSEXTEND = "native nativesdk"
61
62inherit autotools pkgconfig qemu ptest multilib_header update-alternatives
63
64MULTILIB_SUFFIX = "${@d.getVar('base_libdir',1).split('/')[-1]}"
65
66ALTERNATIVE_${PN}-dev = "python3-config"
67ALTERNATIVE_LINK_NAME[python3-config] = "${bindir}/python${PYTHON_MAJMIN}-config"
68ALTERNATIVE_TARGET[python3-config] = "${bindir}/python${PYTHON_MAJMIN}-config-${MULTILIB_SUFFIX}"
69
70
71DEPENDS = "bzip2-replacement-native libffi bzip2 openssl sqlite3 zlib virtual/libintl xz virtual/crypt util-linux libtirpc libnsl2"
72DEPENDS_append_class-target = " python3-native"
73DEPENDS_append_class-nativesdk = " python3-native"
74
75EXTRA_OECONF = " --without-ensurepip --enable-shared --with-platlibdir=${baselib}"
76EXTRA_OECONF_append_class-native = " --bindir=${bindir}/${PN}"
77
78export CROSSPYTHONPATH="${STAGING_LIBDIR_NATIVE}/python${PYTHON_MAJMIN}/lib-dynload/"
79
80EXTRANATIVEPATH += "python3-native"
81
82# LTO will be enabled via packageconfig depending upong distro features
83LTO_class-target = ""
84
85CACHED_CONFIGUREVARS = " \
86 ac_cv_file__dev_ptmx=yes \
87 ac_cv_file__dev_ptc=no \
88 ac_cv_working_tzset=yes \
89"
90
91def possibly_include_pgo(d):
92 # PGO currently causes builds to not be reproducible, so disable it for
93 # now. See YOCTO #13407
94 if bb.utils.contains('MACHINE_FEATURES', 'qemu-usermode', True, False, d) and d.getVar('BUILD_REPRODUCIBLE_BINARIES') != '1':
95 return 'pgo'
96
97 return ''
98
99PACKAGECONFIG_class-target ??= "readline ${@possibly_include_pgo(d)} gdbm ${@bb.utils.filter('DISTRO_FEATURES', 'lto', d)}"
100PACKAGECONFIG_class-native ??= "readline gdbm"
101PACKAGECONFIG_class-nativesdk ??= "readline gdbm"
102PACKAGECONFIG[readline] = ",,readline"
103# Use profile guided optimisation by running PyBench inside qemu-user
104PACKAGECONFIG[pgo] = "--enable-optimizations,,qemu-native"
105PACKAGECONFIG[tk] = ",,tk"
106PACKAGECONFIG[gdbm] = ",,gdbm"
107PACKAGECONFIG[lto] = "--with-lto,,"
108
109do_configure_prepend () {
110 mkdir -p ${B}/Modules
111 cat > ${B}/Modules/Setup.local << EOF
112*disabled*
113${@bb.utils.contains('PACKAGECONFIG', 'gdbm', '', '_gdbm _dbm', d)}
114${@bb.utils.contains('PACKAGECONFIG', 'readline', '', 'readline', d)}
115EOF
116}
117
118CPPFLAGS_append = " -I${STAGING_INCDIR}/ncursesw -I${STAGING_INCDIR}/uuid"
119
120EXTRA_OEMAKE = '\
121 STAGING_LIBDIR=${STAGING_LIBDIR} \
122 STAGING_INCDIR=${STAGING_INCDIR} \
123 LIB=${baselib} \
124'
125
126do_compile_prepend_class-target() {
127 if ${@bb.utils.contains('PACKAGECONFIG', 'pgo', 'true', 'false', d)}; then
128 qemu_binary="${@qemu_wrapper_cmdline(d, '${STAGING_DIR_TARGET}', ['${B}', '${STAGING_DIR_TARGET}/${base_libdir}'])}"
129 cat >pgo-wrapper <<EOF
130#!/bin/sh
131cd ${B}
132$qemu_binary "\$@"
133EOF
134 chmod +x pgo-wrapper
135 fi
136}
137
138do_install_prepend() {
139 ${WORKDIR}/check_build_completeness.py ${T}/log.do_compile
140}
141
142do_install_append_class-target() {
143 oe_multilib_header python${PYTHON_MAJMIN}/pyconfig.h
144}
145
146do_install_append_class-native() {
147 # Make sure we use /usr/bin/env python
148 for PYTHSCRIPT in `grep -rIl ${bindir}/${PN}/python ${D}${bindir}/${PN}`; do
149 sed -i -e '1s|^#!.*|#!/usr/bin/env python3|' $PYTHSCRIPT
150 done
151 # Add a symlink to the native Python so that scripts can just invoke
152 # "nativepython" and get the right one without needing absolute paths
153 # (these often end up too long for the #! parser in the kernel as the
154 # buffer is 128 bytes long).
155 ln -s python3-native/python3 ${D}${bindir}/nativepython3
156}
157
158do_install_append() {
159 mkdir -p ${D}${libdir}/python-sysconfigdata
160 sysconfigfile=`find ${D} -name _sysconfig*.py`
161 cp $sysconfigfile ${D}${libdir}/python-sysconfigdata/_sysconfigdata.py
162
163 sed -i \
164 -e "s,^ 'LIBDIR'.*, 'LIBDIR': '${STAGING_LIBDIR}'\,,g" \
165 -e "s,^ 'INCLUDEDIR'.*, 'INCLUDEDIR': '${STAGING_INCDIR}'\,,g" \
166 -e "s,^ 'CONFINCLUDEDIR'.*, 'CONFINCLUDEDIR': '${STAGING_INCDIR}'\,,g" \
167 -e "/^ 'INCLDIRSTOMAKE'/{N; s,/usr/include,${STAGING_INCDIR},g}" \
168 -e "/^ 'INCLUDEPY'/s,/usr/include,${STAGING_INCDIR},g" \
169 ${D}${libdir}/python-sysconfigdata/_sysconfigdata.py
170
171 # Unfortunately the following pyc files are non-deterministc due to 'frozenset'
172 # being written without strict ordering, even with PYTHONHASHSEED = 0
173 # Upstream is discussing ways to solve the issue properly, until then let's
174 # just not install the problematic files.
175 # More info: http://benno.id.au/blog/2013/01/15/python-determinism
176 rm ${D}${libdir}/python${PYTHON_MAJMIN}/test/__pycache__/test_range.cpython*
177 rm ${D}${libdir}/python${PYTHON_MAJMIN}/test/__pycache__/test_xml_etree.cpython*
178}
179
180do_install_append_class-nativesdk () {
181 # Make sure we use /usr/bin/env python
182 for PYTHSCRIPT in `grep -rIl ${bindir}/python ${D}${bindir}`; do
183 sed -i -e '1s|^#!.*|#!/usr/bin/env python3|' $PYTHSCRIPT
184 done
185 create_wrapper ${D}${bindir}/python${PYTHON_MAJMIN} TERMINFO_DIRS='${sysconfdir}/terminfo:/etc/terminfo:/usr/share/terminfo:/usr/share/misc/terminfo:/lib/terminfo' PYTHONNOUSERSITE='1'
186}
187
188SSTATE_SCAN_FILES += "Makefile _sysconfigdata.py"
189PACKAGE_PREPROCESS_FUNCS += "py_package_preprocess"
190
191py_package_preprocess () {
192 # Remove references to buildmachine paths in target Makefile and _sysconfigdata
193 sed -i -e 's:--sysroot=${STAGING_DIR_TARGET}::g' -e s:'--with-libtool-sysroot=${STAGING_DIR_TARGET}'::g \
194 -e 's|${DEBUG_PREFIX_MAP}||g' \
195 -e 's:${HOSTTOOLS_DIR}/::g' \
196 -e 's:${RECIPE_SYSROOT_NATIVE}::g' \
197 -e 's:${RECIPE_SYSROOT}::g' \
198 -e 's:${BASE_WORKDIR}/${MULTIMACH_TARGET_SYS}::g' \
199 ${PKGD}/${libdir}/python${PYTHON_MAJMIN}/config-${PYTHON_MAJMIN}${PYTHON_ABI}*/Makefile \
200 ${PKGD}/${libdir}/python${PYTHON_MAJMIN}/_sysconfigdata*.py \
201 ${PKGD}/${bindir}/python${PYTHON_MAJMIN}-config
202
203 # Reformat _sysconfigdata after modifying it so that it remains
204 # reproducible
205 for c in ${PKGD}/${libdir}/python${PYTHON_MAJMIN}/_sysconfigdata*.py; do
206 python3 ${WORKDIR}/reformat_sysconfig.py $c
207 done
208
209 # Recompile _sysconfigdata after modifying it
210 cd ${PKGD}
211 sysconfigfile=`find . -name _sysconfigdata_*.py`
212 ${STAGING_BINDIR_NATIVE}/python3-native/python3 \
213 -c "from py_compile import compile; compile('$sysconfigfile')"
214 ${STAGING_BINDIR_NATIVE}/python3-native/python3 \
215 -c "from py_compile import compile; compile('$sysconfigfile', optimize=1)"
216 ${STAGING_BINDIR_NATIVE}/python3-native/python3 \
217 -c "from py_compile import compile; compile('$sysconfigfile', optimize=2)"
218 cd -
219
220 mv ${PKGD}/${bindir}/python${PYTHON_MAJMIN}-config ${PKGD}/${bindir}/python${PYTHON_MAJMIN}-config-${MULTILIB_SUFFIX}
221
222 #Remove the unneeded copy of target sysconfig data
223 rm -rf ${PKGD}/${libdir}/python-sysconfigdata
224}
225
226# We want bytecode precompiled .py files (.pyc's) by default
227# but the user may set it on their own conf
228INCLUDE_PYCS ?= "1"
229
230python(){
231 import collections, json
232
233 filename = os.path.join(d.getVar('THISDIR'), 'python3', 'python3-manifest.json')
234 # This python changes the datastore based on the contents of a file, so mark
235 # that dependency.
236 bb.parse.mark_dependency(d, filename)
237
238 with open(filename) as manifest_file:
239 manifest_str = manifest_file.read()
240 json_start = manifest_str.find('# EOC') + 6
241 manifest_file.seek(json_start)
242 manifest_str = manifest_file.read()
243 python_manifest = json.loads(manifest_str, object_pairs_hook=collections.OrderedDict)
244
245 # First set RPROVIDES for -native case
246 # Hardcoded since it cant be python3-native-foo, should be python3-foo-native
247 pn = 'python3'
248 rprovides = (d.getVar('RPROVIDES') or "").split()
249
250 # ${PN}-misc-native is not in the manifest
251 rprovides.append(pn + '-misc-native')
252
253 for key in python_manifest:
254 pypackage = pn + '-' + key + '-native'
255 if pypackage not in rprovides:
256 rprovides.append(pypackage)
257
258 d.setVar('RPROVIDES_class-native', ' '.join(rprovides))
259
260 # Then work on the target
261 include_pycs = d.getVar('INCLUDE_PYCS')
262
263 packages = d.getVar('PACKAGES').split()
264 pn = d.getVar('PN')
265
266 newpackages=[]
267 for key in python_manifest:
268 pypackage = pn + '-' + key
269
270 if pypackage not in packages:
271 # We need to prepend, otherwise python-misc gets everything
272 # so we use a new variable
273 newpackages.append(pypackage)
274
275 # "Build" python's manifest FILES, RDEPENDS and SUMMARY
276 d.setVar('FILES_' + pypackage, '')
277 for value in python_manifest[key]['files']:
278 d.appendVar('FILES_' + pypackage, ' ' + value)
279
280 # Add cached files
281 if include_pycs == '1':
282 for value in python_manifest[key]['cached']:
283 d.appendVar('FILES_' + pypackage, ' ' + value)
284
285 for value in python_manifest[key]['rdepends']:
286 # Make it work with or without $PN
287 if '${PN}' in value:
288 value=value.split('-', 1)[1]
289 d.appendVar('RDEPENDS_' + pypackage, ' ' + pn + '-' + value)
290
291 for value in python_manifest[key].get('rrecommends', ()):
292 if '${PN}' in value:
293 value=value.split('-', 1)[1]
294 d.appendVar('RRECOMMENDS_' + pypackage, ' ' + pn + '-' + value)
295
296 d.setVar('SUMMARY_' + pypackage, python_manifest[key]['summary'])
297
298 # Prepending so to avoid python-misc getting everything
299 packages = newpackages + packages
300 d.setVar('PACKAGES', ' '.join(packages))
301 d.setVar('ALLOW_EMPTY_${PN}-modules', '1')
302 d.setVar('ALLOW_EMPTY_${PN}-pkgutil', '1')
303}
304
305# Files needed to create a new manifest
306
307do_create_manifest() {
308 # This task should be run with every new release of Python.
309 # We must ensure that PACKAGECONFIG enables everything when creating
310 # a new manifest, this is to base our new manifest on a complete
311 # native python build, containing all dependencies, otherwise the task
312 # wont be able to find the required files.
313 # e.g. BerkeleyDB is an optional build dependency so it may or may not
314 # be present, we must ensure it is.
315
316 cd ${WORKDIR}
317 # This needs to be executed by python-native and NOT by HOST's python
318 nativepython3 create_manifest3.py ${PYTHON_MAJMIN}
319 cp python3-manifest.json.new ${THISDIR}/python3/python3-manifest.json
320}
321
322# bitbake python -c create_manifest
323# Make sure we have native python ready when we create a new manifest
324addtask do_create_manifest after do_patch do_prepare_recipe_sysroot
325
326# manual dependency additions
327RRECOMMENDS_${PN}-core_append_class-nativesdk = " nativesdk-python3-modules"
328RRECOMMENDS_${PN}-crypt_append_class-target = " ${MLPREFIX}openssl ${MLPREFIX}ca-certificates"
329RRECOMMENDS_${PN}-crypt_append_class-nativesdk = " ${MLPREFIX}openssl ${MLPREFIX}ca-certificates"
330
331# For historical reasons PN is empty and provided by python3-modules
332FILES_${PN} = ""
333RPROVIDES_${PN}-modules = "${PN}"
334
335FILES_${PN}-pydoc += "${bindir}/pydoc${PYTHON_MAJMIN} ${bindir}/pydoc3"
336FILES_${PN}-idle += "${bindir}/idle3 ${bindir}/idle${PYTHON_MAJMIN}"
337
338# provide python-pyvenv from python3-venv
339RPROVIDES_${PN}-venv += "${MLPREFIX}python3-pyvenv"
340
341# package libpython3
342PACKAGES =+ "libpython3 libpython3-staticdev"
343FILES_libpython3 = "${libdir}/libpython*.so.*"
344FILES_libpython3-staticdev += "${libdir}/python${PYTHON_MAJMIN}/config-${PYTHON_MAJMIN}-*/libpython${PYTHON_MAJMIN}.a"
345INSANE_SKIP_${PN}-dev += "dev-elf"
346
347# catch all the rest (unsorted)
348PACKAGES += "${PN}-misc"
349RDEPENDS_${PN}-misc += "\
350 ${PN}-core \
351 ${PN}-email \
352 ${PN}-codecs \
353 ${PN}-pydoc \
354 ${PN}-pickle \
355 ${PN}-audio \
356 ${PN}-numbers \
357"
358RDEPENDS_${PN}-modules_append_class-target = " ${MLPREFIX}python3-misc"
359RDEPENDS_${PN}-modules_append_class-nativesdk = " ${MLPREFIX}python3-misc"
360FILES_${PN}-misc = "${libdir}/python${PYTHON_MAJMIN} ${libdir}/python${PYTHON_MAJMIN}/lib-dynload"
361
362# catch manpage
363PACKAGES += "${PN}-man"
364FILES_${PN}-man = "${datadir}/man"
365
366# See https://bugs.python.org/issue18748 and https://bugs.python.org/issue37395
367RDEPENDS_libpython3_append_libc-glibc = " libgcc"
368RDEPENDS_${PN}-ctypes_append_libc-glibc = " ${MLPREFIX}ldconfig"
369RDEPENDS_${PN}-ptest = "${PN}-modules ${PN}-tests unzip bzip2 libgcc tzdata-europe coreutils sed"
370RDEPENDS_${PN}-ptest_append_libc-glibc = " locale-base-tr-tr.iso-8859-9"
371RDEPENDS_${PN}-tkinter += "${@bb.utils.contains('PACKAGECONFIG', 'tk', 'tk tk-lib', '', d)}"
372RDEPENDS_${PN}-idle += "${@bb.utils.contains('PACKAGECONFIG', 'tk', '${PN}-tkinter tcl', '', d)}"
373RDEPENDS_${PN}-dev = ""
374
375RDEPENDS_${PN}-tests_append_class-target = " ${MLPREFIX}bash"
376RDEPENDS_${PN}-tests_append_class-nativesdk = " ${MLPREFIX}bash"
377
378# Python's tests contain large numbers of files we don't need in the recipe sysroots
379SYSROOT_PREPROCESS_FUNCS += " py3_sysroot_cleanup"
380py3_sysroot_cleanup () {
381 rm -rf ${SYSROOT_DESTDIR}${libdir}/python${PYTHON_MAJMIN}/test
382}
generated by cgit v1.2.3-54-g00ecf (git 2.39.0) at 2024-04-16 20:04:17 +0000