diff options
Diffstat (limited to 'meta/recipes-devtools/python/python3_3.11.0.bb')
-rw-r--r-- | meta/recipes-devtools/python/python3_3.11.0.bb | 430 |
1 files changed, 430 insertions, 0 deletions
diff --git a/meta/recipes-devtools/python/python3_3.11.0.bb b/meta/recipes-devtools/python/python3_3.11.0.bb new file mode 100644 index 0000000000..6b6c983abf --- /dev/null +++ b/meta/recipes-devtools/python/python3_3.11.0.bb | |||
@@ -0,0 +1,430 @@ | |||
1 | SUMMARY = "The Python Programming Language" | ||
2 | HOMEPAGE = "http://www.python.org" | ||
3 | DESCRIPTION = "Python is a programming language that lets you work more quickly and integrate your systems more effectively." | ||
4 | LICENSE = "PSF-2.0" | ||
5 | SECTION = "devel/python" | ||
6 | |||
7 | LIC_FILES_CHKSUM = "file://LICENSE;md5=4b8801e752a2c70ac41a5f9aa243f766" | ||
8 | |||
9 | SRC_URI = "http://www.python.org/ftp/python/${PV}/Python-${PV}.tar.xz \ | ||
10 | file://run-ptest \ | ||
11 | file://create_manifest3.py \ | ||
12 | file://get_module_deps3.py \ | ||
13 | file://python3-manifest.json \ | ||
14 | file://check_build_completeness.py \ | ||
15 | file://reformat_sysconfig.py \ | ||
16 | file://cgi_py.patch \ | ||
17 | file://0001-Do-not-add-usr-lib-termcap-to-linker-flags-to-avoid-.patch \ | ||
18 | ${@bb.utils.contains('PACKAGECONFIG', 'tk', '', 'file://avoid_warning_about_tkinter.patch', d)} \ | ||
19 | file://0001-Do-not-use-the-shell-version-of-python-config-that-w.patch \ | ||
20 | file://python-config.patch \ | ||
21 | file://0001-Makefile.pre-use-qemu-wrapper-when-gathering-profile.patch \ | ||
22 | file://0001-python3-use-cc_basename-to-replace-CC-for-checking-c.patch \ | ||
23 | file://0001-bpo-36852-proper-detection-of-mips-architecture-for-.patch \ | ||
24 | file://crosspythonpath.patch \ | ||
25 | file://0001-test_locale.py-correct-the-test-output-format.patch \ | ||
26 | file://0017-setup.py-do-not-report-missing-dependencies-for-disa.patch \ | ||
27 | file://0001-Makefile-do-not-compile-.pyc-in-parallel.patch \ | ||
28 | file://0020-configure.ac-setup.py-do-not-add-a-curses-include-pa.patch \ | ||
29 | file://0001-Skip-failing-tests-due-to-load-variability-on-YP-AB.patch \ | ||
30 | file://0001-test_ctypes.test_find-skip-without-tools-sdk.patch \ | ||
31 | file://makerace.patch \ | ||
32 | file://0001-sysconfig.py-use-platlibdir-also-for-purelib.patch \ | ||
33 | file://0001-Lib-pty.py-handle-stdin-I-O-errors-same-way-as-maste.patch \ | ||
34 | file://0001-setup.py-Do-not-detect-multiarch-paths-when-cross-co.patch \ | ||
35 | file://deterministic_imports.patch \ | ||
36 | file://0001-Avoid-shebang-overflow-on-python-config.py.patch \ | ||
37 | " | ||
38 | |||
39 | SRC_URI:append:class-native = " \ | ||
40 | file://0001-Lib-sysconfig.py-use-prefix-value-from-build-configu.patch \ | ||
41 | file://0001-distutils-sysconfig-append-STAGING_LIBDIR-python-sys.patch \ | ||
42 | file://12-distutils-prefix-is-inside-staging-area.patch \ | ||
43 | file://0001-Don-t-search-system-for-headers-libraries.patch \ | ||
44 | " | ||
45 | SRC_URI[sha256sum] = "a57dc82d77358617ba65b9841cee1e3b441f386c3789ddc0676eca077f2951c3" | ||
46 | |||
47 | # exclude pre-releases for both python 2.x and 3.x | ||
48 | UPSTREAM_CHECK_REGEX = "[Pp]ython-(?P<pver>\d+(\.\d+)+).tar" | ||
49 | UPSTREAM_CHECK_URI = "https://www.python.org/downloads/source/" | ||
50 | |||
51 | CVE_PRODUCT = "python" | ||
52 | |||
53 | # Upstream consider this expected behaviour | ||
54 | CVE_CHECK_IGNORE += "CVE-2007-4559" | ||
55 | # This is not exploitable when glibc has CVE-2016-10739 fixed. | ||
56 | CVE_CHECK_IGNORE += "CVE-2019-18348" | ||
57 | # These are specific to Microsoft Windows | ||
58 | CVE_CHECK_IGNORE += "CVE-2020-15523 CVE-2022-26488" | ||
59 | # The mailcap module is insecure by design, so this can't be fixed in a meaningful way. | ||
60 | # The module will be removed in the future and flaws documented. | ||
61 | CVE_CHECK_IGNORE += "CVE-2015-20107" | ||
62 | |||
63 | PYTHON_MAJMIN = "3.11" | ||
64 | |||
65 | S = "${WORKDIR}/Python-${PV}" | ||
66 | |||
67 | BBCLASSEXTEND = "native nativesdk" | ||
68 | |||
69 | inherit autotools pkgconfig qemu ptest multilib_header update-alternatives | ||
70 | |||
71 | MULTILIB_SUFFIX = "${@d.getVar('base_libdir',1).split('/')[-1]}" | ||
72 | |||
73 | ALTERNATIVE:${PN}-dev = "python3-config" | ||
74 | ALTERNATIVE_LINK_NAME[python3-config] = "${bindir}/python${PYTHON_MAJMIN}-config" | ||
75 | ALTERNATIVE_TARGET[python3-config] = "${bindir}/python${PYTHON_MAJMIN}-config-${MULTILIB_SUFFIX}" | ||
76 | |||
77 | |||
78 | DEPENDS = "bzip2-replacement-native libffi bzip2 openssl sqlite3 zlib virtual/libintl xz virtual/crypt util-linux-libuuid libtirpc libnsl2 autoconf-archive-native ncurses" | ||
79 | DEPENDS:append:class-target = " python3-native" | ||
80 | DEPENDS:append:class-nativesdk = " python3-native" | ||
81 | |||
82 | EXTRA_OECONF = " --without-ensurepip --enable-shared --with-platlibdir=${baselib}" | ||
83 | EXTRA_OECONF:append:class-native = " --bindir=${bindir}/${PN}" | ||
84 | EXTRA_OECONF:append:class-target = " --with-build-python=nativepython3" | ||
85 | EXTRA_OECONF:append:class-nativesdk = " --with-build-python=nativepython3" | ||
86 | |||
87 | export CROSSPYTHONPATH="${STAGING_LIBDIR_NATIVE}/python${PYTHON_MAJMIN}/lib-dynload/" | ||
88 | |||
89 | EXTRANATIVEPATH += "python3-native" | ||
90 | |||
91 | # LTO will be enabled via packageconfig depending upong distro features | ||
92 | LTO:class-target = "" | ||
93 | |||
94 | CACHED_CONFIGUREVARS = " \ | ||
95 | ac_cv_file__dev_ptmx=yes \ | ||
96 | ac_cv_file__dev_ptc=no \ | ||
97 | ac_cv_working_tzset=yes \ | ||
98 | " | ||
99 | |||
100 | # PGO currently causes builds to not be reproducible so disable by default, see YOCTO #13407 | ||
101 | PACKAGECONFIG:class-target ??= "readline gdbm ${@bb.utils.filter('DISTRO_FEATURES', 'lto', d)}" | ||
102 | PACKAGECONFIG:class-native ??= "readline gdbm" | ||
103 | PACKAGECONFIG:class-nativesdk ??= "readline gdbm" | ||
104 | PACKAGECONFIG[readline] = ",,readline" | ||
105 | PACKAGECONFIG[editline] = "--with-readline=editline,,libedit,,,readline" | ||
106 | # Use profile guided optimisation by running PyBench inside qemu-user | ||
107 | PACKAGECONFIG[pgo] = "--enable-optimizations,,qemu-native" | ||
108 | PACKAGECONFIG[tk] = ",,tk" | ||
109 | PACKAGECONFIG[gdbm] = ",,gdbm" | ||
110 | PACKAGECONFIG[lto] = "--with-lto,," | ||
111 | |||
112 | do_configure:prepend () { | ||
113 | mkdir -p ${B}/Modules | ||
114 | cat > ${B}/Modules/Setup.local << EOF | ||
115 | *disabled* | ||
116 | ${@bb.utils.contains('PACKAGECONFIG', 'gdbm', '', '_gdbm _dbm', d)} | ||
117 | ${@bb.utils.contains('PACKAGECONFIG', 'readline', '', 'readline', d)} | ||
118 | EOF | ||
119 | } | ||
120 | |||
121 | CPPFLAGS:append = " -I${STAGING_INCDIR}/ncursesw -I${STAGING_INCDIR}/uuid" | ||
122 | |||
123 | EXTRA_OEMAKE = '\ | ||
124 | STAGING_LIBDIR=${STAGING_LIBDIR} \ | ||
125 | STAGING_INCDIR=${STAGING_INCDIR} \ | ||
126 | LIB=${baselib} \ | ||
127 | ' | ||
128 | |||
129 | do_compile:prepend:class-target() { | ||
130 | if ${@bb.utils.contains('PACKAGECONFIG', 'pgo', 'true', 'false', d)}; then | ||
131 | qemu_binary="${@qemu_wrapper_cmdline(d, '${STAGING_DIR_TARGET}', ['${B}', '${STAGING_DIR_TARGET}/${base_libdir}'])}" | ||
132 | cat >pgo-wrapper <<EOF | ||
133 | #!/bin/sh | ||
134 | cd ${B} | ||
135 | $qemu_binary "\$@" | ||
136 | EOF | ||
137 | chmod +x pgo-wrapper | ||
138 | fi | ||
139 | } | ||
140 | |||
141 | do_install:prepend() { | ||
142 | ${WORKDIR}/check_build_completeness.py ${T}/log.do_compile | ||
143 | } | ||
144 | |||
145 | do_install:append:class-target() { | ||
146 | oe_multilib_header python${PYTHON_MAJMIN}/pyconfig.h | ||
147 | } | ||
148 | |||
149 | do_install:append:class-native() { | ||
150 | # Make sure we use /usr/bin/env python | ||
151 | for PYTHSCRIPT in `grep -rIl ${bindir}/${PN}/python ${D}${bindir}/${PN}`; do | ||
152 | sed -i -e '1s|^#!.*|#!/usr/bin/env python3|' $PYTHSCRIPT | ||
153 | done | ||
154 | # Add a symlink to the native Python so that scripts can just invoke | ||
155 | # "nativepython" and get the right one without needing absolute paths | ||
156 | # (these often end up too long for the #! parser in the kernel as the | ||
157 | # buffer is 128 bytes long). | ||
158 | ln -s python3-native/python3 ${D}${bindir}/nativepython3 | ||
159 | |||
160 | # Remove the opt-1.pyc and opt-2.pyc files. There are over 3,000 of them | ||
161 | # and the overhead in each recipe-sysroot-native isn't worth it, particularly | ||
162 | # when they're only used for python called with -O or -OO. | ||
163 | #find ${D} -name *opt-*.pyc -delete | ||
164 | # Remove all pyc files. There are a ton of them and it is probably faster to let | ||
165 | # python create the ones it wants at runtime rather than manage in the sstate | ||
166 | # tarballs and sysroot creation. | ||
167 | find ${D} -name *.pyc -delete | ||
168 | |||
169 | # Nothing should be looking into ${B} for python3-native | ||
170 | sed -i -e 's:${B}:/build/path/unavailable/:g' \ | ||
171 | ${D}/${libdir}/python${PYTHON_MAJMIN}/config-${PYTHON_MAJMIN}${PYTHON_ABI}*/Makefile | ||
172 | |||
173 | # disable the lookup in user's site-packages globally | ||
174 | sed -i 's#ENABLE_USER_SITE = None#ENABLE_USER_SITE = False#' ${D}${libdir}/python${PYTHON_MAJMIN}/site.py | ||
175 | } | ||
176 | |||
177 | do_install:append() { | ||
178 | for c in ${D}/${libdir}/python${PYTHON_MAJMIN}/_sysconfigdata*.py; do | ||
179 | python3 ${WORKDIR}/reformat_sysconfig.py $c | ||
180 | done | ||
181 | rm -f ${D}${libdir}/python${PYTHON_MAJMIN}/__pycache__/_sysconfigdata*.cpython* | ||
182 | |||
183 | mkdir -p ${D}${libdir}/python-sysconfigdata | ||
184 | sysconfigfile=`find ${D} -name _sysconfig*.py` | ||
185 | sed -i \ | ||
186 | -e "s,^ 'LIBDIR'.*, 'LIBDIR': '${STAGING_LIBDIR}'\,,g" \ | ||
187 | -e "s,^ 'INCLUDEDIR'.*, 'INCLUDEDIR': '${STAGING_INCDIR}'\,,g" \ | ||
188 | -e "s,^ 'CONFINCLUDEDIR'.*, 'CONFINCLUDEDIR': '${STAGING_INCDIR}'\,,g" \ | ||
189 | -e "/^ 'INCLDIRSTOMAKE'/{N; s,/usr/include,${STAGING_INCDIR},g}" \ | ||
190 | -e "/^ 'INCLUDEPY'/s,/usr/include,${STAGING_INCDIR},g" \ | ||
191 | -e "s,${B},/build/path/unavailable/,g" \ | ||
192 | $sysconfigfile | ||
193 | cp $sysconfigfile ${D}${libdir}/python-sysconfigdata/_sysconfigdata.py | ||
194 | |||
195 | |||
196 | # Unfortunately the following pyc files are non-deterministc due to 'frozenset' | ||
197 | # being written without strict ordering, even with PYTHONHASHSEED = 0 | ||
198 | # Upstream is discussing ways to solve the issue properly, until then let's | ||
199 | # just not install the problematic files. | ||
200 | # More info: http://benno.id.au/blog/2013/01/15/python-determinism | ||
201 | rm -f ${D}${libdir}/python${PYTHON_MAJMIN}/test/__pycache__/test_range.cpython* | ||
202 | rm -f ${D}${libdir}/python${PYTHON_MAJMIN}/test/__pycache__/test_xml_etree.cpython* | ||
203 | |||
204 | # Similar to the above, we're getting reproducibility issues with | ||
205 | # /usr/lib/python3.10/__pycache__/traceback.cpython-310.pyc | ||
206 | # so remove it too | ||
207 | rm -f ${D}${libdir}/python${PYTHON_MAJMIN}/__pycache__/traceback.cpython* | ||
208 | |||
209 | # Remove the opt-1.pyc and opt-2.pyc files. They effectively waste space on embedded | ||
210 | # style targets as they're only used when python is called with the -O or -OO options | ||
211 | # which is rare. | ||
212 | find ${D} -name *opt-*.pyc -delete | ||
213 | } | ||
214 | |||
215 | do_install:append:class-nativesdk () { | ||
216 | # Make sure we use /usr/bin/env python | ||
217 | for PYTHSCRIPT in `grep -rIl ${bindir}/python ${D}${bindir}`; do | ||
218 | sed -i -e '1s|^#!.*|#!/usr/bin/env python3|' $PYTHSCRIPT | ||
219 | done | ||
220 | create_wrapper ${D}${bindir}/python${PYTHON_MAJMIN} TERMINFO_DIRS='${sysconfdir}/terminfo:/etc/terminfo:/usr/share/terminfo:/usr/share/misc/terminfo:/lib/terminfo' PYTHONNOUSERSITE='1' | ||
221 | } | ||
222 | |||
223 | SSTATE_SCAN_FILES += "Makefile _sysconfigdata.py" | ||
224 | SSTATE_HASHEQUIV_FILEMAP = " \ | ||
225 | populate_sysroot:*/lib*/python3*/_sysconfigdata*.py:${TMPDIR} \ | ||
226 | populate_sysroot:*/lib*/python3*/_sysconfigdata*.py:${COREBASE} \ | ||
227 | populate_sysroot:*/lib*/python3*/config-*/Makefile:${TMPDIR} \ | ||
228 | populate_sysroot:*/lib*/python3*/config-*/Makefile:${COREBASE} \ | ||
229 | populate_sysroot:*/lib*/python-sysconfigdata/_sysconfigdata.py:${TMPDIR} \ | ||
230 | populate_sysroot:*/lib*/python-sysconfigdata/_sysconfigdata.py:${COREBASE} \ | ||
231 | " | ||
232 | PACKAGE_PREPROCESS_FUNCS += "py_package_preprocess" | ||
233 | |||
234 | py_package_preprocess () { | ||
235 | # Remove references to buildmachine paths in target Makefile and _sysconfigdata | ||
236 | sed -i -e 's:--sysroot=${STAGING_DIR_TARGET}::g' -e s:'--with-libtool-sysroot=${STAGING_DIR_TARGET}'::g \ | ||
237 | -e 's|${DEBUG_PREFIX_MAP}||g' \ | ||
238 | -e 's:${HOSTTOOLS_DIR}/::g' \ | ||
239 | -e 's:${RECIPE_SYSROOT_NATIVE}::g' \ | ||
240 | -e 's:${RECIPE_SYSROOT}::g' \ | ||
241 | -e 's:${BASE_WORKDIR}/${MULTIMACH_TARGET_SYS}::g' \ | ||
242 | ${PKGD}/${libdir}/python${PYTHON_MAJMIN}/config-${PYTHON_MAJMIN}${PYTHON_ABI}*/Makefile \ | ||
243 | ${PKGD}/${libdir}/python${PYTHON_MAJMIN}/_sysconfigdata*.py \ | ||
244 | ${PKGD}/${bindir}/python${PYTHON_MAJMIN}-config | ||
245 | |||
246 | # Reformat _sysconfigdata after modifying it so that it remains | ||
247 | # reproducible | ||
248 | for c in ${PKGD}/${libdir}/python${PYTHON_MAJMIN}/_sysconfigdata*.py; do | ||
249 | python3 ${WORKDIR}/reformat_sysconfig.py $c | ||
250 | done | ||
251 | |||
252 | # Recompile _sysconfigdata after modifying it | ||
253 | cd ${PKGD} | ||
254 | sysconfigfile=`find . -name _sysconfigdata_*.py` | ||
255 | ${STAGING_BINDIR_NATIVE}/python3-native/python3 \ | ||
256 | -c "from py_compile import compile; compile('$sysconfigfile')" | ||
257 | ${STAGING_BINDIR_NATIVE}/python3-native/python3 \ | ||
258 | -c "from py_compile import compile; compile('$sysconfigfile', optimize=1)" | ||
259 | ${STAGING_BINDIR_NATIVE}/python3-native/python3 \ | ||
260 | -c "from py_compile import compile; compile('$sysconfigfile', optimize=2)" | ||
261 | cd - | ||
262 | |||
263 | mv ${PKGD}/${bindir}/python${PYTHON_MAJMIN}-config ${PKGD}/${bindir}/python${PYTHON_MAJMIN}-config-${MULTILIB_SUFFIX} | ||
264 | |||
265 | #Remove the unneeded copy of target sysconfig data | ||
266 | rm -rf ${PKGD}/${libdir}/python-sysconfigdata | ||
267 | } | ||
268 | |||
269 | # We want bytecode precompiled .py files (.pyc's) by default | ||
270 | # but the user may set it on their own conf | ||
271 | INCLUDE_PYCS ?= "1" | ||
272 | |||
273 | python(){ | ||
274 | import collections, json | ||
275 | |||
276 | filename = os.path.join(d.getVar('THISDIR'), 'python3', 'python3-manifest.json') | ||
277 | # This python changes the datastore based on the contents of a file, so mark | ||
278 | # that dependency. | ||
279 | bb.parse.mark_dependency(d, filename) | ||
280 | |||
281 | with open(filename) as manifest_file: | ||
282 | manifest_str = manifest_file.read() | ||
283 | json_start = manifest_str.find('# EOC') + 6 | ||
284 | manifest_file.seek(json_start) | ||
285 | manifest_str = manifest_file.read() | ||
286 | python_manifest = json.loads(manifest_str, object_pairs_hook=collections.OrderedDict) | ||
287 | |||
288 | # First set RPROVIDES for -native case | ||
289 | # Hardcoded since it cant be python3-native-foo, should be python3-foo-native | ||
290 | pn = 'python3' | ||
291 | rprovides = (d.getVar('RPROVIDES') or "").split() | ||
292 | |||
293 | # ${PN}-misc-native is not in the manifest | ||
294 | rprovides.append(pn + '-misc-native') | ||
295 | |||
296 | for key in python_manifest: | ||
297 | pypackage = pn + '-' + key + '-native' | ||
298 | if pypackage not in rprovides: | ||
299 | rprovides.append(pypackage) | ||
300 | |||
301 | d.setVar('RPROVIDES:class-native', ' '.join(rprovides)) | ||
302 | |||
303 | # Then work on the target | ||
304 | include_pycs = d.getVar('INCLUDE_PYCS') | ||
305 | |||
306 | packages = d.getVar('PACKAGES').split() | ||
307 | pn = d.getVar('PN') | ||
308 | |||
309 | newpackages=[] | ||
310 | for key in python_manifest: | ||
311 | pypackage = pn + '-' + key | ||
312 | |||
313 | if pypackage not in packages: | ||
314 | # We need to prepend, otherwise python-misc gets everything | ||
315 | # so we use a new variable | ||
316 | newpackages.append(pypackage) | ||
317 | |||
318 | # "Build" python's manifest FILES, RDEPENDS and SUMMARY | ||
319 | d.setVar('FILES:' + pypackage, '') | ||
320 | for value in python_manifest[key]['files']: | ||
321 | d.appendVar('FILES:' + pypackage, ' ' + value) | ||
322 | |||
323 | # Add cached files | ||
324 | if include_pycs == '1': | ||
325 | for value in python_manifest[key]['cached']: | ||
326 | d.appendVar('FILES:' + pypackage, ' ' + value) | ||
327 | |||
328 | for value in python_manifest[key]['rdepends']: | ||
329 | # Make it work with or without $PN | ||
330 | if '${PN}' in value: | ||
331 | value=value.split('-', 1)[1] | ||
332 | d.appendVar('RDEPENDS:' + pypackage, ' ' + pn + '-' + value) | ||
333 | |||
334 | for value in python_manifest[key].get('rrecommends', ()): | ||
335 | if '${PN}' in value: | ||
336 | value=value.split('-', 1)[1] | ||
337 | d.appendVar('RRECOMMENDS:' + pypackage, ' ' + pn + '-' + value) | ||
338 | |||
339 | d.setVar('SUMMARY:' + pypackage, python_manifest[key]['summary']) | ||
340 | |||
341 | # Prepending so to avoid python-misc getting everything | ||
342 | packages = newpackages + packages | ||
343 | d.setVar('PACKAGES', ' '.join(packages)) | ||
344 | d.setVar('ALLOW_EMPTY:${PN}-modules', '1') | ||
345 | d.setVar('ALLOW_EMPTY:${PN}-pkgutil', '1') | ||
346 | |||
347 | if "pgo" in d.getVar("PACKAGECONFIG").split() and not bb.utils.contains('MACHINE_FEATURES', 'qemu-usermode', True, False, d): | ||
348 | bb.fatal("pgo cannot be enabled as there is no qemu-usermode support for this architecture/machine") | ||
349 | } | ||
350 | |||
351 | # Files needed to create a new manifest | ||
352 | |||
353 | do_create_manifest() { | ||
354 | # This task should be run with every new release of Python. | ||
355 | # We must ensure that PACKAGECONFIG enables everything when creating | ||
356 | # a new manifest, this is to base our new manifest on a complete | ||
357 | # native python build, containing all dependencies, otherwise the task | ||
358 | # wont be able to find the required files. | ||
359 | # e.g. BerkeleyDB is an optional build dependency so it may or may not | ||
360 | # be present, we must ensure it is. | ||
361 | |||
362 | cd ${WORKDIR} | ||
363 | # This needs to be executed by python-native and NOT by HOST's python | ||
364 | nativepython3 create_manifest3.py ${PYTHON_MAJMIN} | ||
365 | cp python3-manifest.json.new ${THISDIR}/python3/python3-manifest.json | ||
366 | } | ||
367 | |||
368 | # bitbake python -c create_manifest | ||
369 | # Make sure we have native python ready when we create a new manifest | ||
370 | addtask do_create_manifest after do_patch do_prepare_recipe_sysroot | ||
371 | |||
372 | # manual dependency additions | ||
373 | RRECOMMENDS:${PN}-core:append:class-nativesdk = " nativesdk-python3-modules" | ||
374 | RRECOMMENDS:${PN}-crypt:append:class-target = " ${MLPREFIX}openssl ${MLPREFIX}ca-certificates" | ||
375 | RRECOMMENDS:${PN}-crypt:append:class-nativesdk = " ${MLPREFIX}openssl ${MLPREFIX}ca-certificates" | ||
376 | |||
377 | # For historical reasons PN is empty and provided by python3-modules | ||
378 | FILES:${PN} = "" | ||
379 | RPROVIDES:${PN}-modules = "${PN}" | ||
380 | |||
381 | FILES:${PN}-pydoc += "${bindir}/pydoc${PYTHON_MAJMIN} ${bindir}/pydoc3" | ||
382 | FILES:${PN}-idle += "${bindir}/idle3 ${bindir}/idle${PYTHON_MAJMIN}" | ||
383 | |||
384 | # provide python-pyvenv from python3-venv | ||
385 | RPROVIDES:${PN}-venv += "${MLPREFIX}python3-pyvenv" | ||
386 | |||
387 | # package libpython3 | ||
388 | PACKAGES =+ "libpython3 libpython3-staticdev" | ||
389 | FILES:libpython3 = "${libdir}/libpython*.so.*" | ||
390 | FILES:libpython3-staticdev += "${libdir}/python${PYTHON_MAJMIN}/config-${PYTHON_MAJMIN}-*/libpython${PYTHON_MAJMIN}.a" | ||
391 | INSANE_SKIP:${PN}-dev += "dev-elf" | ||
392 | INSANE_SKIP:${PN}-ptest = "dev-deps" | ||
393 | |||
394 | # catch all the rest (unsorted) | ||
395 | PACKAGES += "${PN}-misc" | ||
396 | RDEPENDS:${PN}-misc += "\ | ||
397 | ${PN}-core \ | ||
398 | ${PN}-email \ | ||
399 | ${PN}-codecs \ | ||
400 | ${PN}-pydoc \ | ||
401 | ${PN}-pickle \ | ||
402 | ${PN}-audio \ | ||
403 | ${PN}-numbers \ | ||
404 | " | ||
405 | RDEPENDS:${PN}-modules:append:class-target = " ${MLPREFIX}python3-misc" | ||
406 | RDEPENDS:${PN}-modules:append:class-nativesdk = " ${MLPREFIX}python3-misc" | ||
407 | FILES:${PN}-misc = "${libdir}/python${PYTHON_MAJMIN} ${libdir}/python${PYTHON_MAJMIN}/lib-dynload" | ||
408 | |||
409 | # catch manpage | ||
410 | PACKAGES += "${PN}-man" | ||
411 | FILES:${PN}-man = "${datadir}/man" | ||
412 | |||
413 | # See https://bugs.python.org/issue18748 and https://bugs.python.org/issue37395 | ||
414 | RDEPENDS:libpython3:append:libc-glibc = " libgcc" | ||
415 | RDEPENDS:${PN}-ctypes:append:libc-glibc = " ${MLPREFIX}ldconfig" | ||
416 | RDEPENDS:${PN}-ptest = "${PN}-modules ${PN}-tests ${PN}-dev unzip bzip2 libgcc tzdata-europe coreutils sed" | ||
417 | RDEPENDS:${PN}-ptest:append:libc-glibc = " locale-base-tr-tr.iso-8859-9" | ||
418 | RDEPENDS:${PN}-tkinter += "${@bb.utils.contains('PACKAGECONFIG', 'tk', '${MLPREFIX}tk ${MLPREFIX}tk-lib', '', d)}" | ||
419 | RDEPENDS:${PN}-idle += "${@bb.utils.contains('PACKAGECONFIG', 'tk', '${PN}-tkinter ${MLPREFIX}tcl', '', d)}" | ||
420 | DEV_PKG_DEPENDENCY = "" | ||
421 | RDEPENDS:${PN}-pydoc += "${PN}-io" | ||
422 | |||
423 | RDEPENDS:${PN}-tests:append:class-target = " ${MLPREFIX}bash" | ||
424 | RDEPENDS:${PN}-tests:append:class-nativesdk = " ${MLPREFIX}bash" | ||
425 | |||
426 | # Python's tests contain large numbers of files we don't need in the recipe sysroots | ||
427 | SYSROOT_PREPROCESS_FUNCS += " py3_sysroot_cleanup" | ||
428 | py3_sysroot_cleanup () { | ||
429 | rm -rf ${SYSROOT_DESTDIR}${libdir}/python${PYTHON_MAJMIN}/test | ||
430 | } | ||