summaryrefslogtreecommitdiffstats
path: root/meta/recipes-devtools/docbook-sgml-dtd
diff options
context:
space:
mode:
Diffstat (limited to 'meta/recipes-devtools/docbook-sgml-dtd')
-rw-r--r--meta/recipes-devtools/docbook-sgml-dtd/docbook-sgml-dtd-3.1-native_3.1.bb23
-rw-r--r--meta/recipes-devtools/docbook-sgml-dtd/docbook-sgml-dtd-4.1-native_4.1.bb23
-rw-r--r--meta/recipes-devtools/docbook-sgml-dtd/docbook-sgml-dtd-4.5-native.bb18
-rw-r--r--meta/recipes-devtools/docbook-sgml-dtd/docbook-sgml-dtd-native.inc70
-rw-r--r--meta/recipes-devtools/docbook-sgml-dtd/files/LICENSE-OASIS16
5 files changed, 150 insertions, 0 deletions
diff --git a/meta/recipes-devtools/docbook-sgml-dtd/docbook-sgml-dtd-3.1-native_3.1.bb b/meta/recipes-devtools/docbook-sgml-dtd/docbook-sgml-dtd-3.1-native_3.1.bb
new file mode 100644
index 0000000000..a7df4f9761
--- /dev/null
+++ b/meta/recipes-devtools/docbook-sgml-dtd/docbook-sgml-dtd-3.1-native_3.1.bb
@@ -0,0 +1,23 @@
1require docbook-sgml-dtd-native.inc
2
3LICENSE = "OASIS"
4LIC_FILES_CHKSUM = "file://LICENSE-OASIS;md5=c608985dd5f7f215e669e7639a0b1d2e"
5
6DTD_VERSION = "3.1"
7
8PR = "${INC_PR}.0"
9
10# Note: the upstream sources are not distributed with a license file.
11# LICENSE-OASIS is included as a "patch" to workaround this. When
12# upgrading this recipe, please verify whether this is still needed.
13SRC_URI = "http://www.docbook.org/sgml/3.1/docbk31.zip \
14 file://LICENSE-OASIS"
15
16SRC_URI[md5sum] = "432749c0c806dbae81c8bcb70da3b5d3"
17SRC_URI[sha256sum] = "20261d2771b9a052abfa3d8fab1aa62be05791a010281c566f9073bf0e644538"
18
19do_compile() {
20 # Refer to http://www.linuxfromscratch.org/blfs/view/stable/pst/sgml-dtd-3.html
21 # for details.
22 sed -i -e '/ISO 8879/d' -e 's|DTDDECL "-//OASIS//DTD DocBook V3.1//EN"|SGMLDECL|g' docbook.cat
23}
diff --git a/meta/recipes-devtools/docbook-sgml-dtd/docbook-sgml-dtd-4.1-native_4.1.bb b/meta/recipes-devtools/docbook-sgml-dtd/docbook-sgml-dtd-4.1-native_4.1.bb
new file mode 100644
index 0000000000..88c9396360
--- /dev/null
+++ b/meta/recipes-devtools/docbook-sgml-dtd/docbook-sgml-dtd-4.1-native_4.1.bb
@@ -0,0 +1,23 @@
1require docbook-sgml-dtd-native.inc
2
3LICENSE = "OASIS"
4LIC_FILES_CHKSUM = "file://LICENSE-OASIS;md5=c608985dd5f7f215e669e7639a0b1d2e"
5
6DTD_VERSION = "4.1"
7
8PR = "${INC_PR}.0"
9
10# Note: the upstream sources are not distributed with a license file.
11# LICENSE-OASIS is included as a "patch" to workaround this. When
12# upgrading this recipe, please verify whether this is still needed.
13SRC_URI = "http://docbook.org/sgml/4.1/docbk41.zip \
14 file://LICENSE-OASIS"
15
16SRC_URI[md5sum] = "489f6ff2a2173eb1e14216c10533ede2"
17SRC_URI[sha256sum] = "deaafcf0a3677692e7ad4412c0e41c1db3e9da6cdcdb3dd32b2cc1f9c97d6311"
18
19do_compile() {
20 # Refer to http://www.linuxfromscratch.org/blfs/view/stable/pst/sgml-dtd.html
21 # for details.
22 sed -i -e '/ISO 8879/d' -e '/gml/d' docbook.cat
23}
diff --git a/meta/recipes-devtools/docbook-sgml-dtd/docbook-sgml-dtd-4.5-native.bb b/meta/recipes-devtools/docbook-sgml-dtd/docbook-sgml-dtd-4.5-native.bb
new file mode 100644
index 0000000000..ae723c74fe
--- /dev/null
+++ b/meta/recipes-devtools/docbook-sgml-dtd/docbook-sgml-dtd-4.5-native.bb
@@ -0,0 +1,18 @@
1require docbook-sgml-dtd-native.inc
2
3LICENSE = "OASIS"
4LIC_FILES_CHKSUM = "file://LICENSE-OASIS;md5=c608985dd5f7f215e669e7639a0b1d2e"
5
6DTD_VERSION = "4.5"
7
8PR = "${INC_PR}.0"
9PV = "4.5"
10
11SRC_URI[md5sum] = "07c581f4bbcba6d3aac85360a19f95f7"
12SRC_URI[sha256sum] = "8043e514e80c6c19cb146b5d37937d1305bf3abf9b0097c36df7f70f611cdf43"
13
14do_compile() {
15 # Refer to http://www.linuxfromscratch.org/blfs/view/stable/pst/sgml-dtd.html
16 # for details.
17 sed -i -e '/ISO 8879/d' -e'/gml/d' docbook.cat
18}
diff --git a/meta/recipes-devtools/docbook-sgml-dtd/docbook-sgml-dtd-native.inc b/meta/recipes-devtools/docbook-sgml-dtd/docbook-sgml-dtd-native.inc
new file mode 100644
index 0000000000..af50987968
--- /dev/null
+++ b/meta/recipes-devtools/docbook-sgml-dtd/docbook-sgml-dtd-native.inc
@@ -0,0 +1,70 @@
1# The DTDs of the various versions have to be installed in parallel and
2# should not replace each other. The installation step is common for
3# all versions and just differs in ${DTD_VERSION} which is set in each
4# version recipe.
5#
6# The DTDs do have some quirks (see LFS documentation).
7SUMMARY = "Document type definitions for verification of SGML data files"
8DESCRIPTION = "Document type definitions for verification of SGML data \
9files against the DocBook rule set"
10HOMEPAGE = "http://www.docbook.org/sgml/"
11
12DEPENDS = "sgml-common-native"
13
14# Note: the upstream sources are not distributed with a license file.
15# LICENSE-OASIS is included as a "patch" to workaround this. When
16# upgrading this recipe, please verify whether this is still needed.
17SRC_URI = "http://www.docbook.org/sgml/${DTD_VERSION}/docbook-${DTD_VERSION}.zip \
18 file://LICENSE-OASIS"
19
20# The .zip file extracts to the current dir
21S = "${WORKDIR}"
22
23INC_PR = "r3"
24
25SSTATEPOSTINSTFUNCS += "docbook_sgml_dtd_sstate_postinst"
26SYSROOT_PREPROCESS_FUNCS += "docbook_sgml_dtd_sysroot_preprocess"
27
28inherit native
29
30do_install () {
31 # Refer to http://www.linuxfromscratch.org/blfs/view/stable/pst/sgml-dtd.html
32 # for details.
33 install -d -m 755 ${D}${datadir}/sgml/docbook/sgml-dtd-${DTD_VERSION}
34 install docbook.cat ${D}${datadir}/sgml/docbook/sgml-dtd-${DTD_VERSION}/catalog
35 cp -PpRr *.dtd *.mod *.dcl ${D}${datadir}/sgml/docbook/sgml-dtd-${DTD_VERSION}
36
37 install -d ${D}${sysconfdir}/sgml
38 echo "CATALOG ${datadir}/sgml/docbook/sgml-dtd-${DTD_VERSION}/catalog" > \
39 ${D}${sysconfdir}/sgml/sgml-docbook-dtd-${DTD_VERSION}.cat
40}
41
42docbook_sgml_dtd_sstate_postinst () {
43 if [ "${BB_CURRENTTASK}" = "populate_sysroot" -o "${BB_CURRENTTASK}" = "populate_sysroot_setscene" ]
44 then
45 # Ensure that the catalog file sgml-docbook.cat is properly
46 # updated when the package is installed from sstate cache.
47 ${SYSROOT_DESTDIR}${bindir_crossscripts}/install-catalog-docbook-sgml-dtd-${DTD_VERSION} \
48 --add ${sysconfdir}/sgml/sgml-docbook.bak \
49 ${sysconfdir}/sgml/sgml-docbook-dtd-${DTD_VERSION}.cat
50 ${SYSROOT_DESTDIR}${bindir_crossscripts}/install-catalog-docbook-sgml-dtd-${DTD_VERSION} \
51 --add ${sysconfdir}/sgml/sgml-docbook.cat \
52 ${sysconfdir}/sgml/sgml-docbook-dtd-${DTD_VERSION}.cat
53 fi
54}
55
56docbook_sgml_dtd_sysroot_preprocess () {
57 install -d ${SYSROOT_DESTDIR}${bindir_crossscripts}/
58 install -m 755 ${STAGING_BINDIR_NATIVE}/install-catalog ${SYSROOT_DESTDIR}${bindir_crossscripts}/install-catalog-docbook-sgml-dtd-${DTD_VERSION}
59}
60
61CLEANFUNCS += "docbook_sgml_dtd_sstate_clean"
62
63docbook_sgml_dtd_sstate_clean () {
64 # Ensure that the catalog file sgml-docbook.cat is properly
65 # updated when the package is removed from sstate cache.
66 files="${sysconfdir}/sgml/sgml-docbook.bak ${sysconfdir}/sgml/sgml-docbook.cat"
67 for f in $files; do
68 [ ! -f $f ] || sed -i '/\/sgml\/sgml-docbook-dtd-${DTD_VERSION}.cat/d' $f
69 done
70}
diff --git a/meta/recipes-devtools/docbook-sgml-dtd/files/LICENSE-OASIS b/meta/recipes-devtools/docbook-sgml-dtd/files/LICENSE-OASIS
new file mode 100644
index 0000000000..6da7f5b8c7
--- /dev/null
+++ b/meta/recipes-devtools/docbook-sgml-dtd/files/LICENSE-OASIS
@@ -0,0 +1,16 @@
1Permission to use, copy, modify and distribute the DocBook XML DTD
2and its accompanying documentation for any purpose and without fee
3is hereby granted in perpetuity, provided that the above copyright
4notice and this paragraph appear in all copies. The copyright
5holders make no representation about the suitability of the DTD for
6any purpose. It is provided "as is" without expressed or implied
7warranty.
8
9If you modify the DocBook DTD in any way, except for declaring and
10referencing additional sets of general entities and declaring
11additional notations, label your DTD as a variant of DocBook. See
12the maintenance documentation for more information.
13
14Please direct all questions, bug reports, or suggestions for
15changes to the docbook@lists.oasis-open.org mailing list. For more
16information, see http://www.oasis-open.org/docbook/.