diff options
Diffstat (limited to 'meta/recipes-devtools/python/python3_3.7.7.bb')
-rw-r--r-- | meta/recipes-devtools/python/python3_3.7.7.bb | 331 |
1 files changed, 331 insertions, 0 deletions
diff --git a/meta/recipes-devtools/python/python3_3.7.7.bb b/meta/recipes-devtools/python/python3_3.7.7.bb new file mode 100644 index 0000000000..823eb2f8fd --- /dev/null +++ b/meta/recipes-devtools/python/python3_3.7.7.bb | |||
@@ -0,0 +1,331 @@ | |||
1 | SUMMARY = "The Python Programming Language" | ||
2 | HOMEPAGE = "http://www.python.org" | ||
3 | LICENSE = "PSFv2" | ||
4 | SECTION = "devel/python" | ||
5 | |||
6 | LIC_FILES_CHKSUM = "file://LICENSE;md5=203a6dbc802ee896020a47161e759642" | ||
7 | |||
8 | SRC_URI = "http://www.python.org/ftp/python/${PV}/Python-${PV}.tar.xz \ | ||
9 | file://run-ptest \ | ||
10 | file://create_manifest3.py \ | ||
11 | file://get_module_deps3.py \ | ||
12 | file://python3-manifest.json \ | ||
13 | file://check_build_completeness.py \ | ||
14 | file://cgi_py.patch \ | ||
15 | file://0001-Do-not-add-usr-lib-termcap-to-linker-flags-to-avoid-.patch \ | ||
16 | ${@bb.utils.contains('PACKAGECONFIG', 'tk', '', 'file://avoid_warning_about_tkinter.patch', d)} \ | ||
17 | file://0001-Do-not-use-the-shell-version-of-python-config-that-w.patch \ | ||
18 | file://python-config.patch \ | ||
19 | file://0001-Makefile.pre-use-qemu-wrapper-when-gathering-profile.patch \ | ||
20 | file://0001-Do-not-hardcode-lib-as-location-for-site-packages-an.patch \ | ||
21 | file://0001-python3-use-cc_basename-to-replace-CC-for-checking-c.patch \ | ||
22 | file://0002-Don-t-do-runtime-test-to-get-float-byte-order.patch \ | ||
23 | file://0003-setup.py-pass-missing-libraries-to-Extension-for-mul.patch \ | ||
24 | file://0001-Lib-sysconfig.py-fix-another-place-where-lib-is-hard.patch \ | ||
25 | file://0001-Makefile-fix-Issue36464-parallel-build-race-problem.patch \ | ||
26 | file://0001-bpo-36852-proper-detection-of-mips-architecture-for-.patch \ | ||
27 | file://crosspythonpath.patch \ | ||
28 | file://reformat_sysconfig.py \ | ||
29 | file://0001-Use-FLAG_REF-always-for-interned-strings.patch \ | ||
30 | file://0001-test_locale.py-correct-the-test-output-format.patch \ | ||
31 | " | ||
32 | |||
33 | SRC_URI_append_class-native = " \ | ||
34 | file://0001-distutils-sysconfig-append-STAGING_LIBDIR-python-sys.patch \ | ||
35 | file://12-distutils-prefix-is-inside-staging-area.patch \ | ||
36 | " | ||
37 | SRC_URI_append_class-nativesdk = " \ | ||
38 | file://0001-main.c-if-OEPYTHON3HOME-is-set-use-instead-of-PYTHON.patch \ | ||
39 | " | ||
40 | |||
41 | SRC_URI[md5sum] = "172c650156f7bea68ce31b2fd01fa766" | ||
42 | SRC_URI[sha256sum] = "06a0a9f1bf0d8cd1e4121194d666c4e28ddae4dd54346de6c343206599f02136" | ||
43 | |||
44 | # exclude pre-releases for both python 2.x and 3.x | ||
45 | UPSTREAM_CHECK_REGEX = "[Pp]ython-(?P<pver>\d+(\.\d+)+).tar" | ||
46 | |||
47 | CVE_PRODUCT = "python" | ||
48 | |||
49 | # This is not exploitable when glibc has CVE-2016-10739 fixed. | ||
50 | CVE_CHECK_WHITELIST += "CVE-2019-18348" | ||
51 | |||
52 | PYTHON_MAJMIN = "3.7" | ||
53 | PYTHON_BINABI = "${PYTHON_MAJMIN}m" | ||
54 | |||
55 | S = "${WORKDIR}/Python-${PV}" | ||
56 | |||
57 | BBCLASSEXTEND = "native nativesdk" | ||
58 | |||
59 | inherit autotools pkgconfig qemu ptest multilib_header update-alternatives | ||
60 | |||
61 | MULTILIB_SUFFIX = "${@d.getVar('base_libdir',1).split('/')[-1]}" | ||
62 | |||
63 | ALTERNATIVE_${PN}-dev = "python-config" | ||
64 | ALTERNATIVE_LINK_NAME[python-config] = "${bindir}/python${PYTHON_BINABI}-config" | ||
65 | ALTERNATIVE_TARGET[python-config] = "${bindir}/python${PYTHON_BINABI}-config-${MULTILIB_SUFFIX}" | ||
66 | |||
67 | |||
68 | DEPENDS = "bzip2-replacement-native libffi bzip2 gdbm openssl sqlite3 zlib virtual/libintl xz virtual/crypt util-linux libtirpc libnsl2" | ||
69 | DEPENDS_append_class-target = " python3-native" | ||
70 | DEPENDS_append_class-nativesdk = " python3-native" | ||
71 | |||
72 | EXTRA_OECONF = " --without-ensurepip --enable-shared" | ||
73 | EXTRA_OECONF_append_class-native = " --bindir=${bindir}/${PN}" | ||
74 | |||
75 | export CROSSPYTHONPATH="${STAGING_LIBDIR_NATIVE}/python${PYTHON_MAJMIN}/lib-dynload/" | ||
76 | |||
77 | EXTRANATIVEPATH += "python3-native" | ||
78 | |||
79 | CACHED_CONFIGUREVARS = " \ | ||
80 | ac_cv_file__dev_ptmx=yes \ | ||
81 | ac_cv_file__dev_ptc=no \ | ||
82 | ac_cv_working_tzset=yes \ | ||
83 | " | ||
84 | python() { | ||
85 | # PGO currently causes builds to not be reproducible, so disable it for | ||
86 | # now. See YOCTO #13407 | ||
87 | if bb.utils.contains('MACHINE_FEATURES', 'qemu-usermode', True, False, d) and d.getVar('BUILD_REPRODUCIBLE_BINARIES') != '1': | ||
88 | d.setVar('PACKAGECONFIG_PGO', 'pgo') | ||
89 | else: | ||
90 | d.setVar('PACKAGECONFIG_PGO', '') | ||
91 | } | ||
92 | |||
93 | PACKAGECONFIG_class-target ??= "readline ${PACKAGECONFIG_PGO}" | ||
94 | PACKAGECONFIG_class-native ??= "readline" | ||
95 | PACKAGECONFIG_class-nativesdk ??= "readline" | ||
96 | PACKAGECONFIG[readline] = ",,readline" | ||
97 | # Use profile guided optimisation by running PyBench inside qemu-user | ||
98 | PACKAGECONFIG[pgo] = "--enable-optimizations,,qemu-native" | ||
99 | PACKAGECONFIG[tk] = ",,tk" | ||
100 | |||
101 | CPPFLAGS_append = " -I${STAGING_INCDIR}/ncursesw -I${STAGING_INCDIR}/uuid" | ||
102 | |||
103 | EXTRA_OEMAKE = '\ | ||
104 | STAGING_LIBDIR=${STAGING_LIBDIR} \ | ||
105 | STAGING_INCDIR=${STAGING_INCDIR} \ | ||
106 | LIB=${baselib} \ | ||
107 | ' | ||
108 | |||
109 | do_compile_prepend_class-target() { | ||
110 | if ${@bb.utils.contains('PACKAGECONFIG', 'pgo', 'true', 'false', d)}; then | ||
111 | qemu_binary="${@qemu_wrapper_cmdline(d, '${STAGING_DIR_TARGET}', ['${B}', '${STAGING_DIR_TARGET}/${base_libdir}'])}" | ||
112 | cat >pgo-wrapper <<EOF | ||
113 | #!/bin/sh | ||
114 | cd ${B} | ||
115 | $qemu_binary "\$@" | ||
116 | EOF | ||
117 | chmod +x pgo-wrapper | ||
118 | fi | ||
119 | } | ||
120 | |||
121 | do_install_prepend() { | ||
122 | ${WORKDIR}/check_build_completeness.py ${T}/log.do_compile | ||
123 | } | ||
124 | |||
125 | do_install_append_class-target() { | ||
126 | oe_multilib_header python${PYTHON_BINABI}/pyconfig.h | ||
127 | } | ||
128 | |||
129 | do_install_append_class-native() { | ||
130 | # Make sure we use /usr/bin/env python | ||
131 | for PYTHSCRIPT in `grep -rIl ${bindir}/${PN}/python ${D}${bindir}/${PN}`; do | ||
132 | sed -i -e '1s|^#!.*|#!/usr/bin/env python3|' $PYTHSCRIPT | ||
133 | done | ||
134 | # Add a symlink to the native Python so that scripts can just invoke | ||
135 | # "nativepython" and get the right one without needing absolute paths | ||
136 | # (these often end up too long for the #! parser in the kernel as the | ||
137 | # buffer is 128 bytes long). | ||
138 | ln -s python3-native/python3 ${D}${bindir}/nativepython3 | ||
139 | } | ||
140 | |||
141 | do_install_append() { | ||
142 | mkdir -p ${D}${libdir}/python-sysconfigdata | ||
143 | sysconfigfile=`find ${D} -name _sysconfig*.py` | ||
144 | cp $sysconfigfile ${D}${libdir}/python-sysconfigdata/_sysconfigdata.py | ||
145 | |||
146 | sed -i \ | ||
147 | -e "s,^ 'LIBDIR'.*, 'LIBDIR': '${STAGING_LIBDIR}'\,,g" \ | ||
148 | -e "s,^ 'INCLUDEDIR'.*, 'INCLUDEDIR': '${STAGING_INCDIR}'\,,g" \ | ||
149 | -e "s,^ 'CONFINCLUDEDIR'.*, 'CONFINCLUDEDIR': '${STAGING_INCDIR}'\,,g" \ | ||
150 | -e "/^ 'INCLDIRSTOMAKE'/{N; s,/usr/include,${STAGING_INCDIR},g}" \ | ||
151 | -e "/^ 'INCLUDEPY'/s,/usr/include,${STAGING_INCDIR},g" \ | ||
152 | ${D}${libdir}/python-sysconfigdata/_sysconfigdata.py | ||
153 | } | ||
154 | |||
155 | do_install_append_class-nativesdk () { | ||
156 | create_wrapper ${D}${bindir}/python${PYTHON_MAJMIN} OEPYTHON3HOME='${prefix}' TERMINFO_DIRS='${sysconfdir}/terminfo:/etc/terminfo:/usr/share/terminfo:/usr/share/misc/terminfo:/lib/terminfo' PYTHONNOUSERSITE='1' | ||
157 | } | ||
158 | |||
159 | SSTATE_SCAN_FILES += "Makefile _sysconfigdata.py" | ||
160 | PACKAGE_PREPROCESS_FUNCS += "py_package_preprocess" | ||
161 | |||
162 | py_package_preprocess () { | ||
163 | # Remove references to buildmachine paths in target Makefile and _sysconfigdata | ||
164 | sed -i -e 's:--sysroot=${STAGING_DIR_TARGET}::g' -e s:'--with-libtool-sysroot=${STAGING_DIR_TARGET}'::g \ | ||
165 | -e 's|${DEBUG_PREFIX_MAP}||g' \ | ||
166 | -e 's:${HOSTTOOLS_DIR}/::g' \ | ||
167 | -e 's:${RECIPE_SYSROOT_NATIVE}::g' \ | ||
168 | -e 's:${RECIPE_SYSROOT}::g' \ | ||
169 | -e 's:${BASE_WORKDIR}/${MULTIMACH_TARGET_SYS}::g' \ | ||
170 | ${PKGD}/${prefix}/lib/python${PYTHON_MAJMIN}/config-${PYTHON_MAJMIN}${PYTHON_ABI}*/Makefile \ | ||
171 | ${PKGD}/${libdir}/python${PYTHON_MAJMIN}/_sysconfigdata*.py \ | ||
172 | ${PKGD}/${bindir}/python${PYTHON_BINABI}-config | ||
173 | |||
174 | # Reformat _sysconfigdata after modifying it so that it remains | ||
175 | # reproducible | ||
176 | for c in ${PKGD}/${libdir}/python${PYTHON_MAJMIN}/_sysconfigdata*.py; do | ||
177 | python3 ${WORKDIR}/reformat_sysconfig.py $c | ||
178 | done | ||
179 | |||
180 | # Recompile _sysconfigdata after modifying it | ||
181 | cd ${PKGD} | ||
182 | sysconfigfile=`find . -name _sysconfigdata_*.py` | ||
183 | ${STAGING_BINDIR_NATIVE}/python3-native/python3 \ | ||
184 | -c "from py_compile import compile; compile('$sysconfigfile')" | ||
185 | ${STAGING_BINDIR_NATIVE}/python3-native/python3 \ | ||
186 | -c "from py_compile import compile; compile('$sysconfigfile', optimize=1)" | ||
187 | ${STAGING_BINDIR_NATIVE}/python3-native/python3 \ | ||
188 | -c "from py_compile import compile; compile('$sysconfigfile', optimize=2)" | ||
189 | cd - | ||
190 | |||
191 | mv ${PKGD}/${bindir}/python${PYTHON_BINABI}-config ${PKGD}/${bindir}/python${PYTHON_BINABI}-config-${MULTILIB_SUFFIX} | ||
192 | |||
193 | #Remove the unneeded copy of target sysconfig data | ||
194 | rm -rf ${PKGD}/${libdir}/python-sysconfigdata | ||
195 | } | ||
196 | |||
197 | # We want bytecode precompiled .py files (.pyc's) by default | ||
198 | # but the user may set it on their own conf | ||
199 | INCLUDE_PYCS ?= "1" | ||
200 | |||
201 | python(){ | ||
202 | import collections, json | ||
203 | |||
204 | filename = os.path.join(d.getVar('THISDIR'), 'python3', 'python3-manifest.json') | ||
205 | # This python changes the datastore based on the contents of a file, so mark | ||
206 | # that dependency. | ||
207 | bb.parse.mark_dependency(d, filename) | ||
208 | |||
209 | with open(filename) as manifest_file: | ||
210 | manifest_str = manifest_file.read() | ||
211 | json_start = manifest_str.find('# EOC') + 6 | ||
212 | manifest_file.seek(json_start) | ||
213 | manifest_str = manifest_file.read() | ||
214 | python_manifest = json.loads(manifest_str, object_pairs_hook=collections.OrderedDict) | ||
215 | |||
216 | # First set RPROVIDES for -native case | ||
217 | # Hardcoded since it cant be python3-native-foo, should be python3-foo-native | ||
218 | pn = 'python3' | ||
219 | rprovides = d.getVar('RPROVIDES').split() | ||
220 | |||
221 | for key in python_manifest: | ||
222 | pypackage = pn + '-' + key + '-native' | ||
223 | if pypackage not in rprovides: | ||
224 | rprovides.append(pypackage) | ||
225 | |||
226 | d.setVar('RPROVIDES_class-native', ' '.join(rprovides)) | ||
227 | |||
228 | # Then work on the target | ||
229 | include_pycs = d.getVar('INCLUDE_PYCS') | ||
230 | |||
231 | packages = d.getVar('PACKAGES').split() | ||
232 | pn = d.getVar('PN') | ||
233 | |||
234 | newpackages=[] | ||
235 | for key in python_manifest: | ||
236 | pypackage = pn + '-' + key | ||
237 | |||
238 | if pypackage not in packages: | ||
239 | # We need to prepend, otherwise python-misc gets everything | ||
240 | # so we use a new variable | ||
241 | newpackages.append(pypackage) | ||
242 | |||
243 | # "Build" python's manifest FILES, RDEPENDS and SUMMARY | ||
244 | d.setVar('FILES_' + pypackage, '') | ||
245 | for value in python_manifest[key]['files']: | ||
246 | d.appendVar('FILES_' + pypackage, ' ' + value) | ||
247 | |||
248 | # Add cached files | ||
249 | if include_pycs == '1': | ||
250 | for value in python_manifest[key]['cached']: | ||
251 | d.appendVar('FILES_' + pypackage, ' ' + value) | ||
252 | |||
253 | for value in python_manifest[key]['rdepends']: | ||
254 | # Make it work with or without $PN | ||
255 | if '${PN}' in value: | ||
256 | value=value.split('-', 1)[1] | ||
257 | d.appendVar('RDEPENDS_' + pypackage, ' ' + pn + '-' + value) | ||
258 | |||
259 | for value in python_manifest[key].get('rrecommends', ()): | ||
260 | if '${PN}' in value: | ||
261 | value=value.split('-', 1)[1] | ||
262 | d.appendVar('RRECOMMENDS_' + pypackage, ' ' + pn + '-' + value) | ||
263 | |||
264 | d.setVar('SUMMARY_' + pypackage, python_manifest[key]['summary']) | ||
265 | |||
266 | # Prepending so to avoid python-misc getting everything | ||
267 | packages = newpackages + packages | ||
268 | d.setVar('PACKAGES', ' '.join(packages)) | ||
269 | d.setVar('ALLOW_EMPTY_${PN}-modules', '1') | ||
270 | } | ||
271 | |||
272 | # Files needed to create a new manifest | ||
273 | |||
274 | do_create_manifest() { | ||
275 | # This task should be run with every new release of Python. | ||
276 | # We must ensure that PACKAGECONFIG enables everything when creating | ||
277 | # a new manifest, this is to base our new manifest on a complete | ||
278 | # native python build, containing all dependencies, otherwise the task | ||
279 | # wont be able to find the required files. | ||
280 | # e.g. BerkeleyDB is an optional build dependency so it may or may not | ||
281 | # be present, we must ensure it is. | ||
282 | |||
283 | cd ${WORKDIR} | ||
284 | # This needs to be executed by python-native and NOT by HOST's python | ||
285 | nativepython3 create_manifest3.py ${PYTHON_MAJMIN} | ||
286 | cp python3-manifest.json.new ${THISDIR}/python3/python3-manifest.json | ||
287 | } | ||
288 | |||
289 | # bitbake python -c create_manifest | ||
290 | addtask do_create_manifest | ||
291 | |||
292 | # Make sure we have native python ready when we create a new manifest | ||
293 | do_create_manifest[depends] += "${PN}:do_prepare_recipe_sysroot" | ||
294 | do_create_manifest[depends] += "${PN}:do_patch" | ||
295 | |||
296 | # manual dependency additions | ||
297 | RPROVIDES_${PN}-modules = "${PN}" | ||
298 | RRECOMMENDS_${PN}-core_append_class-nativesdk = " nativesdk-python3-modules" | ||
299 | RRECOMMENDS_${PN}-crypt_append_class-target = " openssl ca-certificates" | ||
300 | RRECOMMENDS_${PN}-crypt_append_class-nativesdk = " openssl ca-certificates" | ||
301 | |||
302 | FILES_${PN}-pydoc += "${bindir}/pydoc${PYTHON_MAJMIN} ${bindir}/pydoc3" | ||
303 | FILES_${PN}-idle += "${bindir}/idle3 ${bindir}/idle${PYTHON_MAJMIN}" | ||
304 | |||
305 | # provide python-pyvenv from python3-venv | ||
306 | RPROVIDES_${PN}-venv += "python3-pyvenv" | ||
307 | |||
308 | # package libpython3 | ||
309 | PACKAGES =+ "libpython3 libpython3-staticdev" | ||
310 | FILES_libpython3 = "${libdir}/libpython*.so.*" | ||
311 | FILES_libpython3-staticdev += "${prefix}/lib/python${PYTHON_MAJMIN}/config-${PYTHON_BINABI}-*/libpython${PYTHON_BINABI}.a" | ||
312 | INSANE_SKIP_${PN}-dev += "dev-elf" | ||
313 | |||
314 | # catch all the rest (unsorted) | ||
315 | PACKAGES += "${PN}-misc" | ||
316 | RDEPENDS_${PN}-misc += "python3-core python3-email python3-codecs python3-pydoc python3-pickle" | ||
317 | RDEPENDS_${PN}-modules_append_class-target = " python3-misc" | ||
318 | RDEPENDS_${PN}-modules_append_class-nativesdk = " python3-misc" | ||
319 | FILES_${PN}-misc = "${libdir}/python${PYTHON_MAJMIN} ${libdir}/python${PYTHON_MAJMIN}/lib-dynload" | ||
320 | |||
321 | # catch manpage | ||
322 | PACKAGES += "${PN}-man" | ||
323 | FILES_${PN}-man = "${datadir}/man" | ||
324 | |||
325 | # See https://bugs.python.org/issue18748 and https://bugs.python.org/issue37395 | ||
326 | RDEPENDS_libpython3_append_libc-glibc = " libgcc" | ||
327 | RDEPENDS_${PN}-ptest = "${PN}-modules ${PN}-tests unzip bzip2 libgcc tzdata-europe coreutils sed" | ||
328 | RDEPENDS_${PN}-ptest_append_libc-glibc = " locale-base-tr-tr.iso-8859-9" | ||
329 | RDEPENDS_${PN}-tkinter += "${@bb.utils.contains('PACKAGECONFIG', 'tk', 'tk tk-lib', '', d)}" | ||
330 | RDEPENDS_${PN}-dev = "" | ||
331 | |||