summaryrefslogtreecommitdiffstats
path: root/meta/recipes-devtools/meson/nativesdk-meson_0.55.0.bb
diff options
context:
space:
mode:
Diffstat (limited to 'meta/recipes-devtools/meson/nativesdk-meson_0.55.0.bb')
-rw-r--r--meta/recipes-devtools/meson/nativesdk-meson_0.55.0.bb65
1 files changed, 65 insertions, 0 deletions
diff --git a/meta/recipes-devtools/meson/nativesdk-meson_0.55.0.bb b/meta/recipes-devtools/meson/nativesdk-meson_0.55.0.bb
new file mode 100644
index 0000000000..67add2c25e
--- /dev/null
+++ b/meta/recipes-devtools/meson/nativesdk-meson_0.55.0.bb
@@ -0,0 +1,65 @@
1include meson.inc
2
3inherit nativesdk
4inherit siteinfo
5
6SRC_URI += "file://meson-setup.py \
7 file://meson-wrapper"
8
9def meson_endian(prefix, d):
10 arch, os = d.getVar(prefix + "_ARCH"), d.getVar(prefix + "_OS")
11 sitedata = siteinfo_data_for_machine(arch, os, d)
12 if "endian-little" in sitedata:
13 return "little"
14 elif "endian-big" in sitedata:
15 return "big"
16 else:
17 bb.fatal("Cannot determine endianism for %s-%s" % (arch, os))
18
19# The cross file logic is similar but not identical to that in meson.bbclass,
20# since it's generating for an SDK rather than a cross-compile. Important
21# differences are:
22# - We can't set vars like CC, CXX, etc. yet because they will be filled in with
23# real paths by meson-setup.sh when the SDK is extracted.
24# - Some overrides aren't needed, since the SDK injects paths that take care of
25# them.
26do_install_append() {
27 install -d ${D}${datadir}/meson
28 cat >${D}${datadir}/meson/meson.cross.template <<EOF
29[binaries]
30c = @CC
31cpp = @CXX
32ar = @AR
33nm = @NM
34strip = @STRIP
35pkgconfig = 'pkg-config'
36
37[properties]
38needs_exe_wrapper = true
39c_args = @CFLAGS
40c_link_args = @LDFLAGS
41cpp_args = @CPPFLAGS
42cpp_link_args = @LDFLAGS
43
44[host_machine]
45system = '${SDK_OS}'
46cpu_family = '${SDK_ARCH}'
47cpu = '${SDK_ARCH}'
48endian = '${@meson_endian("SDK", d)}'
49EOF
50
51 install -d ${D}${SDKPATHNATIVE}/post-relocate-setup.d
52 install -m 0755 ${WORKDIR}/meson-setup.py ${D}${SDKPATHNATIVE}/post-relocate-setup.d/
53
54 # We need to wrap the real meson with a thin env setup wrapper.
55 mv ${D}${bindir}/meson ${D}${bindir}/meson.real
56 install -m 0755 ${WORKDIR}/meson-wrapper ${D}${bindir}/meson
57}
58
59RDEPENDS_${PN} += "\
60 nativesdk-ninja \
61 nativesdk-python3 \
62 nativesdk-python3-setuptools \
63 "
64
65FILES_${PN} += "${datadir}/meson ${SDKPATHNATIVE}"