diff options
Diffstat (limited to 'meta/recipes-devtools/e2fsprogs/e2fsprogs_1.46.1.bb')
-rw-r--r-- | meta/recipes-devtools/e2fsprogs/e2fsprogs_1.46.1.bb | 141 |
1 files changed, 141 insertions, 0 deletions
diff --git a/meta/recipes-devtools/e2fsprogs/e2fsprogs_1.46.1.bb b/meta/recipes-devtools/e2fsprogs/e2fsprogs_1.46.1.bb new file mode 100644 index 0000000000..be8b67c35d --- /dev/null +++ b/meta/recipes-devtools/e2fsprogs/e2fsprogs_1.46.1.bb | |||
@@ -0,0 +1,141 @@ | |||
1 | require e2fsprogs.inc | ||
2 | |||
3 | SRC_URI += "file://remove.ldconfig.call.patch \ | ||
4 | file://run-ptest \ | ||
5 | file://ptest.patch \ | ||
6 | file://mkdir_p.patch \ | ||
7 | " | ||
8 | |||
9 | SRC_URI_append_class-native = " file://e2fsprogs-fix-missing-check-for-permission-denied.patch \ | ||
10 | file://quiet-debugfs.patch \ | ||
11 | " | ||
12 | |||
13 | |||
14 | SRCREV = "3114c623f56b0d61f5f34b85f7b23d28f6c848c0" | ||
15 | UPSTREAM_CHECK_GITTAGREGEX = "v(?P<pver>\d+\.\d+(\.\d+)*)$" | ||
16 | |||
17 | EXTRA_OECONF += "--libdir=${base_libdir} --sbindir=${base_sbindir} \ | ||
18 | --enable-elf-shlibs --disable-libuuid --disable-uuidd \ | ||
19 | --disable-libblkid --enable-verbose-makecmds \ | ||
20 | --with-crond-dir=no" | ||
21 | |||
22 | EXTRA_OECONF_darwin = "--libdir=${base_libdir} --sbindir=${base_sbindir} --enable-bsd-shlibs" | ||
23 | |||
24 | PACKAGECONFIG ??= "" | ||
25 | PACKAGECONFIG[fuse] = '--enable-fuse2fs,--disable-fuse2fs,fuse' | ||
26 | |||
27 | # make locale rules sometimes fire, sometimes don't as git doesn't preserve | ||
28 | # file mktime. Touch the files introducing non-determinism to the build | ||
29 | do_compile_prepend (){ | ||
30 | find ${S}/po -type f -name "*.po" -exec touch {} + | ||
31 | } | ||
32 | |||
33 | do_install () { | ||
34 | oe_runmake 'DESTDIR=${D}' install | ||
35 | oe_runmake 'DESTDIR=${D}' install-libs | ||
36 | # We use blkid from util-linux now so remove from here | ||
37 | rm -f ${D}${base_libdir}/libblkid* | ||
38 | rm -rf ${D}${includedir}/blkid | ||
39 | rm -f ${D}${base_libdir}/pkgconfig/blkid.pc | ||
40 | rm -f ${D}${base_sbindir}/blkid | ||
41 | rm -f ${D}${base_sbindir}/fsck | ||
42 | rm -f ${D}${base_sbindir}/findfs | ||
43 | |||
44 | # e2initrd_helper and the pkgconfig files belong in libdir | ||
45 | if [ ! ${D}${libdir} -ef ${D}${base_libdir} ]; then | ||
46 | install -d ${D}${libdir} | ||
47 | mv ${D}${base_libdir}/e2initrd_helper ${D}${libdir} | ||
48 | mv ${D}${base_libdir}/pkgconfig ${D}${libdir} | ||
49 | fi | ||
50 | |||
51 | oe_multilib_header ext2fs/ext2_types.h | ||
52 | install -d ${D}${base_bindir} | ||
53 | mv ${D}${bindir}/chattr ${D}${base_bindir}/chattr.e2fsprogs | ||
54 | |||
55 | install -v -m 755 ${S}/contrib/populate-extfs.sh ${D}${base_sbindir}/ | ||
56 | |||
57 | # Clean host path (build directory) in compile_et, mk_cmds | ||
58 | sed -i -e "s,\(ET_DIR=.*\)${S}/lib/et\(.*\),\1${datadir}/et\2,g" ${D}${bindir}/compile_et | ||
59 | sed -i -e "s,\(SS_DIR=.*\)${S}/lib/ss\(.*\),\1${datadir}/ss\2,g" ${D}${bindir}/mk_cmds | ||
60 | } | ||
61 | |||
62 | # Need to find the right mke2fs.conf file | ||
63 | e2fsprogs_conf_fixup () { | ||
64 | for i in mke2fs mkfs.ext2 mkfs.ext3 mkfs.ext4; do | ||
65 | create_wrapper ${D}${base_sbindir}/$i MKE2FS_CONFIG=${sysconfdir}/mke2fs.conf | ||
66 | done | ||
67 | } | ||
68 | |||
69 | do_install_append_class-native() { | ||
70 | e2fsprogs_conf_fixup | ||
71 | } | ||
72 | |||
73 | do_install_append_class-nativesdk() { | ||
74 | e2fsprogs_conf_fixup | ||
75 | } | ||
76 | |||
77 | do_install_append_class-target() { | ||
78 | mv ${D}${base_sbindir}/mke2fs ${D}${base_sbindir}/mke2fs.e2fsprogs | ||
79 | mv ${D}${base_sbindir}/mkfs.ext2 ${D}${base_sbindir}/mkfs.ext2.e2fsprogs | ||
80 | mv ${D}${base_sbindir}/tune2fs ${D}${base_sbindir}/tune2fs.e2fsprogs | ||
81 | } | ||
82 | |||
83 | RDEPENDS_e2fsprogs = "e2fsprogs-badblocks e2fsprogs-dumpe2fs" | ||
84 | RRECOMMENDS_e2fsprogs = "e2fsprogs-mke2fs e2fsprogs-e2fsck" | ||
85 | |||
86 | PACKAGES =+ "e2fsprogs-badblocks e2fsprogs-dumpe2fs e2fsprogs-e2fsck e2fsprogs-e2scrub e2fsprogs-mke2fs e2fsprogs-resize2fs e2fsprogs-tune2fs" | ||
87 | PACKAGES =+ "libcomerr libss libe2p libext2fs" | ||
88 | |||
89 | FILES_e2fsprogs-dumpe2fs = "${base_sbindir}/dumpe2fs" | ||
90 | FILES_e2fsprogs-resize2fs = "${base_sbindir}/resize2fs*" | ||
91 | FILES_e2fsprogs-e2fsck = "${base_sbindir}/e2fsck ${base_sbindir}/fsck.ext*" | ||
92 | FILES_e2fsprogs-e2scrub = "${base_sbindir}/e2scrub*" | ||
93 | FILES_e2fsprogs-mke2fs = "${base_sbindir}/mke2fs.e2fsprogs ${base_sbindir}/mkfs.ext* ${sysconfdir}/mke2fs.conf" | ||
94 | FILES_e2fsprogs-tune2fs = "${base_sbindir}/tune2fs.e2fsprogs ${base_sbindir}/e2label" | ||
95 | FILES_e2fsprogs-badblocks = "${base_sbindir}/badblocks" | ||
96 | FILES_libcomerr = "${base_libdir}/libcom_err.so.*" | ||
97 | FILES_libss = "${base_libdir}/libss.so.*" | ||
98 | FILES_libe2p = "${base_libdir}/libe2p.so.*" | ||
99 | FILES_libext2fs = "${libdir}/e2initrd_helper ${base_libdir}/libext2fs.so.*" | ||
100 | FILES_${PN}-dev += "${datadir}/*/*.awk ${datadir}/*/*.sed ${base_libdir}/*.so ${bindir}/compile_et ${bindir}/mk_cmds" | ||
101 | |||
102 | ALTERNATIVE_${PN} = "chattr" | ||
103 | ALTERNATIVE_PRIORITY = "100" | ||
104 | ALTERNATIVE_LINK_NAME[chattr] = "${base_bindir}/chattr" | ||
105 | ALTERNATIVE_TARGET[chattr] = "${base_bindir}/chattr.e2fsprogs" | ||
106 | |||
107 | ALTERNATIVE_${PN}-doc = "fsck.8" | ||
108 | ALTERNATIVE_LINK_NAME[fsck.8] = "${mandir}/man8/fsck.8" | ||
109 | |||
110 | ALTERNATIVE_${PN}-mke2fs = "mke2fs mkfs.ext2" | ||
111 | ALTERNATIVE_LINK_NAME[mke2fs] = "${base_sbindir}/mke2fs" | ||
112 | ALTERNATIVE_LINK_NAME[mkfs.ext2] = "${base_sbindir}/mkfs.ext2" | ||
113 | |||
114 | ALTERNATIVE_${PN}-tune2fs = "tune2fs" | ||
115 | ALTERNATIVE_LINK_NAME[tune2fs] = "${base_sbindir}/tune2fs" | ||
116 | |||
117 | RDEPENDS_e2fsprogs-e2scrub = "bash" | ||
118 | RDEPENDS_${PN}-ptest += "coreutils procps bash bzip2 diffutils perl sed" | ||
119 | RDEPENDS_${PN}-ptest += "e2fsprogs-badblocks e2fsprogs-dumpe2fs e2fsprogs-e2fsck e2fsprogs-mke2fs e2fsprogs-resize2fs e2fsprogs-tune2fs" | ||
120 | |||
121 | do_compile_ptest() { | ||
122 | oe_runmake -C ${B}/tests | ||
123 | } | ||
124 | |||
125 | do_install_ptest() { | ||
126 | # This file's permissions depends on the host umask so be deterministic | ||
127 | chmod 0644 ${B}/tests/test_data.tmp | ||
128 | cp -R --no-dereference --preserve=mode,links -v ${B}/tests ${D}${PTEST_PATH}/test | ||
129 | cp -R --no-dereference --preserve=mode,links -v ${S}/tests/* ${D}${PTEST_PATH}/test | ||
130 | sed -e 's!../e2fsck/e2fsck!e2fsck!g' \ | ||
131 | -e 's!../misc/tune2fs!tune2fs!g' -i ${D}${PTEST_PATH}/test/*/expect* | ||
132 | sed -e 's!../e2fsck/e2fsck!${base_sbindir}/e2fsck!g' -i ${D}${PTEST_PATH}/test/*/script | ||
133 | |||
134 | # Remove various files | ||
135 | find "${D}${PTEST_PATH}" -type f \ | ||
136 | \( -name 'Makefile' -o -name 'Makefile.in' -o -name '*.o' -o -name '*.c' -o -name '*.h' \)\ | ||
137 | -exec rm -f {} + | ||
138 | |||
139 | install -d ${D}${PTEST_PATH}/lib | ||
140 | install -m 0644 ${B}/lib/config.h ${D}${PTEST_PATH}/lib/ | ||
141 | } | ||