summaryrefslogtreecommitdiffstats
path: root/meta/recipes-devtools/guile/guile_2.0.11.bb
diff options
context:
space:
mode:
Diffstat (limited to 'meta/recipes-devtools/guile/guile_2.0.11.bb')
-rw-r--r--meta/recipes-devtools/guile/guile_2.0.11.bb105
1 files changed, 105 insertions, 0 deletions
diff --git a/meta/recipes-devtools/guile/guile_2.0.11.bb b/meta/recipes-devtools/guile/guile_2.0.11.bb
new file mode 100644
index 0000000000..8fda850fc2
--- /dev/null
+++ b/meta/recipes-devtools/guile/guile_2.0.11.bb
@@ -0,0 +1,105 @@
1SUMMARY = "Guile is the GNU Ubiquitous Intelligent Language for Extensions"
2DESCRIPTION = "Guile is the GNU Ubiquitous Intelligent Language for Extensions,\
3 the official extension language for the GNU operating system.\
4 Guile is a library designed to help programmers create flexible applications.\
5 Using Guile in an application allows the application's functionality to be\
6 extended by users or other programmers with plug-ins, modules, or scripts.\
7 Guile provides what might be described as 'practical software freedom,'\
8 making it possible for users to customize an application to meet their\
9 needs without digging into the application's internals."
10
11HOMEPAGE = "http://www.gnu.org/software/guile/"
12SECTION = "devel"
13LICENSE = "GPLv3"
14LIC_FILES_CHKSUM = "file://COPYING;md5=d32239bcb673463ab874e80d47fae504"
15
16SRC_URI = "${GNU_MIRROR}/guile/guile-${PV}.tar.xz \
17 file://debian/0002-Mark-Unused-modules-are-removed-gc-test-as-unresolve.patch \
18 file://debian/0003-Mark-mutex-with-owner-not-retained-threads-test-as-u.patch \
19 file://opensuse/guile-64bit.patch \
20 file://guile_2.0.6_fix_sed_error.patch \
21 file://arm_endianness.patch \
22 file://workaround-ice-ssa-corruption.patch \
23 file://libguile-Makefile.am-depends.patch \
24 "
25
26# file://debian/0001-Change-guile-to-guile-X.Y-for-info-pages.patch
27# file://opensuse/guile-turn-off-gc-test.patch
28
29SRC_URI[md5sum] = "03f1bce1a4983076d955003472306a13"
30SRC_URI[sha256sum] = "aed0a4a6db4e310cbdfeb3613fa6f86fddc91ef624c1e3f8937a6304c69103e2"
31
32
33inherit autotools gettext pkgconfig texinfo
34BBCLASSEXTEND = "native"
35
36DEPENDS = "libunistring bdwgc gmp libtool libffi ncurses readline"
37# add guile-native only to the target recipe's DEPENDS
38DEPENDS_append_class-target = " guile-native libatomics-ops"
39
40RDEPENDS_${PN}_append_libc-glibc_class-target = "glibc-gconv-iso8859-1"
41
42EXTRA_OECONF += "${@['--without-libltdl-prefix --without-libgmp-prefix --without-libreadline-prefix', ''][bb.data.inherits_class('native',d)]}"
43
44do_configure_prepend() {
45 mkdir -p po
46}
47
48export GUILE_FOR_BUILD="${BUILD_SYS}-guile"
49
50do_compile_append() {
51 # just for target recipe
52 if [ "${PN}" = "guile" ]
53 then
54 sed -i -e s:${STAGING_DIR_TARGET}::g \
55 -e s:/${TARGET_SYS}::g \
56 -e s:-L/usr/lib::g \
57 -e s:-isystem/usr/include::g \
58 -e s:,/usr/lib:,\$\{libdir\}:g \
59 meta/guile-2.0.pc
60 fi
61}
62
63do_install_append_class-native() {
64 install -m 0755 ${D}${bindir}/guile ${D}${bindir}/${HOST_SYS}-guile
65
66 create_wrapper ${D}/${bindir}/guile \
67 GUILE_LOAD_PATH=${STAGING_DATADIR_NATIVE}/guile/2.0 \
68 GUILE_LOAD_COMPILED_PATH=${STAGING_LIBDIR_NATIVE}/guile/2.0/ccache
69 create_wrapper ${D}${bindir}/${HOST_SYS}-guile \
70 GUILE_LOAD_PATH=${STAGING_DATADIR_NATIVE}/guile/2.0 \
71 GUILE_LOAD_COMPILED_PATH=${STAGING_LIBDIR_NATIVE}/guile/2.0/ccache
72}
73
74SYSROOT_PREPROCESS_FUNCS = "guile_cross_config"
75
76guile_cross_config() {
77 # this is only for target recipe
78 if [ "${PN}" = "guile" ]
79 then
80 # Create guile-config returning target values instead of native values
81 install -d ${SYSROOT_DESTDIR}${STAGING_BINDIR_CROSS}
82 echo '#!'`which ${BUILD_SYS}-guile`$' \\\n--no-auto-compile -e main -s\n!#\n(define %guile-build-info '\'\( \
83 > guile-config.cross
84 sed -n -e 's:^[ \t]*{[ \t]*": (:' \
85 -e 's:",[ \t]*": . ":' \
86 -e 's:" *}, *\\:"):' \
87 -e 's:^.*cachedir.*$::' \
88 -e '/^ (/p' \
89 < libguile/libpath.h >> guile-config.cross
90 echo '))' >> guile-config.cross
91 cat meta/guile-config >> guile-config.cross
92 install guile-config.cross ${STAGING_BINDIR_CROSS}/guile-config
93 fi
94}
95
96# Guile needs the compiled files to be newer than the source, and it won't
97# auto-compile into the prefix even if it can write there, so touch them here as
98# sysroot is managed.
99SSTATEPOSTINSTFUNCS += "guile_sstate_postinst"
100guile_sstate_postinst() {
101 if [ "${BB_CURRENTTASK}" = "populate_sysroot" -o "${BB_CURRENTTASK}" = "populate_sysroot_setscene" ]
102 then
103 find ${STAGING_DIR_TARGET}/${libdir}/guile/2.0/ccache -type f | xargs touch
104 fi
105}