diff options
Diffstat (limited to 'meta/recipes-devtools/git/git_2.42.0.bb')
-rw-r--r-- | meta/recipes-devtools/git/git_2.42.0.bb | 163 |
1 files changed, 163 insertions, 0 deletions
diff --git a/meta/recipes-devtools/git/git_2.42.0.bb b/meta/recipes-devtools/git/git_2.42.0.bb new file mode 100644 index 0000000000..c417b11b1e --- /dev/null +++ b/meta/recipes-devtools/git/git_2.42.0.bb | |||
@@ -0,0 +1,163 @@ | |||
1 | SUMMARY = "Distributed version control system" | ||
2 | HOMEPAGE = "http://git-scm.com" | ||
3 | DESCRIPTION = "Git is a free and open source distributed version control system designed to handle everything from small to very large projects with speed and efficiency." | ||
4 | SECTION = "console/utils" | ||
5 | LICENSE = "GPL-2.0-only & GPL-2.0-or-later & BSD-3-Clause & MIT & BSL-1.0 & LGPL-2.1-or-later" | ||
6 | DEPENDS = "openssl zlib" | ||
7 | |||
8 | PROVIDES:append:class-native = " git-replacement-native" | ||
9 | |||
10 | SRC_URI = "${KERNELORG_MIRROR}/software/scm/git/git-${PV}.tar.gz;name=tarball \ | ||
11 | file://fixsort.patch \ | ||
12 | file://0001-config.mak.uname-do-not-force-RHEL-7-specific-build-.patch \ | ||
13 | " | ||
14 | |||
15 | S = "${WORKDIR}/git-${PV}" | ||
16 | |||
17 | LIC_FILES_CHKSUM = "\ | ||
18 | file://COPYING;md5=7c0d7ef03a7eb04ce795b0f60e68e7e1 \ | ||
19 | file://reftable/LICENSE;md5=1a6424cafc4c9c88c689848e165af33b \ | ||
20 | file://sha1dc/LICENSE.txt;md5=9bbe4c990a9e98ea4b98ef5d3bcb8a7a \ | ||
21 | file://compat/nedmalloc/License.txt;md5=e4224ccaecb14d942c71d31bef20d78c \ | ||
22 | file://compat/inet_ntop.c;md5=76593c6f74e8ced5b24520175688d59b;endline=16 \ | ||
23 | file://compat/obstack.h;md5=08ad25fee5428cd879ceef451ce3a22e;endline=18 \ | ||
24 | file://compat/poll/poll.h;md5=9fc00170a53b8e3e52157c91ac688dd1;endline=19 \ | ||
25 | file://compat/regex/regex.h;md5=30cc8af0e6f0f8a25acec6d8783bb763;beginline=4;endline=22 \ | ||
26 | " | ||
27 | |||
28 | CVE_PRODUCT = "git-scm:git" | ||
29 | |||
30 | PACKAGECONFIG ??= "expat curl" | ||
31 | PACKAGECONFIG[cvsserver] = "" | ||
32 | PACKAGECONFIG[svn] = "" | ||
33 | PACKAGECONFIG[manpages] = ",,asciidoc-native xmlto-native" | ||
34 | PACKAGECONFIG[curl] = "--with-curl,--without-curl,curl" | ||
35 | PACKAGECONFIG[expat] = "--with-expat,--without-expat,expat" | ||
36 | |||
37 | EXTRA_OECONF = "--with-perl=${STAGING_BINDIR_NATIVE}/perl-native/perl \ | ||
38 | --without-tcltk \ | ||
39 | --without-iconv \ | ||
40 | " | ||
41 | EXTRA_OECONF:append:class-nativesdk = " --with-gitconfig=/etc/gitconfig " | ||
42 | |||
43 | # Needs brokensep as this doesn't use automake | ||
44 | inherit autotools-brokensep perlnative bash-completion manpages | ||
45 | |||
46 | EXTRA_OEMAKE = "NO_PYTHON=1 CFLAGS='${CFLAGS}' LDFLAGS='${LDFLAGS}'" | ||
47 | EXTRA_OEMAKE += "'PERL_PATH=/usr/bin/env perl'" | ||
48 | EXTRA_OEMAKE += "COMPUTE_HEADER_DEPENDENCIES=no" | ||
49 | EXTRA_OEMAKE:append:class-native = " NO_CROSS_DIRECTORY_HARDLINKS=1" | ||
50 | |||
51 | do_compile:prepend () { | ||
52 | # Remove perl/perl.mak to fix the out-of-date perl.mak error | ||
53 | # during rebuild | ||
54 | rm -f perl/perl.mak | ||
55 | |||
56 | if [ "${@bb.utils.filter('PACKAGECONFIG', 'manpages', d)}" ]; then | ||
57 | oe_runmake man | ||
58 | fi | ||
59 | } | ||
60 | |||
61 | do_install () { | ||
62 | oe_runmake install DESTDIR="${D}" bindir=${bindir} \ | ||
63 | template_dir=${datadir}/git-core/templates | ||
64 | |||
65 | install -d ${D}/${datadir}/bash-completion/completions/ | ||
66 | install -m 644 ${S}/contrib/completion/git-completion.bash ${D}/${datadir}/bash-completion/completions/git | ||
67 | |||
68 | if [ "${@bb.utils.filter('PACKAGECONFIG', 'manpages', d)}" ]; then | ||
69 | # Needs to be serial with make 4.4 due to https://savannah.gnu.org/bugs/index.php?63362 | ||
70 | make install-man DESTDIR="${D}" | ||
71 | fi | ||
72 | } | ||
73 | |||
74 | perl_native_fixup () { | ||
75 | sed -i -e 's#${STAGING_BINDIR_NATIVE}/perl-native/#${bindir}/#' \ | ||
76 | -e 's#${libdir}/perl-native/#${libdir}/#' \ | ||
77 | ${@d.getVar("PERLTOOLS").replace(' /',d.getVar('D') + '/')} | ||
78 | |||
79 | if [ ! "${@bb.utils.filter('PACKAGECONFIG', 'cvsserver', d)}" ]; then | ||
80 | # Only install the git cvsserver command if explicitly requested | ||
81 | # as it requires the DBI Perl module, which does not exist in | ||
82 | # OE-Core. | ||
83 | rm ${D}${libexecdir}/git-core/git-cvsserver \ | ||
84 | ${D}${bindir}/git-cvsserver | ||
85 | fi | ||
86 | |||
87 | if [ ! "${@bb.utils.filter('PACKAGECONFIG', 'svn', d)}" ]; then | ||
88 | # Only install the git svn command and all Git::SVN Perl modules | ||
89 | # if explicitly requested as they require the SVN::Core Perl | ||
90 | # module, which does not exist in OE-Core. | ||
91 | rm -r ${D}${libexecdir}/git-core/git-svn \ | ||
92 | ${D}${datadir}/perl5/Git/SVN* | ||
93 | fi | ||
94 | } | ||
95 | |||
96 | REL_GIT_EXEC_PATH = "${@os.path.relpath(libexecdir, bindir)}/git-core" | ||
97 | REL_GIT_TEMPLATE_DIR = "${@os.path.relpath(datadir, bindir)}/git-core/templates" | ||
98 | |||
99 | do_install:append:class-target () { | ||
100 | perl_native_fixup | ||
101 | } | ||
102 | |||
103 | do_install:append:class-native() { | ||
104 | create_wrapper ${D}${bindir}/git \ | ||
105 | GIT_EXEC_PATH='`dirname $''realpath`'/${REL_GIT_EXEC_PATH} \ | ||
106 | GIT_TEMPLATE_DIR='`dirname $''realpath`'/${REL_GIT_TEMPLATE_DIR} | ||
107 | } | ||
108 | |||
109 | do_install:append:class-nativesdk() { | ||
110 | create_wrapper ${D}${bindir}/git \ | ||
111 | GIT_EXEC_PATH='`dirname $''realpath`'/${REL_GIT_EXEC_PATH} \ | ||
112 | GIT_TEMPLATE_DIR='`dirname $''realpath`'/${REL_GIT_TEMPLATE_DIR} | ||
113 | perl_native_fixup | ||
114 | } | ||
115 | |||
116 | FILES:${PN} += "${datadir}/git-core ${libexecdir}/git-core/" | ||
117 | |||
118 | PERLTOOLS = " \ | ||
119 | ${bindir}/git-cvsserver \ | ||
120 | ${libexecdir}/git-core/git-archimport \ | ||
121 | ${libexecdir}/git-core/git-cvsexportcommit \ | ||
122 | ${libexecdir}/git-core/git-cvsimport \ | ||
123 | ${libexecdir}/git-core/git-cvsserver \ | ||
124 | ${libexecdir}/git-core/git-send-email \ | ||
125 | ${libexecdir}/git-core/git-svn \ | ||
126 | ${libexecdir}/git-core/git-instaweb \ | ||
127 | ${datadir}/gitweb/gitweb.cgi \ | ||
128 | ${datadir}/git-core/templates/hooks/prepare-commit-msg.sample \ | ||
129 | ${datadir}/git-core/templates/hooks/pre-rebase.sample \ | ||
130 | ${datadir}/git-core/templates/hooks/fsmonitor-watchman.sample \ | ||
131 | " | ||
132 | |||
133 | # Git tools requiring perl | ||
134 | PACKAGES =+ "${PN}-perltools" | ||
135 | FILES:${PN}-perltools += " \ | ||
136 | ${PERLTOOLS} \ | ||
137 | ${libdir}/perl \ | ||
138 | ${datadir}/perl5 \ | ||
139 | " | ||
140 | |||
141 | RDEPENDS:${PN}-perltools = "${PN} perl perl-module-file-path findutils" | ||
142 | |||
143 | # git-tk package with gitk and git-gui | ||
144 | PACKAGES =+ "${PN}-tk" | ||
145 | #RDEPENDS:${PN}-tk = "${PN} tk tcl" | ||
146 | #EXTRA_OEMAKE = "TCL_PATH=${STAGING_BINDIR_CROSS}/tclsh" | ||
147 | FILES:${PN}-tk = " \ | ||
148 | ${bindir}/gitk \ | ||
149 | ${datadir}/gitk \ | ||
150 | " | ||
151 | |||
152 | PACKAGES =+ "gitweb" | ||
153 | FILES:gitweb = "${datadir}/gitweb/" | ||
154 | RDEPENDS:gitweb = "perl" | ||
155 | |||
156 | BBCLASSEXTEND = "native nativesdk" | ||
157 | |||
158 | EXTRA_OECONF += "ac_cv_snprintf_returns_bogus=no \ | ||
159 | ac_cv_fread_reads_directories=${ac_cv_fread_reads_directories=yes} \ | ||
160 | " | ||
161 | EXTRA_OEMAKE += "NO_GETTEXT=1" | ||
162 | |||
163 | SRC_URI[tarball.sha256sum] = "34aedd54210d7216a55d642bbb4cfb22695b7610719a106bf0ddef4c82a8beed" | ||