summaryrefslogtreecommitdiffstats
path: root/meta/recipes-devtools/perl/perl_5.20.0.bb
diff options
context:
space:
mode:
Diffstat (limited to 'meta/recipes-devtools/perl/perl_5.20.0.bb')
-rw-r--r--meta/recipes-devtools/perl/perl_5.20.0.bb348
1 files changed, 348 insertions, 0 deletions
diff --git a/meta/recipes-devtools/perl/perl_5.20.0.bb b/meta/recipes-devtools/perl/perl_5.20.0.bb
new file mode 100644
index 0000000000..4bd452512d
--- /dev/null
+++ b/meta/recipes-devtools/perl/perl_5.20.0.bb
@@ -0,0 +1,348 @@
1SUMMARY = "Perl scripting language"
2HOMEPAGE = "http://www.perl.org/"
3SECTION = "devel"
4LICENSE = "Artistic-1.0 | GPL-1.0"
5LIC_FILES_CHKSUM = "file://Copying;md5=5b122a36d0f6dc55279a0ebc69f3c60b \
6 file://Artistic;md5=2e6fd2475335af892494fe1f7327baf3"
7# We need gnugrep (for -I)
8DEPENDS = "virtual/db grep-native"
9DEPENDS += "gdbm zlib"
10PR = "r1"
11
12# 5.10.1 has Module::Build built-in
13PROVIDES += "libmodule-build-perl"
14
15SRC_URI = "http://www.cpan.org/src/5.0/perl-${PV}.tar.gz \
16"
17
18# Pick up patches from debian
19# http://ftp.de.debian.org/debian/pool/main/p/perl/perl_5.20.0-1.debian.tar.xz
20SRC_URI += " \
21 file://debian/cpan_definstalldirs.diff \
22 file://debian/db_file_ver.diff \
23 file://debian/doc_info.diff \
24 file://debian/enc2xs_inc.diff \
25 file://debian/errno_ver.diff \
26 file://debian/libperl_embed_doc.diff \
27 file://debian/fixes/respect_umask.diff \
28 file://debian/writable_site_dirs.diff \
29 file://debian/extutils_set_libperl_path.diff \
30 file://debian/no_packlist_perllocal.diff \
31 file://debian/prefix_changes.diff \
32 file://debian/instmodsh_doc.diff \
33 file://debian/ld_run_path.diff \
34 file://debian/libnet_config_path.diff \
35 file://debian/mod_paths.diff \
36 file://debian/module_build_man_extensions.diff \
37 file://debian/prune_libs.diff \
38 file://debian/fixes/net_smtp_docs.diff \
39 file://debian/perlivp.diff \
40 file://debian/squelch-locale-warnings.diff \
41 file://debian/skip-upstream-git-tests.diff \
42 file://debian/skip-kfreebsd-crash.diff \
43 file://debian/fixes/document_makemaker_ccflags.diff \
44 file://debian/find_html2text.diff \
45 file://debian/hurd_test_skip_stack.diff \
46 file://debian/perl5db-x-terminal-emulator.patch \
47 file://debian/cpan-missing-site-dirs.diff \
48 file://debian/fixes/memoize_storable_nstore.diff \
49 file://debian/regen-skip.diff \
50"
51
52SRC_URI += " \
53 file://Makefile.patch \
54 file://Makefile.SH.patch \
55 file://installperl.patch \
56 file://perl-dynloader.patch \
57 file://perl-moreconfig.patch \
58 file://letgcc-find-errno.patch \
59 file://generate-sh.patch \
60 file://native-perlinc.patch \
61 file://perl-enable-gdbm.patch \
62 file://cross-generate_uudmap.patch \
63 file://fix_bad_rpath.patch \
64 file://perl-archlib-exp.patch \
65 file://dynaloaderhack.patch \
66 \
67 \
68 file://config.sh \
69 file://config.sh-32 \
70 file://config.sh-32-le \
71 file://config.sh-32-be \
72 file://config.sh-64 \
73 file://config.sh-64-le \
74 file://config.sh-64-be \
75 file://perl-5.14.3-fix-CVE-2010-4777.patch \
76 file://0001-Makefile.SH-fix-do_install-failed.patch \
77"
78
79# Fix test case issues
80SRC_URI_append_class-target = " \
81 file://test/dist-threads-t-join.t-adjust-ps-option.patch \
82 file://test/ext-DynaLoader-t-DynaLoader.t-fix-calling-dl_findfil.patch \
83 "
84
85SRC_URI[md5sum] = "406ec049ebe3afcc80d9c76ec78ca4f8"
86SRC_URI[sha256sum] = "4e8c28ad6ecc89902f9cb2e76f2815bb1a8287ded278e15f7a36ca45f8bbcd02"
87
88inherit perlnative siteinfo
89
90# Where to find the native perl
91HOSTPERL = "${STAGING_BINDIR_NATIVE}/perl-native/perl${PV}"
92
93# Where to find .so files - use the -native versions not those from the target build
94export PERLHOSTLIB = "${STAGING_LIBDIR_NATIVE}/perl-native/perl/${PV}/"
95
96# LDFLAGS for shared libraries
97export LDDLFLAGS = "${LDFLAGS} -shared"
98
99LDFLAGS_append = " -fstack-protector"
100
101# We're almost Debian, aren't we?
102CFLAGS += "-DDEBIAN"
103
104do_nolargefile() {
105 sed -i -e "s,\(uselargefiles=\)'define',\1'undef',g" \
106 -e "s,\(d_readdir64_r=\)'define',\1'undef',g" \
107 -e "s,\(readdir64_r_proto=\)'\w+',\1'0',g" \
108 -e "/ccflags_uselargefiles/d" \
109 -e "s/-Duselargefiles//" \
110 -e "s/-D_FILE_OFFSET_BITS=64//" \
111 -e "s/-D_LARGEFILE_SOURCE//" \
112 ${S}/Cross/config.sh-${TARGET_ARCH}-${TARGET_OS}
113}
114
115do_configure() {
116 # Make hostperl in build directory be the native perl
117 ln -sf ${HOSTPERL} hostperl
118
119 # Do our work in the cross subdir
120 cd Cross
121
122 # Generate configuration
123 rm -f config.sh-${TARGET_ARCH}-${TARGET_OS}
124 for i in ${WORKDIR}/config.sh \
125 ${WORKDIR}/config.sh-${SITEINFO_BITS} \
126 ${WORKDIR}/config.sh-${SITEINFO_BITS}-${SITEINFO_ENDIANNESS}; do
127 cat $i >> config.sh-${TARGET_ARCH}-${TARGET_OS}
128 done
129
130 # Fixups for uclibc
131 if [ "${TARGET_OS}" = "linux-uclibc" -o "${TARGET_OS}" = "linux-uclibceabi" ]; then
132 sed -i -e "s,\(d_crypt_r=\)'define',\1'undef',g" \
133 -e "s,\(d_futimes=\)'define',\1'undef',g" \
134 -e "s,\(crypt_r_proto=\)'\w+',\1'0',g" \
135 -e "s,\(d_getnetbyname_r=\)'define',\1'undef',g" \
136 -e "s,\(getnetbyname_r_proto=\)'\w+',\1'0',g" \
137 -e "s,\(d_getnetbyaddr_r=\)'define',\1'undef',g" \
138 -e "s,\(getnetbyaddr_r_proto=\)'\w+',\1'0',g" \
139 -e "s,\(d_getnetent_r=\)'define',\1'undef',g" \
140 -e "s,\(getnetent_r_proto=\)'\w+',\1'0',g" \
141 -e "s,\(d_sockatmark=\)'define',\1'undef',g" \
142 -e "s,\(d_sockatmarkproto=\)'\w+',\1'0',g" \
143 -e "s,\(d_eaccess=\)'define',\1'undef',g" \
144 -e "s,\(d_stdio_ptr_lval=\)'define',\1'undef',g" \
145 -e "s,\(d_stdio_ptr_lval_sets_cnt=\)'define',\1'undef',g" \
146 -e "s,\(d_stdiobase=\)'define',\1'undef',g" \
147 -e "s,\(d_stdstdio=\)'define',\1'undef',g" \
148 -e "s,-fstack-protector,-fno-stack-protector,g" \
149 config.sh-${TARGET_ARCH}-${TARGET_OS}
150 fi
151
152 ${@bb.utils.contains('DISTRO_FEATURES', 'largefile', '', 'do_nolargefile', d)}
153
154 # Update some paths in the configuration
155 sed -i -e 's,@ARCH@-thread-multi,,g' \
156 -e 's,@ARCH@,${TARGET_ARCH}-${TARGET_OS},g' \
157 -e 's,@STAGINGDIR@,${STAGING_DIR_HOST},g' \
158 -e "s,@INCLUDEDIR@,${STAGING_INCDIR},g" \
159 -e "s,@LIBDIR@,${libdir},g" \
160 -e "s,@BASELIBDIR@,${base_libdir},g" \
161 -e "s,@EXECPREFIX@,${exec_prefix},g" \
162 -e 's,@USRBIN@,${bindir},g' \
163 config.sh-${TARGET_ARCH}-${TARGET_OS}
164
165 case "${TARGET_ARCH}" in
166 x86_64 | powerpc | s390)
167 sed -i -e "s,\(need_va_copy=\)'undef',\1'define',g" \
168 config.sh-${TARGET_ARCH}-${TARGET_OS}
169 ;;
170 arm)
171 sed -i -e "s,\(d_u32align=\)'undef',\1'define',g" \
172 config.sh-${TARGET_ARCH}-${TARGET_OS}
173 ;;
174 esac
175 # These are strewn all over the source tree
176 for foo in `grep -I --exclude="*.patch" --exclude="*.diff" --exclude="*.pod" --exclude="README*" -m1 "/usr/include/.*\.h" ${S}/* -r -l` ${S}/utils/h2xs.PL ; do
177 echo Fixing: $foo
178 sed -e 's|\([ "^'\''I]\+\)/usr/include/|\1${STAGING_INCDIR}/|g' -i $foo
179 done
180
181 rm -f config
182 echo "ARCH = ${TARGET_ARCH}" > config
183 echo "OS = ${TARGET_OS}" >> config
184}
185
186do_compile() {
187 # Fix to avoid recursive substitution of path
188 sed -i -e "s|\([ \"\']\+\)/usr/include|\1${STAGING_INCDIR}|g" ext/Errno/Errno_pm.PL
189 sed -i -e "s|\([ \"\']\+\)/usr/include|\1${STAGING_INCDIR}|g" cpan/Compress-Raw-Zlib/config.in
190 sed -i -e 's|/usr/lib|""|g' cpan/Compress-Raw-Zlib/config.in
191 sed -i -e 's|SYSROOTLIB|${STAGING_LIBDIR}|g' cpan/ExtUtils-MakeMaker/lib/ExtUtils/Liblist/Kid.pm
192
193 cd Cross
194 oe_runmake perl LD="${CCLD}"
195}
196
197do_install() {
198 #export hostperl="${STAGING_BINDIR_NATIVE}/perl-native/perl${PV}"
199 oe_runmake install DESTDIR=${D}
200 # Add perl pointing at current version
201 ln -sf perl${PV} ${D}${bindir}/perl
202
203 ln -sf perl ${D}/${libdir}/perl5
204
205 # Remove unwanted file and empty directories
206 rm -f ${D}/${libdir}/perl/${PV}/.packlist
207 rmdir ${D}/${libdir}/perl/site_perl/${PV}
208 rmdir ${D}/${libdir}/perl/site_perl
209
210 # Fix up shared library
211 mv ${D}/${libdir}/perl/${PV}/CORE/libperl.so ${D}/${libdir}/libperl.so.${PV}
212 ln -sf libperl.so.${PV} ${D}/${libdir}/libperl.so.5
213 ln -sf ../../../libperl.so.${PV} ${D}/${libdir}/perl/${PV}/CORE/libperl.so
214
215 # target config, used by cpan.bbclass to extract version information
216 install config.sh ${D}${libdir}/perl
217
218 ln -s Config_heavy.pl ${D}${libdir}/perl/${PV}/Config_heavy-target.pl
219}
220
221do_install_append_class-nativesdk () {
222 create_wrapper ${D}${bindir}/perl \
223 PERL5LIB='$PERL5LIB:$OECORE_NATIVE_SYSROOT/${libdir_nativesdk}/perl:$OECORE_NATIVE_SYSROOT/${libdir_nativesdk}/perl/${PV}'
224}
225
226PACKAGE_PREPROCESS_FUNCS += "perl_package_preprocess"
227
228perl_package_preprocess () {
229 # Fix up installed configuration
230 sed -i -e "s,${D},,g" \
231 -e "s,--sysroot=${STAGING_DIR_HOST},,g" \
232 -e "s,-isystem${STAGING_INCDIR} ,,g" \
233 -e "s,${STAGING_LIBDIR},${libdir},g" \
234 -e "s,${STAGING_BINDIR},${bindir},g" \
235 -e "s,${STAGING_INCDIR},${includedir},g" \
236 -e "s,${STAGING_BINDIR_NATIVE}/perl-native/,${bindir}/,g" \
237 -e "s,${STAGING_BINDIR_NATIVE}/,,g" \
238 -e "s,${STAGING_BINDIR_TOOLCHAIN}/${TARGET_PREFIX},${bindir},g" \
239 ${PKGD}${bindir}/h2xs \
240 ${PKGD}${bindir}/h2ph \
241 ${PKGD}${bindir}/pod2man \
242 ${PKGD}${bindir}/pod2text \
243 ${PKGD}${bindir}/pod2usage \
244 ${PKGD}${bindir}/podchecker \
245 ${PKGD}${bindir}/podselect \
246 ${PKGD}${libdir}/perl/${PV}/CORE/config.h \
247 ${PKGD}${libdir}/perl/${PV}/CORE/perl.h \
248 ${PKGD}${libdir}/perl/${PV}/CORE/pp.h \
249 ${PKGD}${libdir}/perl/${PV}/Config.pm \
250 ${PKGD}${libdir}/perl/${PV}/Config.pod \
251 ${PKGD}${libdir}/perl/${PV}/Config_heavy.pl \
252 ${PKGD}${libdir}/perl/${PV}/ExtUtils/Liblist/Kid.pm \
253 ${PKGD}${libdir}/perl/${PV}/FileCache.pm \
254 ${PKGD}${libdir}/perl/${PV}/pod/*.pod \
255 ${PKGD}${libdir}/perl/config.sh
256}
257
258PACKAGES = "perl-dbg perl perl-misc perl-dev perl-pod perl-doc perl-lib \
259 perl-module-cpan perl-module-cpanplus perl-module-unicore"
260FILES_${PN} = "${bindir}/perl ${bindir}/perl${PV} \
261 ${libdir}/perl/${PV}/Config.pm \
262 ${libdir}/perl/${PV}/strict.pm \
263 ${libdir}/perl/${PV}/warnings.pm \
264 ${libdir}/perl/${PV}/warnings \
265 ${libdir}/perl/${PV}/vars.pm \
266 "
267FILES_${PN}_append_class-nativesdk = " ${bindir}/perl.real"
268RPROVIDES_${PN} += "perl-module-strict perl-module-vars perl-module-config perl-module-warnings \
269 perl-module-warnings-register"
270FILES_${PN}-dev = "${libdir}/perl/${PV}/CORE"
271FILES_${PN}-lib = "${libdir}/libperl.so* \
272 ${libdir}/perl5 \
273 ${libdir}/perl/config.sh \
274 ${libdir}/perl/${PV}/Config_heavy.pl \
275 ${libdir}/perl/${PV}/Config_heavy-target.pl"
276FILES_${PN}-pod = "${libdir}/perl/${PV}/pod \
277 ${libdir}/perl/${PV}/*.pod \
278 ${libdir}/perl/${PV}/*/*.pod \
279 ${libdir}/perl/${PV}/*/*/*.pod "
280FILES_perl-misc = "${bindir}/*"
281FILES_${PN}-dbg += "${libdir}/perl/${PV}/auto/*/.debug \
282 ${libdir}/perl/${PV}/auto/*/*/.debug \
283 ${libdir}/perl/${PV}/auto/*/*/*/.debug \
284 ${libdir}/perl/${PV}/CORE/.debug \
285 ${libdir}/perl/${PV}/*/.debug \
286 ${libdir}/perl/${PV}/*/*/.debug \
287 ${libdir}/perl/${PV}/*/*/*/.debug "
288FILES_${PN}-doc = "${libdir}/perl/${PV}/*/*.txt \
289 ${libdir}/perl/${PV}/*/*/*.txt \
290 ${libdir}/perl/${PV}/auto/XS/Typemap \
291 ${libdir}/perl/${PV}/B/assemble \
292 ${libdir}/perl/${PV}/B/cc_harness \
293 ${libdir}/perl/${PV}/B/disassemble \
294 ${libdir}/perl/${PV}/B/makeliblinks \
295 ${libdir}/perl/${PV}/CGI/eg \
296 ${libdir}/perl/${PV}/CPAN/PAUSE2003.pub \
297 ${libdir}/perl/${PV}/CPAN/SIGNATURE \
298 ${libdir}/perl/${PV}/CPANPLUS/Shell/Default/Plugins/HOWTO.pod \
299 ${libdir}/perl/${PV}/Encode/encode.h \
300 ${libdir}/perl/${PV}/ExtUtils/MANIFEST.SKIP \
301 ${libdir}/perl/${PV}/ExtUtils/NOTES \
302 ${libdir}/perl/${PV}/ExtUtils/PATCHING \
303 ${libdir}/perl/${PV}/ExtUtils/typemap \
304 ${libdir}/perl/${PV}/ExtUtils/xsubpp \
305 ${libdir}/perl/${PV}/ExtUtils/Changes_EU-Install \
306 ${libdir}/perl/${PV}/Net/*.eg \
307 ${libdir}/perl/${PV}/unicore/mktables \
308 ${libdir}/perl/${PV}/unicore/mktables.lst \
309 ${libdir}/perl/${PV}/unicore/version "
310
311FILES_perl-module-cpan += "${libdir}/perl/${PV}/CPAN \
312 ${libdir}/perl/${PV}/CPAN.pm"
313FILES_perl-module-cpanplus += "${libdir}/perl/${PV}/CPANPLUS \
314 ${libdir}/perl/${PV}/CPANPLUS.pm"
315FILES_perl-module-unicore += "${libdir}/perl/${PV}/unicore"
316
317# Create a perl-modules package recommending all the other perl
318# packages (actually the non modules packages and not created too)
319ALLOW_EMPTY_perl-modules = "1"
320PACKAGES_append = " perl-modules "
321
322python populate_packages_prepend () {
323 libdir = d.expand('${libdir}/perl/${PV}')
324 do_split_packages(d, libdir, 'auto/([^.]*)/[^/]*\.(so|ld|ix|al)', 'perl-module-%s', 'perl module %s', recursive=True, match_path=True, prepend=False)
325 do_split_packages(d, libdir, 'Module/([^\/]*)\.pm', 'perl-module-%s', 'perl module %s', recursive=True, allow_dirs=False, match_path=True, prepend=False)
326 do_split_packages(d, libdir, 'Module/([^\/]*)/.*', 'perl-module-%s', 'perl module %s', recursive=True, allow_dirs=False, match_path=True, prepend=False)
327 do_split_packages(d, libdir, '(^(?!(CPAN\/|CPANPLUS\/|Module\/|unicore\/|auto\/)[^\/]).*)\.(pm|pl|e2x)', 'perl-module-%s', 'perl module %s', recursive=True, allow_dirs=False, match_path=True, prepend=False)
328
329 # perl-modules should recommend every perl module, and only the
330 # modules. Don't attempt to use the result of do_split_packages() as some
331 # modules are manually split (eg. perl-module-unicore).
332 packages = filter(lambda p: 'perl-module-' in p, d.getVar('PACKAGES', True).split())
333 d.setVar("RRECOMMENDS_${PN}-modules", ' '.join(packages))
334}
335
336PACKAGES_DYNAMIC += "^perl-module-.*"
337PACKAGES_DYNAMIC_class-nativesdk += "^nativesdk-perl-module-.*"
338
339RPROVIDES_perl-lib = "perl-lib"
340
341require perl-rdepends_${PV}.inc
342require perl-rprovides.inc
343require perl-rprovides_${PV}.inc
344require perl-ptest.inc
345
346SSTATE_SCAN_FILES += "*.pm *.pod *.h *.pl *.sh"
347
348BBCLASSEXTEND = "nativesdk"
generated by cgit v1.2.3-54-g00ecf (git 2.39.0) at 2024-06-02 18:20:57 +0000