summaryrefslogtreecommitdiffstats
path: root/meta/recipes-devtools/elfutils/elfutils_0.148.bb
diff options
context:
space:
mode:
Diffstat (limited to 'meta/recipes-devtools/elfutils/elfutils_0.148.bb')
-rw-r--r--meta/recipes-devtools/elfutils/elfutils_0.148.bb103
1 files changed, 103 insertions, 0 deletions
diff --git a/meta/recipes-devtools/elfutils/elfutils_0.148.bb b/meta/recipes-devtools/elfutils/elfutils_0.148.bb
new file mode 100644
index 0000000..e2b8d26
--- /dev/null
+++ b/meta/recipes-devtools/elfutils/elfutils_0.148.bb
@@ -0,0 +1,103 @@
1SUMMARY = "Utilities and libraries for handling compiled object files"
2HOMEPAGE = "https://fedorahosted.org/elfutils"
3SECTION = "base"
4LICENSE = "(GPL-2+ & Elfutils-Exception)"
5LIC_FILES_CHKSUM = "file://COPYING;md5=0636e73ff0215e8d672dc4c32c317bb3\
6 file://EXCEPTION;md5=570adcb0c1218ab57f2249c67d0ce417"
7DEPENDS = "libtool bzip2 zlib virtual/libintl"
8
9PR = "r11"
10
11SRC_URI = "https://fedorahosted.org/releases/e/l/elfutils/elfutils-${PV}.tar.bz2"
12
13SRC_URI[md5sum] = "a0bed1130135f17ad27533b0034dba8d"
14SRC_URI[sha256sum] = "8aebfa4a745db21cf5429c9541fe482729b62efc7e53e9110151b4169fe887da"
15
16# pick the patch from debian
17# http://ftp.de.debian.org/debian/pool/main/e/elfutils/elfutils_0.148-1.debian.tar.gz
18
19SRC_URI += "\
20 file://redhat-portability.diff \
21 file://redhat-robustify.diff \
22 file://hppa_backend.diff \
23 file://arm_backend.diff \
24 file://mips_backend.diff \
25 file://m68k_backend.diff \
26 file://testsuite-ignore-elflint.diff \
27 file://elf_additions.diff \
28 file://elfutils-fsize.patch \
29 file://remove-unused.patch \
30 file://mempcpy.patch \
31 file://fix_for_gcc-4.7.patch \
32 file://dso-link-change.patch \
33 file://nm-Fix-size-passed-to-snprintf-for-invalid-sh_name-case.patch \
34 file://elfutils-ar-c-fix-num-passed-to-memset.patch \
35 file://add-ptest.patch \
36 file://run-ptest \
37 file://avoid_parallel_tests.patch \
38"
39# Only apply when building uclibc based target recipe
40SRC_URI_append_libc-uclibc = " file://uclibc-support.patch"
41
42# The buildsystem wants to generate 2 .h files from source using a binary it just built,
43# which can not pass the cross compiling, so let's work around it by adding 2 .h files
44# along with the do_configure_prepend()
45
46SRC_URI += "\
47 file://i386_dis.h \
48 file://x86_64_dis.h \
49"
50inherit autotools gettext ptest
51
52EXTRA_OECONF = "--program-prefix=eu- --without-lzma"
53EXTRA_OECONF_append_class-native = " --without-bzlib"
54EXTRA_OECONF_append_libc-uclibc = " --enable-uclibc"
55
56do_configure_prepend() {
57 sed -i '/^i386_dis.h:/,+4 {/.*/d}' ${S}/libcpu/Makefile.am
58
59 cp ${WORKDIR}/*dis.h ${S}/libcpu
60}
61
62do_compile_ptest() {
63 oe_runmake -C tests buildtest-TESTS
64}
65
66do_install_ptest() {
67 oe_runmake -C tests install-ptest DESTDIR=${D}${PTEST_PATH}
68}
69
70
71# we can not build complete elfutils when using uclibc
72# but some recipes e.g. gcc 4.5 depends on libelf so we
73# build only libelf for uclibc case
74
75EXTRA_OEMAKE_libc-uclibc = "-C libelf"
76EXTRA_OEMAKE_class-native = ""
77EXTRA_OEMAKE_class-nativesdk = ""
78
79BBCLASSEXTEND = "native nativesdk"
80
81# Package utilities separately
82PACKAGES =+ "${PN}-binutils libelf libasm libdw libdw-dev libasm-dev libelf-dev"
83FILES_${PN}-binutils = "\
84 ${bindir}/eu-addr2line \
85 ${bindir}/eu-ld \
86 ${bindir}/eu-nm \
87 ${bindir}/eu-readelf \
88 ${bindir}/eu-size \
89 ${bindir}/eu-strip"
90
91FILES_libelf = "${libdir}/libelf-${PV}.so ${libdir}/libelf.so.*"
92FILES_libasm = "${libdir}/libasm-${PV}.so ${libdir}/libasm.so.*"
93FILES_libdw = "${libdir}/libdw-${PV}.so ${libdir}/libdw.so.* ${libdir}/elfutils/lib*"
94FILES_libelf-dev = "${libdir}/libelf.so ${includedir}"
95FILES_libasm-dev = "${libdir}/libasm.so ${includedir}/elfutils/libasm.h"
96FILES_libdw-dev = "${libdir}/libdw.so ${includedir}/dwarf.h ${includedir}/elfutils/libdw*.h"
97# Some packages have the version preceeding the .so instead properly
98# versioned .so.<version>, so we need to reorder and repackage.
99#FILES_${PN} += "${libdir}/*-${PV}.so ${base_libdir}/*-${PV}.so"
100#FILES_SOLIBSDEV = "${libdir}/libasm.so ${libdir}/libdw.so ${libdir}/libelf.so"
101
102# The package contains symlinks that trip up insane
103INSANE_SKIP_${MLPREFIX}libdw = "dev-so"