summaryrefslogtreecommitdiffstats
path: root/meta/recipes-devtools/opensp/opensp_1.5.2.bb
diff options
context:
space:
mode:
Diffstat (limited to 'meta/recipes-devtools/opensp/opensp_1.5.2.bb')
-rw-r--r--meta/recipes-devtools/opensp/opensp_1.5.2.bb55
1 files changed, 55 insertions, 0 deletions
diff --git a/meta/recipes-devtools/opensp/opensp_1.5.2.bb b/meta/recipes-devtools/opensp/opensp_1.5.2.bb
new file mode 100644
index 0000000..a1f115c
--- /dev/null
+++ b/meta/recipes-devtools/opensp/opensp_1.5.2.bb
@@ -0,0 +1,55 @@
1SUMMARY = "An SGML parser"
2DESCRIPTION = "An SGML parser used by the OpenJade suite of utilities."
3HOMEPAGE = "http://openjade.sourceforge.net"
4SECTION = "libs"
5LICENSE = "BSD"
6LIC_FILES_CHKSUM = "file://COPYING;md5=641ff1e4511f0a87044ad42f87cb1045"
7
8PR = "r1"
9
10# At -Os it encounters calls to some inline functions which are then
11# not found in any other objects with gcc 4.5
12FULL_OPTIMIZATION += "-O2"
13
14SRC_URI = "${SOURCEFORGE_MIRROR}/openjade/OpenSP-${PV}.tar.gz \
15 file://obsolete_automake_macros.patch \
16"
17
18SRC_URI[md5sum] = "670b223c5d12cee40c9137be86b6c39b"
19SRC_URI[sha256sum] = "57f4898498a368918b0d49c826aa434bb5b703d2c3b169beb348016ab25617ce"
20
21S = "${WORKDIR}/OpenSP-${PV}"
22
23inherit autotools gettext
24
25EXTRA_OECONF = "--disable-doc-build"
26
27EXTRA_OECONF_class-native = "\
28 --disable-doc-build \
29 --enable-default-catalog=${sysconfdir}/sgml/catalog \
30 --enable-default-search-path=${datadir}/sgml \
31 "
32
33do_install_append() {
34 # Set up symlinks to often-used alternate names. See
35 # http://www.linuxfromscratch.org/blfs/view/stable/pst/opensp.html
36 cd ${D}${libdir}
37 ln -sf libosp.so libsp.so
38
39 cd ${D}${bindir}
40 for util in nsgmls sgmlnorm spam spcat spent sx; do
41 ln -sf o$util $util
42 done
43 ln -sf osx sgml2xml
44}
45
46do_install_append_class-native() {
47 for util in nsgmls sgmlnorm spam spcat spent sx; do
48 create_cmdline_wrapper ${D}/${bindir}/$util \
49 -D ${sysconfdir}/sgml
50 done
51}
52
53FILES_${PN} += "${datadir}/OpenSP/"
54
55BBCLASSEXTEND = "native"