summaryrefslogtreecommitdiffstats
path: root/meta/recipes-devtools/elfutils/elfutils_0.148.bb
diff options
context:
space:
mode:
Diffstat (limited to 'meta/recipes-devtools/elfutils/elfutils_0.148.bb')
-rw-r--r--meta/recipes-devtools/elfutils/elfutils_0.148.bb107
1 files changed, 107 insertions, 0 deletions
diff --git a/meta/recipes-devtools/elfutils/elfutils_0.148.bb b/meta/recipes-devtools/elfutils/elfutils_0.148.bb
new file mode 100644
index 0000000000..12864b94b7
--- /dev/null
+++ b/meta/recipes-devtools/elfutils/elfutils_0.148.bb
@@ -0,0 +1,107 @@
1SUMMARY = "Utilities and libraries for handling compiled object files"
2HOMEPAGE = "https://fedorahosted.org/elfutils"
3SECTION = "base"
4LICENSE = "(GPL-2+ & Elfutils-Exception)"
5LIC_FILES_CHKSUM = "file://COPYING;md5=0636e73ff0215e8d672dc4c32c317bb3\
6 file://EXCEPTION;md5=570adcb0c1218ab57f2249c67d0ce417"
7DEPENDS = "libtool bzip2 zlib virtual/libintl"
8
9PR = "r11"
10
11SRC_URI = "https://fedorahosted.org/releases/e/l/${PN}/${BP}.tar.bz2"
12
13SRC_URI[md5sum] = "a0bed1130135f17ad27533b0034dba8d"
14SRC_URI[sha256sum] = "8aebfa4a745db21cf5429c9541fe482729b62efc7e53e9110151b4169fe887da"
15
16# pick the patch from debian
17# http://ftp.de.debian.org/debian/pool/main/e/elfutils/elfutils_0.148-1.debian.tar.gz
18
19SRC_URI += "\
20 file://redhat-portability.diff \
21 file://redhat-robustify.diff \
22 file://hppa_backend.diff \
23 file://arm_backend.diff \
24 file://mips_backend.diff \
25 file://m68k_backend.diff \
26 file://testsuite-ignore-elflint.diff \
27 file://elf_additions.diff \
28 file://elfutils-fsize.patch \
29 file://remove-unused.patch \
30 file://mempcpy.patch \
31 file://fix_for_gcc-4.7.patch \
32 file://dso-link-change.patch \
33 file://nm-Fix-size-passed-to-snprintf-for-invalid-sh_name-case.patch \
34 file://elfutils-ar-c-fix-num-passed-to-memset.patch \
35 file://Fix_elf_cvt_gunhash.patch \
36 file://elf_begin.c-CVE-2014-9447-fix.patch \
37 file://add-ptest.patch \
38 file://run-ptest \
39 file://avoid_parallel_tests.patch \
40"
41# Only apply when building uclibc based target recipe
42SRC_URI_append_libc-uclibc = " file://uclibc-support.patch"
43
44# The buildsystem wants to generate 2 .h files from source using a binary it just built,
45# which can not pass the cross compiling, so let's work around it by adding 2 .h files
46# along with the do_configure_prepend()
47
48SRC_URI += "\
49 file://i386_dis.h \
50 file://x86_64_dis.h \
51"
52inherit autotools gettext ptest
53
54EXTRA_OECONF = "--program-prefix=eu- --without-lzma"
55EXTRA_OECONF_append_class-native = " --without-bzlib"
56EXTRA_OECONF_append_libc-uclibc = " --enable-uclibc"
57
58do_configure_prepend() {
59 sed -i '/^i386_dis.h:/,+4 {/.*/d}' ${S}/libcpu/Makefile.am
60
61 cp ${WORKDIR}/*dis.h ${S}/libcpu
62}
63
64do_compile_ptest() {
65 oe_runmake -C tests buildtest-TESTS
66}
67
68do_install_ptest() {
69 oe_runmake -C tests install-ptest DESTDIR=${D}${PTEST_PATH}
70}
71
72
73# we can not build complete elfutils when using uclibc
74# but some recipes e.g. gcc 4.5 depends on libelf so we
75# build only libelf for uclibc case
76
77EXTRA_OEMAKE_libc-uclibc = "-C libelf"
78EXTRA_OEMAKE_class-native = ""
79EXTRA_OEMAKE_class-nativesdk = ""
80
81BBCLASSEXTEND = "native nativesdk"
82
83# Package utilities separately
84PACKAGES =+ "${PN}-binutils libelf libasm libdw libdw-dev libasm-dev libelf-dev"
85FILES_${PN}-binutils = "\
86 ${bindir}/eu-addr2line \
87 ${bindir}/eu-ld \
88 ${bindir}/eu-nm \
89 ${bindir}/eu-readelf \
90 ${bindir}/eu-size \
91 ${bindir}/eu-strip"
92
93FILES_libelf = "${libdir}/libelf-${PV}.so ${libdir}/libelf.so.*"
94FILES_libasm = "${libdir}/libasm-${PV}.so ${libdir}/libasm.so.*"
95FILES_libdw = "${libdir}/libdw-${PV}.so ${libdir}/libdw.so.* ${libdir}/elfutils/lib*"
96FILES_libelf-dev = "${libdir}/libelf.so ${includedir}"
97FILES_libasm-dev = "${libdir}/libasm.so ${includedir}/elfutils/libasm.h"
98FILES_libdw-dev = "${libdir}/libdw.so ${includedir}/dwarf.h ${includedir}/elfutils/libdw*.h"
99# Some packages have the version preceeding the .so instead properly
100# versioned .so.<version>, so we need to reorder and repackage.
101#FILES_${PN} += "${libdir}/*-${PV}.so ${base_libdir}/*-${PV}.so"
102#FILES_SOLIBSDEV = "${libdir}/libasm.so ${libdir}/libdw.so ${libdir}/libelf.so"
103
104# The package contains symlinks that trip up insane
105INSANE_SKIP_${MLPREFIX}libdw = "dev-so"
106
107RDEPENDS_${PN}-ptest += " bash"